This is documentation for Mathematica 4, which was
based on an earlier version of the Wolfram Language.
View current documentation (Version 11.2)

 Documentation /  Mathematica /  Das Mathematica Buch /  Die Prinzipien von Mathematica /  Die Struktur von Grafik und Ton /

Die Struktur von GrafikGrafikanweisungen und Optionen

2.9.2 Zweidimensionale Grafik-Elemente

Grundlegende zweidimensionale Grafik-Elemente

Hier ist eine Linien-Primitive.

In[1]:= sägeZahn = Line[Table[{n, (-1)^n}, {n, 6}]]

Out[1]=

Dies zeigt die Linie als zweidimensionales Grafik-Objekt.

In[2]:= sägeGraph = Show[ Graphics[sägeZahn] ]

Out[2]=

Dies zeigt die Linie erneut mit hinzugefügten Achsen.

In[3]:= Show[ %, Axes -> True ]

Out[3]=

Sie können Grafik-Objekte, die Sie explizit mit Grafik-Primitiven erzeugt haben, mit solchen, die mit Funktionen wie Plot erzeugt wurden, kombinieren.

Dies erzeugt ein gewöhnliches Mathematica-Diagramm.

In[4]:= Plot[Sin[Pi x], {x, 0, 6}]

Out[4]=

Dies kombiniert das Diagramm mit dem oben erzeugten Sägezahnbild.

In[5]:= Show[%, sägeGraph]

Out[5]=

Sie können verschiedene Grafik-Elemente kombinieren, indem Sie sie einfach in einer Liste angeben. Bei zweidimensionaler Grafik wird Mathematica die Elemente in genau der Reihenfolge darstellen, wie Sie sie angeben. Spätere Elemente werden deshalb über frühere gezeichnet.

Hier ist eine Liste von zwei Rectangle-Grafik-Elementen.

In[6]:= {Rectangle[{1, -1}, {2, -0.6}],
Rectangle[{4, .3}, {5, .8}]}

Out[6]=

Dies zeichnet die Rechtecke über die oben definierte Linie.

In[7]:= Show[ Graphics[ {sägeZahn, %} ]]

Out[7]=

Die Polygon-Grafik-Primitive nimmt eine Liste von -Koordinaten, die den Ecken eines Polygons entsprechen. Mathematica verbindet die letzte mit der ersten Ecke und füllt die so entstandene Fläche aus.

Hier sind die Koordinaten der Ecken eines regulären Fünfecks.

In[8]:= pentagon = Table[{Sin[2 Pi n/5], Cos[2 Pi n/5]}, {n, 5}]

Out[8]=

Dies zeigt das Fünfeck. Mit der Vorgabe-Auswahl des Bildseitenverhältnisses sieht das Fünfeck etwas zusammengedrückt aus.

In[9]:= Show[ Graphics[ Polygon[pentagon] ] ]

Out[9]=

Dies wählt das Bildseitenverhältnis so, daß die Gestalt des Fünfecks erhalten bleibt.

In[10]:= Show[%, AspectRatio -> Automatic]

Out[10]=

Mathematica kann mit Polygonen umgehen, die in sich gefaltet sind.

In[11]:= Show[Graphics[
Polygon[ {{-1, -1}, {1, 1}, {1, -1}, {-1, 1}} ] ]]

Out[11]=

Kreise und Kreisscheiben

Dies zeigt zwei Kreise mit dem Radius 2. Wenn Sie die Option AspectRatio -> Automatic setzen, erhalten die Kreise ihr natürliches Bildseitenverhältnis.

In[12]:= Show[ Graphics[
{Circle[{0, 0}, 2], Circle[{1, 1}, 2]} ],
AspectRatio -> Automatic ]

Out[12]=

Dies zeigt eine Folge von Ellipsenscheiben mit zunehmend größeren Halbachsen in der -Richtung und zunehmend kleineren in der -Richtung.

In[13]:= Show[ Graphics[
Table[Disk[{3n, 0}, {n/4, 2-n/4}], {n, 4}] ],
AspectRatio -> Automatic ]

Out[13]=

In Mathematica können Kreisbögen und Ellipsensegmente erzeugt werden. In beiden Fällen werden die Objekte durch einen Anfangs- und Endwinkel spezifiziert. Die Winkel werden im Gegenuhrzeigersinn im Bogenmaß gemessen, wobei Null der positiven -Richtung entspricht.

Dies zeichnet einen -Keil mit dem Mittelpunkt im Ursprung.

In[14]:= Show[ Graphics[ Disk[{0, 0}, 1, {0, 140 Degree}] ],
AspectRatio -> Automatic ]

Out[14]=

Rasterorientierte Grafik-Elemente

Hier ist ein Array von Werten zwischen 0 und 1.

In[15]:= modtab = Table[Mod[i, j]/3, {i, 4}, {j, 4}] // N

Out[15]=

Dies benutzt das Werte-Array als Graustufen in einem Raster.

In[16]:= Show[ Graphics[ Raster[%] ] ]

Out[16]=

Dies zeigt zwei sich überlappende Kopien des Rasters.

In[17]:= Show[ Graphics[ {Raster[modtab, {{0, 0}, {2, 2}}],
Raster[modtab, {{1.5, 1.5}, {3, 2}}]} ] ]

Out[17]=

Im Vorgabe-Fall erzeugt Raster immer ein Array mit grauen Zellen. Mit der Option ColorFunction können Sie eine „Färbefunktion" auf alle Zellen anwenden (siehe Abschnitt 2.9.7).

Sie können auch die Grafik-Primitive RasterArray einsetzen. Raster hat als Argument ein Array von Werten, während das Argument von RasterArray ein Array von Mathematica-Grafikanweisungen ist. Mit der zur jeweiligen Zelle gehörigen Anweisung wird die Farbe der Zelle bestimmt. In der Regel werden die Anweisungen aus dem Satz GrayLevel, RGBColor oder Hue ausgewählt. Mit Hilfe von RGBColor- und Hue-Anweisungen können Sie mit RasterArray Farb-Raster erzeugen.

Die Struktur von GrafikGrafikanweisungen und Optionen