Mathematica 9 is now available

 Documentation /  Scientific Astronomer /  Notebooks /

GPS SatellitesMir Transit

How to Visually Find The Mir Space Station

http://www.wolfram.com/applications/astronomer/index.html

setup

First load the package:

<<Astronomer`HomeSite`

and then set your viewing location:

SetLocation[GeoLongitude -> 145.0*Degree,
GeoLatitude -> -37.8*Degree,
GeoAltitude -> 0.*KiloMeter,
TimeZone -> 11];
(* Melbourne *)

Low Orbit Earth Satellites

There are many low orbit Earth satellites that are visible to the naked eye. The trick in spotting them is simply to know when to look. The window of opportunity is usually only about two minutes wide, and occurs at a time just after dusk or just before dawn.

The Mir space station is the best and brightest object to see. It can appear nearly as bright as the brightest stars, but will move rapidly across the sky. A Space Shuttle can also appear as bright as Mir, but missions do not happen all the time.

Other satellites that can appear bright are: the Hubble Space Telescope (HST), the Upper Atmosphere Research Satellite (UARS), and the Cosmic Background Explorer (COBE).

This notebook focuses on the Mir space station as an example. The notebook shows how to compute the precise time when Mir will be visible from your location, and also how to generate various star charts to aid in spotting it. Mir is usually so bright and moves so fast across the sky, that a detailed star chart is often not necessary however.

About Mir

The Russian Mir space station consists of two Kvant observation modules (launched 1987 and 1989), the Kristall industrial processing module (launched 1990) and the Mir vehicle itself (launched 1986). Regular supply ships such as Soyuz-TM and Progress-M are also always present, and new modules such as Spektr and Priroda were added in 1995.

Mir is in an orbit 340km up and tilted 51.6 degrees to the equator, so that any observer whose latitude is less than that will have the possibility of visually seeing the space station as a bright object moving quickly across the dusk or dawn sky.

The critical window is when Mir is still illuminated by sunlight but when the surface of the Earth below is still in darkness. This window is only open for a few minutes at most, and can only happen just after sunset or just before sunrise.

During such a critical period Mir can appears very bright at around magnitude 0, but can reach magnitude -1, and flashes of around magnitude -3 have been known to occur. Even at magnitude 0 it will appear as a very bright star-like object. And with binoculars it is sometimes possible to see vapour clouds near the station due to water dumps or burns of the orbital manoeuvering engines.

Mir typically makes brief two minute appearances at various times for a couple of weeks in evening skies. It is then lost for a couple of weeks in daylight, after which it reappears for brief two minute appearances at various times for a couple of weeks in morning skies. Finally it is eclipsed for a short period before returning to the evening sky, whence the cycle starts over.

Set Current Orbital Elements of Mir Space Station

Up to date orbital elements for the Mir space station and other satellites can be obtained from http://www.celestrak.com/NORAD/elements/mir.txt. It is important to use an up to date element set, as after a month or two the elements may not be very accurate anymore. Current Mir elements.

SetOrbitalElements[Mir,
"1 16609U 86017A 95025.53583445 .00005100 00000-0 71581-4 0 9062",
"2 16609 51.6458 152.6933 0001412 164.2374 195.8663 15.58639897510653"];

The date of this element set it 95025.53583445 which corresponds to 25th day of 1995.

Compute Date and Time when Mir is Visible

Use the BestView function to find the next overhead visibility:

BestView[Mir, {1995,1,31}]

The above says Mir is visible (and transiting the meridian) at 9:49pm on the first day of February, 1995. This time should be accurate to within about 20 seconds, with the uncertainty due to Mir doing some orbital manoeuvre not taken into account in the element set used.

You can check that Mir is indeed overhead at that precise time by typing:

GetLocation[Mir, {1995,2,1,21,49,0}]

which is very near our viewing location:

GetLocation[]

To compute the time when Mir will suddenly disappear due the Earth blocking out the sunlight from reaching Mir, type:

EclipseBegin[Mir, {1995,2,1,21,49,0}]

which says that at 9:50:46pm it will disappear. That is only 1 minute 46 seconds after it crosses the Meridian. In practice it takes a few seconds to fade away.

Although Mir is moving above the viewing location at the time computed above, its brightness will depend on how dark the background sky appears (among other things). So you must check when the Sun sets:

SunSet[{1995,2,1}]

The Sun therefore sets about 80 minutes before Mir moves overhead, and that is ample darkness. Also the next full moon is still a long way off:

FullMoon[{1995,2,1}]

so there is no problem with a bright Moon.

Finally here is the ephemeris data for Mir at the transit time.

Ephemeris[Mir, {1995,2,1,21,49,0},
ViewPoint->TopoCentric]

Note you must use ViewPoint->TopoCentric in the above, and other similar functions.

Some Numbers

Here is a table, in 5 second intervals, showing the Azimuth compass direction, the angular Altitude, the Distance, and the visibility of Mir during the transit period.

Table[{
ToString @ StringForm["9:`1`:`2``3`pm",
47+Floor[s/60],
If[s-Floor[s/60]*60<10,0,""],
s-Floor[s/60]*60],
Azimuth/Degrees,
Altitude/Degrees,
Distance,
!EclipseQ[Mir,
{1995,2,1,21,47,s}]} /.
HorizonCoordinates[Mir,
{1995,2,1,21,47,s},
ViewPoint->TopoCentric],
{s,0,240,5}]//TableForm

The highest angle, and hence closest approach, occurs at 9:49:10pm. Also assuming that you will not spot Mir until it is at least about 30 degrees above the horizon, means that you might pick it up visually at about 9:47:45pm in the south-west sky. It then moves overhead and disappears in the north-east sky at about 30 degrees altitude at 9:50:45pm. See the graphics later which makes this clearer.

Mir can disappear at any point in its travel overhead.

Global View of Mir Flyover

Here is a global view of the flyover of Mir which is shown as the red line moving from the south-west horizon over the zenith and towards the north-east horizon. Note the position of the Sun (the big yellow dot) which has just set into the south-west horizon. Also the Moon is below the west horizon.

ZenithStarChart[{1995,2,1,21,50,0},
RadialAngle -> 105*Degree,
Mesh -> True,
StarColors -> True,
StarLabels -> True,
MagnitudeRange -> 4.0,
RotateLabel -> False,
Epilog -> {RGBColor[1,0,0],
OrbitTrack[Mir,
{1995,2,1,21,50-10,0},
{1995,2,1,21,50+5,0},
ViewPoint -> TopoCentric,
PlotPoints -> 100]}];1;

Update: new and improved way to do the above. The OrbitTrack[...] used in Epilog above is a flexible way to draw an orbit track. However, there is now an easier way. Just use the option OrbitTrack->Mir (or a list of objects).

ZenithStarChart[{1995,2,1,21,50,0},
RadialAngle -> 105*Degree,
Mesh -> True,
StarColors -> True,
StarLabels -> True,
MagnitudeRange -> 4.0,
RotateLabel -> False,
OrbitTrack -> Mir];1;

Track Path of Mir

In the following Mesh->True is an expensive option in terms of CPU time, but you can use it anyway.

CompassStarChart[South,
     {1995,2,1,21,50,0},
Mesh -> True,
MagnitudeRange -> 4.0,
Ecliptic -> False,
StarColors -> True,
Epilog -> {RGBColor[1,0,0],
OrbitTrack[Mir,
{1995,2,1,21,50-10,0},
{1995,2,1,21,50+5,0},
ViewPoint -> TopoCentric,
PlotPoints -> 100]}];1;

CompassStarChart[North,
{1995,2,1,21,50,0},
Mesh -> True,
MagnitudeRange -> 4.0,
Ecliptic -> False,
StarColors -> True,
Epilog -> {RGBColor[1,0,0],
OrbitTrack[Mir,
{1995,2,1,21,50-5,0},
{1995,2,1,21,50+10,0},
ViewPoint -> TopoCentric,
PlotPoints -> 100]}];1;

Track Path of Mir (with different style settings)

Read the next section for a simplified way of doing all this.

In the following marks are labeled along the orbit at one minute intervals using the OrbitMark function.

CompassStarChart[South,
{1995,2,1,21,50,0},
Mesh -> False,
MagnitudeRange -> 4.0,
Ecliptic -> False,
StarLabels -> True,
Epilog -> {RGBColor[1,0,0],
OrbitTrack[Mir,
{1995,2,1,21,50-10,0},
{1995,2,1,21,50+5,0},
ViewPoint->TopoCentric,
PlotPoints->100],
Table[OrbitMark[Mir,
{1995,2,1,21,m,0},
ViewPoint->TopoCentric,
PlotLabel->m],
{m,49-6,49+6,1}]}];1;

Similar marks are labeled in the following. The point where Mir disappears into the Earth's shadow is also indicated with a blue X.

CompassStarChart[North,
{1995,2,1,21,50,0},
Mesh -> False,
MagnitudeRange -> 4.0,
Ecliptic -> False,
StarLabels -> True,
Epilog -> {RGBColor[1,0,0],
OrbitTrack[Mir,
{1995,2,1,21,50-5,0},
{1995,2,1,21,50+10,0},
ViewPoint->TopoCentric,
PlotPoints->100],
{RGBColor[0,0,1],
OrbitMark[Mir,
{1995,2,1,21,50,46},
ViewPoint->TopoCentric,
PlotLabel->"X"]},
Table[OrbitMark[Mir,
{1995,2,1,21,m,0},
ViewPoint->TopoCentric,
PlotLabel->m],
{m,49-6,49+6,1}]}];1;

Track Path of Mir (simplified method!!!)

In the following marks are labeled along the orbit at one minute intervals using the OrbitMark function.

CompassStarChart[South,
{1995,2,1,21,50,0},
Mesh -> False,
MagnitudeRange -> 4.0,
Ecliptic -> False,
StarLabels -> True,
OrbitTrack -> Mir];1;

Similar marks are labeled in the following. The point where Mir disappears into the Earth's shadow is also indicated with a blue X.

CompassStarChart[North,
{1995,2,1,21,50,0},
Mesh -> False,
MagnitudeRange -> 4.0,
Ecliptic -> False,
StarLabels -> True,
OrbitTrack -> Mir];1;

Orbit Track of Mir

OrbitTrackPlot[Mir,
{1995,2,1,21,50-10,0},
{1995,2,1,21,50+10,0},
LocationRing -> True,
Shading -> True];1;

OrbitTrackPlot[Mir,
{1995,2,1,21,50-10,0},
{1995,2,1,21,50+10,0},
LocationRing -> True,
Shading -> True,
PlotRange -> {{70, 180},
             {-80, 30}}];

GPS SatellitesMir Transit



Any questions about topics on this page? Click here to get an individual response.Buy NowMore Information
THIS IS DOCUMENTATION FOR AN OBSOLETE PRODUCT.