This is documentation for Mathematica 5, which was
based on an earlier version of the Wolfram Language.
View current documentation (Version 11.1)

Documentation / Mathematica / The Mathematica Book / Advanced Mathematics in Mathematica / Numerical Operations on Data /

3.8.5 Convolutions and Correlations

Convolution and correlation are central to many kinds of operations on lists of data. They are used in such areas as signal and image processing, statistical data analysis, approximations to partial differential equations, as well as operations on digit sequences and power series.

In both convolution and correlation the basic idea is to combine a kernel list with successive sublists of a list of data. The convolution of a kernel with a list has the general form , while the correlation has the general form .

Convolution and correlation of lists.

This forms the convolution of the kernel {x, y} with a list of data.

In[1]:= ListConvolve[{x,y}, {a,b,c,d,e}]


This forms the correlation.

In[2]:= ListCorrelate[{x,y}, {a,b,c,d,e}]


In this case reversing the kernel gives exactly the same result as ListConvolve.

In[3]:= ListCorrelate[{y, x}, {a,b,c,d,e}]


This forms successive differences of the data.

In[4]:= ListCorrelate[{-1,1}, {a,b,c,d,e}]


In forming sublists to combine with a kernel, there is always an issue of what to do at the ends of the list of data. By default, ListConvolve and ListCorrelate never form sublists which would "overhang" the ends of the list of data. This means that the output you get is normally shorter than the original list of data.

With an input list of length 6, the output is in this case of length 4.

In[5]:= ListCorrelate[{1,1,1}, Range[6]]


In practice one often wants to get output that is as long as the original list of data. To do this requires including sublists that overhang one or both ends of the list of data. The additional elements needed to form these sublists must be filled in with some kind of "padding". By default, Mathematica takes copies of the original list to provide the padding, thus effectively treating the list as being cyclic.

Controlling how the ends of the list of data are treated.

The default involves no overhangs.

In[6]:= ListCorrelate[{x, y}, {a, b, c, d}]


The last term in the last element now comes from the beginning of the list.

In[7]:= ListCorrelate[{x, y}, {a, b, c, d}, 1]


Now the first term of the first element and the last term of the last element both involve wraparound.

In[8]:= ListCorrelate[{x, y}, {a, b, c, d}, {-1, 1}]


In the general case ListCorrelate[kernel, list, , ] is set up so that in the first element of the result, the first element of list appears multiplied by the element at position in kernel, and in the last element of the result, the last element of list appears multiplied by the element at position in kernel. The default case in which no overhang is allowed on either side thus corresponds to ListCorrelate[kernel, list, 1, -1].

With a kernel of length 3, alignments {-1, 2} always make the first and last elements of the result the same.

In[9]:= ListCorrelate[{x, y, z}, {a, b, c, d}, {-1, 2}]


For many kinds of data, it is convenient to assume not that the data is cyclic, but rather that it is padded at either end by some fixed element, often 0, or by some sequence of elements.

Controlling the padding for a list of data.

This pads with element p.

In[10]:= ListCorrelate[{x, y}, {a, b, c, d}, {-1, 1}, p]


A common case is to pad with zero.

In[11]:= ListCorrelate[{x, y}, {a, b, c, d}, {-1, 1}, 0]


In this case q appears at one end, and p at the other.

In[12]:= ListCorrelate[{x, y}, {a, b, c, d}, {-1, 1}, {p, q}]


Different choices of kernel allow ListConvolve and ListCorrelate to be used for different kinds of computations.

This finds a moving average of data.

In[13]:= ListCorrelate[{1,1,1}/3, {a,b,c,d,e}, {-1,1}]


Here is a Gaussian kernel.

In[14]:= kern = Table[Exp[-n^2/100]/Sqrt[2. Pi], {n, -10, 10}] ;

This generates some "data".

In[15]:= data = Table[BesselJ[1, x] + 0.2 Random[ ], {x, 0, 10, .1}] ;

Here is a plot of the data.

In[16]:= ListPlot[data];

This convolves the kernel with the data.

In[17]:= ListConvolve[kern, data, {-1, 1}] ;

The result is a smoothed version of the data.

In[18]:= ListPlot[%]


You can use ListConvolve and ListCorrelate to handle symbolic as well as numerical data.

This forms the convolution of two symbolic lists.

In[19]:= ListConvolve[{a,b,c}, {u,v,w}, {1, -1}, 0]


The result corresponds exactly with the coefficients in the expanded form of this product of polynomials.

In[20]:= Expand[(a + b x + c x^2)(u + v x + w x^2)]


ListConvolve and ListCorrelate work on data in any number of dimensions.

This imports image data from a file.

In[21]:= g = ReadList["", Number, RecordLists->True];

Here is the image.

In[22]:= Show[Graphics[Raster[g], AspectRatio->Automatic]]


This convolves the data with a two-dimensional kernel.

In[23]:= ListConvolve[{{1,1,1},{1,-8,1},{1,1,1}}, g] ;

This shows the image corresponding to the data.

In[24]:= Show[Graphics[Raster[%], AspectRatio->Automatic]]


Other functions for manipulating multidimensional data.