This is documentation for Mathematica 5, which was
based on an earlier version of the Wolfram Language.
View current documentation (Version 11.2)

Documentation / Mathematica / The Mathematica Book / Advanced Mathematics in Mathematica / Manipulating Equations and Inequalities /

3.4.9 Equations and Inequalities over Domains

Mathematica normally assumes that variables which appear in equations can stand for arbitrary complex numbers. But when you use Reduce, you can explicitly tell Mathematica that the variables stand for objects in more restricted domains.

Solving over domains.

Reduce by default assumes that x can be complex, and gives all five complex solutions.

In[1]:= Reduce[x^6 - x^4 - 4x^2 + 4 == 0, x]


But here it assumes that x is real, and gives only the real solutions.

In[2]:= Reduce[x^6 - x^4 - 4x^2 + 4 == 0, x, Reals]


And here it assumes that x is an integer, and gives only the integer solutions.

In[3]:= Reduce[x^6 - x^4 - 4x^2 + 4 == 0, x, Integers]


A single polynomial equation in one variable will always have a finite set of discrete solutions. And in such a case one can think of Reduce[eqns, vars, dom] as just filtering the solutions by selecting the ones that happen to lie in the domain dom.

But as soon as there are more variables, things can become more complicated, with solutions to equations corresponding to parametric curves or surfaces in which the values of some variables can depend on the values of others. Often this dependence can be described by some collection of equations or inequalities, but the form of these can change significantly when one goes from one domain to another.

This gives solutions over the complex numbers as simple formulas.

In[4]:= Reduce[x^2 + y^2 == 1, {x, y}]


To represent solutions over the reals requires introducing an inequality.

In[5]:= Reduce[x^2 + y^2 == 1, {x, y}, Reals]


Over the integers, the solution can be represented as equations for discrete points.

In[6]:= Reduce[x^2 + y^2 == 1, {x, y}, Integers]


If your input involves only equations, then Reduce will by default assume that all variables are complex. But if your input involves inequalities, then Reduce will assume that any algebraic variables appearing in them are real, since inequalities can only compare real quantities.

Since the variables appear in an inequality, they are assumed to be real.

In[7]:= Reduce[{x + y + z == 1, x^2 + y^2 + z^2 < 1}, {x, y, z}]


Schematic building blocks for solutions to polynomial equations and inequalities.

For systems of polynomials over real and complex domains, the solutions always consist of a finite number of components, within which the values of variables are given by algebraic numbers or functions.

Here the components are distinguished by equations and inequations on x.

In[8]:= Reduce[x y^3 + y == 1, {x, y}, Complexes]


And here the components are distinguished by inequalities on x.

In[9]:= Reduce[x y^3 + y == 1, {x, y}, Reals]


While in principle Reduce can always find the complete solution to any collection of polynomial equations and inequalities with real or complex variables, the results are often very complicated, with the number of components typically growing exponentially as the number of variables increases.

With 3 variables, the solution here already involves 8 components.

In[10]:= Reduce[x^2 == y^2 == z^2 == 1, {x, y, z}]


As soon as one introduces functions like Sin or Exp, even equations in single real or complex variables can have solutions with an infinite number of components. Reduce labels these components by introducing additional parameters. By default, the n parameter in a given solution will be named C[n]. In general you can specify that it should be named f[n] by giving the option setting GeneratedParameters -> f.

The components here are labeled by the integer parameter .

In[11]:= Reduce[Exp[x] == 2, x,
GeneratedParameters -> (Subscript[c, #]&)]


Reduce can handle equations not only over real and complex variables, but also over integers. Solving such Diophantine equations can often be a very difficult problem.

Describing the solution to this equation over the reals is straightforward.

In[12]:= Reduce[x y == 8, {x, y}, Reals]


The solution over the integers involves the divisors of 8.

In[13]:= Reduce[x y == 8, {x, y}, Integers]


Solving an equation like this effectively requires factoring a large number.

In[14]:= Reduce[{x y == 7777777, x > y > 0}, {x, y}, Integers]


Reduce can solve any system of linear equations or inequalities over the integers. With linear equations in variables, parameters typically need to be introduced. But with inequalities, a much larger number of parameters may be needed.

Three parameters are needed here, even though there are only two variables.

In[15]:= Reduce[{3x - 2y > 1, x > 0, y > 0}, {x, y}, Integers]


With two variables, Reduce can solve any quadratic equation over the integers. The result can be a Fibonacci-like sequence, represented in terms of powers of quadratic irrationals.

Here is the solution to a Pell equation.

In[16]:= Reduce[{x^2 == 13 y^2 + 1, x > 0, y > 0}, {x, y}, Integers]


The actual values for specific C[1] as integers, as they should be.

In[17]:= FullSimplify[% /. Table[{C[1] -> i}, {i, 4}]]


Reduce can handle many specific classes of equations over the integers.

Here Reduce finds the solution to a Thue equation.

In[18]:= Reduce[x^3 - 4 x y^2 + y^3 == 1, {x, y}, Integers]


Changing the right-hand side to 3, the equation now has no solution.

In[19]:= Reduce[x^3 - 4 x y^2 + y^3 == 3, {x, y}, Integers]


Equations over the integers sometimes have seemingly quite random collections of solutions. And even small changes in equations can often lead them to have no solutions at all.

For polynomial equations over real and complex numbers, there is a definite decision procedure for determining whether or not any solution exists. But for polynomial equations over the integers, the unsolvability of Hilbert's Tenth Problem demonstrates that there can never be any such general procedure.

For specific classes of equations, however, procedures can be found, and indeed many are implemented in Reduce. But handling different classes of equations can often seem to require whole different branches of number theory, and quite different kinds of computations. And in fact it is known that there are universal integer polynomial equations, for which filling in some variables can make solutions for other variables correspond to the output of absolutely any possible program. This then means that for such equations there can never in general be any closed-form solution built from fixed elements like algebraic functions.

If one includes functions like Sin, then even for equations involving real and complex numbers the same issues can arise.

Reduce here effectively has to solve an equation over the integers.

In[20]:= Reduce[Sin[Pi x]^2 + Sin[Pi y]^2 +
(x^2 + y^2 - 25)^2 == 0, {x, y}, Reals]


Handling equations involving integers modulo n.

Since there are only ever a finite number of possible solutions for integer equations modulo n, Reduce can systematically find them.

This finds all solutions modulo 4.

In[21]:= Reduce[x^5 == y^4 + x y + 1, {x, y}, Modulus -> 4]


Different ways to specify domains for variables.

This assumes that x is an integer, but y is a real.

In[22]:= Reduce[{x^2 + 2y^2 == 1, x Element Integers, y Element Reals}, {x, y}]


Reduce normally treats complex variables as single objects. But in dealing with functions that are not analytic or have branch cuts, it sometimes has to break them into pairs of real variables Re[z] and Im[z].

The result involves separate real and imaginary parts.

In[23]:= Reduce[Abs[z] == 1, z]


Here again there is a separate condition on the imaginary part.

In[24]:= Reduce[Log[z] == a, {a, z}]


Reduce by default assumes that variables that appear algebraically in inequalities are real. But you can override this by explicitly specifying Complexes as the default domain. It is often useful in such cases to be able to specify that certain variables are still real.

Reduce by default assumes that x is a real.

In[25]:= Reduce[x^2 < 1, x]


This forces Reduce to consider the case where x can be complex.

In[26]:= Reduce[x^2 < 1, x, Complexes]


Since x does not appear algebraically, Reduce immediately assumes that it can be complex.

In[27]:= Reduce[Abs[x] < 1, x]


Here x is a real, but y can be complex.

In[28]:= Reduce[{Abs[y] < Abs[x], x Element Reals}, {x, y}]


Finding particular solutions in domains.

Reduce always returns a complete representation of the solution to a system of equations or inequalities. Sometimes, however, you may just want to find particular sample solutions. You can do this using FindInstance.

If FindInstance[expr, vars, dom] returns {} then this means that Mathematica has effectively proved that expr cannot be satisfied for any values of variables in the specified domain. When expr can be satisfied, FindInstance will normally pick quite arbitrarily among values that do this, as discussed for inequalities in Section 3.4.8.

Particularly for integer equations, FindInstance can often find particular solutions to equations even when Reduce cannot find a complete solution. In such cases it usually returns one of the smallest solutions to the equations.

This finds the smallest integer point on an elliptic curve.

In[29]:= FindInstance[{x^2 == y^3 + 12, x > 0, y > 0},
{x, y}, Integers]


One feature of FindInstance is that it also works with Boolean expressions whose variables can have values True or False. You can use FindInstance to determine whether a particular expression is satisfiable, so that there is some choice of truth values for its variables that makes the expression True.

This expression cannot be satisfied for any choice of p and q.

In[30]:= FindInstance[p && ! (p || ! q), {p, q}, Booleans]


But this can.

In[31]:= FindInstance[p && ! (! p || ! q), {p, q}, Booleans]