This is documentation for Mathematica 5, which was
based on an earlier version of the Wolfram Language.
View current documentation (Version 11.2)

Documentation / Mathematica / The Mathematica Book / Advanced Mathematics in Mathematica / Manipulating Equations and Inequalities /

3.4.11 Advanced Topic: Quantifiers

In a statement like x^4 + x^2 > 0, Mathematica treats the variable x as having a definite, though unspecified, value. Sometimes, however, it is useful to be able to make statements about whole collections of possible values for x. You can do this using quantifiers.

The structure of quantifiers.

You can work with quantifiers in Mathematica much as you work with equations, inequalities or logical connectives. In most cases, the quantifiers will not immediately be changed by evaluation. But they can be simplified or reduced by functions like FullSimplify and Reduce.

This asserts that an x exists that makes the inequality true. The output here is just a formatted version of the input.

In[1]:= Exists[x, x^4 + x^2 > 0]


FullSimplify establishes that the assertion is true.

In[2]:= FullSimplify[%]


This gives False, since the inequality fails when x is zero.

In[3]:= FullSimplify[ForAll[x, x^4 + x^2 > 0]]


Mathematica supports a version of the standard notation for quantifiers used in predicate logic and pure mathematics. You can input as \[ForAll] or AliasIndicatorfaAliasIndicator, and you can input as \[Exists] or AliasIndicatorexAliasIndicator. To make the notation precise, however, Mathematica makes the quantified variable a subscript. The conditions on the variable can also be given in the subscript, separated by a comma.

Notation for quantifiers.

Given a statement that involves quantifiers, there are certain important cases where it is possible to resolve it into an equivalent statement in which the quantifiers have been eliminated. Somewhat like solving an equation, such quantifier elimination turns an implicit statement about what is true for all x or for some x into an explicit statement about the conditions under which this holds.

Quantifier elimination.

This shows that an x exists that makes the equation true.

In[4]:= Resolve[Exists[x, x^2 == x^3]]


This shows that the equations can only be satisfied if c obeys a certain condition.

In[5]:= Resolve[Exists[x, x^2 == c && x^3 == c + 1]]


Resolve can always eliminate quantifiers from any collection of polynomial equations and inequations over complex numbers, and from any collection of polynomial equations and inequalities over real numbers. It can also eliminate quantifiers from Boolean expressions.

This finds the conditions for a quadratic form over the reals to be positive.

In[6]:= Resolve[ForAll[x, a x^2 + b x + c > 0], Reals]


This shows that there is a way of assigning truth values to p and q that makes the expression true.

In[7]:= Resolve[Exists[{p, q}, p || q && ! q], Booleans]


You can also use quantifiers with Reduce. If you give Reduce a collection of equations or inequalities, then it will try to produce a detailed representation of the complete solution set. But sometimes you may want to address a more global question, such as whether the solution set covers all values of x, or whether it covers none of these values. Quantifiers provide a convenient way to specify such questions.

This gives the complete structure of the solution set.

In[8]:= Reduce[x^2 + x + c == 0, {c, x}, Reals]


This instead just gives the condition for a solution to exist.

In[9]:= Reduce[Exists[x, x^2 + x + c == 0], {c}, Reals]


It is possible to formulate a great many mathematical questions in terms of quantifiers.

This finds the conditions for a circle to be contained within an arbitrary conic section.

In[10]:= Reduce[ForAll[{x, y}, x^2 + y^2 < 1, a x^2 + b y^2 < c],
{a, b, c}, Reals]


This finds the conditions for a line to intersect a circle.

In[11]:= Reduce[Exists[{x, y}, x^2 + y^2 < 1, r x + s y == 1],
{r, s}, Reals]


This defines q to be a general monic quartic.

In[12]:= q[x_] := x^4 + b x^3 + c x^2 + d x + e

This finds the condition for all pairs of roots to the quartic to be equal.

In[13]:= Reduce[ForAll[{x, y}, q[x] == 0 && q[y] == 0, x == y],
{b, c, d, e}]


Although quantifier elimination over the integers is in general a computationally impossible problem, Mathematica can do it in specific cases.

This shows that cannot be a rational number.

In[14]:= Resolve[Exists[{x, y}, x^2 == 2 y^2 && y > 0], Integers]


is, though.

In[15]:= Resolve[Exists[{x, y}, 4 x^2 == 9 y^2 && y > 0], Integers]