This is documentation for Mathematica 3, which was
based on an earlier version of the Wolfram Language.
View current documentation (Version 11.1)
 Documentation / Mathematica / The Mathematica Book / Advanced Mathematics / Numerical Operations on Data  /

3.8.2 Approximate Functions and Interpolation

In many kinds of numerical computations, it is convenient to introduce approximate functions. Approximate functions can be thought of as generalizations of ordinary approximate real numbers. While an approximate real number gives the value to a certain precision of a single numerical quantity, an approximate function gives the value to a certain precision of a quantity which depends on one or more parameters. Mathematica uses approximate functions, for example, to represent numerical solutions to differential equations obtained with NDSolve, as discussed in Section 1.6.4.
Approximate functions in Mathematica are represented by InterpolatingFunction objects. These objects work like the pure functions discussed in Section 2.2.5. The basic idea is that when given a particular argument, an InterpolatingFunction object finds the approximate function value that corresponds to that argument.
The InterpolatingFunction object contains a representation of the approximate function based on interpolation. Typically it contains values and possibly derivatives at a sequence of points. It effectively assumes that the function varies smoothly between these points. As a result, when you ask for the value of the function with a particular argument, the InterpolatingFunction object can interpolate to find an approximation to the value you want.

Constructing approximate functions.

  • Here is a table of the values of the sine function.
  • In[1]:= Table[{x, Sin[x]}, {x, 0, 2, 0.25}]


  • This constructs an approximate function which represents these values.
  • In[2]:= sin = Interpolation[%]


  • The approximate function reproduces each of the values in the original table.
  • In[3]:= sin[0.25]


  • It also allows you to get approximate values at other points.
  • In[4]:= sin[0.3]


  • In this case the interpolation is a fairly good approximation to the true sine function.
  • In[5]:= Sin[0.3]


    You can work with approximate functions much as you would with any other Mathematica functions. You can plot approximate functions, or perform numerical operations such as integration or root finding.

  • If you give a non-numerical argument, the approximate function is left in symbolic form.
  • In[6]:= sin[x]


  • Here is a numerical integral of the approximate function.
  • In[7]:= NIntegrate[sin[x]^2, {x, 0, Pi/2}]


  • Here is the same numerical integral for the true sine function.
  • In[8]:= NIntegrate[Sin[x]^2, {x, 0, Pi/2}]


  • A plot of the approximate function is essentially indistinguishable from the true sine function.
  • In[9]:= Plot[sin[x], {x, 0, 2}]

    If you differentiate an approximate function, Mathematica will return another approximate function that represents the derivative.

  • This finds the derivative of the approximate sine function, and evaluates it at

  • In[10]:= sin'[Pi/6]


  • The result is close to the exact one.
  • In[11]:= N[Cos[Pi/6]]


    InterpolatingFunction objects contain all the information Mathematica needs about approximate functions. In standard Mathematica output format, however, only the part that gives the domain of the InterpolatingFunction object is printed explicitly. The lists of actual parameters used in the InterpolatingFunction object are shown only in iconic form.

  • In standard output format, the only part of an InterpolatingFunction object printed explicitly is its domain.
  • In[12]:= sin


  • If you ask for a value outside of the domain, Mathematica prints a warning, then uses extrapolation to find a result.
  • In[13]:= sin[3]

    InterpolatingFunction::dmval: Input value {3} lies outside the range of data in the interpolating function. Extrapolation will be used.


    The more information you give about the function you are trying to approximate, the better the approximation Mathematica constructs can be. You can, for example, specify not only values of the function at a sequence of points, but also derivatives.

    Constructing approximate functions with specified derivatives.

    Interpolation works by fitting polynomial curves between the points you specify. You can use the option InterpolationOrder to specify the degree of these polynomial curves. The default setting is InterpolationOrder->3, yielding cubic curves.

  • This makes a table of values of the cosine function.
  • In[14]:= tab = Table[{x, Cos[x]}, {x, 0, 6}] ;

  • This creates an approximate function using linear interpolation between the values in the table.
  • In[15]:= Interpolation[tab, InterpolationOrder -> 1]


  • The approximate function consists of a collection of straight-line segments.
  • In[16]:= Plot[%[x], {x, 0, 6}]

  • With the default setting InterpolationOrder->3, cubic curves are used, and the function looks smooth.
  • In[17]:= Plot[Evaluate[Interpolation[tab]][x], {x, 0, 6}]

    Increasing the setting for InterpolationOrder typically leads to smoother approximate functions. However, if you increase the setting too much, spurious wiggles may develop.

    Interpolating multidimensional arrays of data.

  • This interpolates an array of values from integer grid points.
  • In[18]:= ListInterpolation[
    Table[1.5/(x^2 + y^3), {x, 10}, {y, 15}]]


  • Here is the value at a particular position.
  • In[19]:= %[6.5, 7.2]


  • Here is another array of values.
  • In[20]:= tab = Table[1.5/(x^2 + y^3),
    {x, 5.5, 7.2, .2}, {y, 2.3, 8.9, .1}] ;

  • To interpolate this array you explicitly have to tell Mathematica the domain it covers.
  • In[21]:= ListInterpolation[tab, {{5.5, 7.2}, {2.3, 8.9}}]


    ListInterpolation works for arrays of any dimension, and in each case it produces an InterpolatingFunction object which takes the appropriate number of arguments.

  • This interpolates a three-dimensional array.
  • In[22]:= ListInterpolation[
    Array[#1^2 + #2^2 - #3^2 &, {10, 10, 10}]] ;

  • The resulting InterpolatingFunction object takes three arguments.
  • In[23]:= %[3.4, 7.8, 2.6]


    Mathematica can handle not only purely numerical approximate functions, but also ones which involve symbolic parameters.

  • This generates an InterpolatingFunction that depends on the parameters a and b.
  • In[24]:= sfun = ListInterpolation[{1 + a, 2, 3, 4 + b, 5}]


  • This shows how the interpolated value at 2.2 depends on the parameters.
  • In[25]:= sfun[2.2] // Simplify


  • With the default setting for InterpolationOrder used, the value at this point no longer depends on a.
  • In[26]:= sfun[3.8] // Simplify


    In working with approximate functions, you can quite often end up with complicated combinations of InterpolatingFunction objects. You can always tell Mathematica to produce a single InterpolatingFunction object valid over a particular domain by using FunctionInterpolation.

  • This generates a new InterpolatingFunction object valid in the domain 0 to 1.
  • In[27]:= FunctionInterpolation[x + sin[x^2], {x, 0, 1}]


  • This generates a nested InterpolatingFunction object.
  • In[28]:= ListInterpolation[{3, 4, 5, sin[a], 6}]


  • This produces a pure two-dimensional InterpolatingFunction object.
  • In[29]:= FunctionInterpolation[a^2 + %[x], {x, 1, 3}, {a, 0, 1.5}]


    Constructing approximate functions by evaluating expressions.