This is documentation for Mathematica 5, which was
based on an earlier version of the Wolfram Language.
View current documentation (Version 11.2)

Documentation / Mathematica / The Mathematica Book / Advanced Mathematics in Mathematica / Numerical Operations on Data /

3.8.6 Cellular Automata

Cellular automata provide a convenient way to represent many kinds of systems in which the values of cells in an array are updated in discrete steps according to a local rule.

Generating a cellular automaton evolution.

This starts with the list given, then evolves rule 30 for four steps.

In[1]:= CellularAutomaton[30, {0, 0, 0, 1, 0, 0, 0}, 4]

Out[1]=

This defines a simple function for displaying cellular automaton evolution.

In[2]:= CAPlot[data_] := ListDensityPlot[Reverse[Max[data] - data],
AspectRatio->Automatic, Mesh->False, FrameTicks->None]

This shows 100 steps of rule 30 evolution from random initial conditions.

In[3]:= CAPlot[CellularAutomaton[30, Table[Random[Integer], {250}],
100]]

Out[3]=

Ways of specifying initial conditions for one-dimensional cellular automata.

If you give an explicit list of initial values, CellularAutomaton will take the elements in this list to correspond to all the cells in the system, arranged cyclically.

The right neighbor of the cell at the end is the cell at the beginning.

In[4]:= CellularAutomaton[30, {1, 0, 0, 0, 0}, 1]

Out[4]=

It is often convenient to set up initial conditions in which there is a small "seed" region, superimposed on a constant "background". By default, CellularAutomaton automatically fills in enough background to cover the size of the pattern that can be produced in the number of steps of evolution you specify.

This shows rule 30 evolving from an initial condition containing a single black cell.

In[5]:= CAPlot[CellularAutomaton[30, {{1}, 0}, 100]]

Out[5]=

This shows rule 30 evolving from an initial condition consisting of a {1,1} seed on a background of repeated {1,0,1,1} blocks.

In[6]:= CAPlot[CellularAutomaton[30, {{1, 1}, {1, 0, 1, 1}}, 100]]

Out[6]=

Particularly in studying interactions between structures, you may sometimes want to specify initial conditions for cellular automata in which certain blocks are placed at particular offsets.

This sets up an initial condition with black cells at offsets .

In[7]:= CAPlot[CellularAutomaton[30,
{{{ {1}, {-40} }, {{1}, {40}}}, 0}, 100]]

Out[7]=

Specifying rules for one-dimensional cellular automata.

In the simplest cases, a cellular automaton allows k possible values or "colors" for each cell, and has rules that involve up to r neighbors on each side. The digits of the "rule number" n then specify what the color of a new cell should be for each possible configuration of the neighborhood.

This evolves a single neighborhood for 1 step.

In[8]:= CellularAutomaton[30, {1,1,0}, 1]

Out[8]=

Here are the 8 possible neighborhoods for a , cellular automaton.

In[9]:= Table[IntegerDigits[i,2,3],{i,7,0,-1}]

Out[9]=

This shows the new color of the center cell for each of the 8 neighborhoods.

In[10]:= Map[CellularAutomaton[30, #, 1][[2,2]]&, %]

Out[10]=

For rule 30, this sequence corresponds to the base-2 digits of the number 30.

In[11]:= FromDigits[%, 2]

Out[11]=

This runs the general , rule with rule number 921408.

In[12]:= CAPlot[CellularAutomaton[{921408, 3, 1}, {{1}, 0}, 100]]

Out[12]=

For a general cellular automaton rule, each digit of the rule number specifies what color a different possible neighborhood of cells should yield. To find out which digit corresponds to which neighborhood, one effectively treats the cells in a neighborhood as digits in a number. For an cellular automaton, the number is obtained from the list of elements neig in the neighborhood by neig . k^2, k, 1.

It is sometimes convenient to consider totalistic cellular automata, in which the new value of a cell depends only on the total of the values in its neighborhood. One can specify totalistic cellular automata by rule numbers or "codes" in which each digit refers to neighborhoods with a given total value, obtained for example from neig . 1, 1, 1.

In general, CellularAutomaton allows one to specify rules using any sequence of weights. Another choice sometimes convenient is k, 1, k, which yields outer totalistic rules.

This runs the , totalistic rule with code number 867.

In[13]:= CAPlot[CellularAutomaton[{867, {3, 1}, 1}, {{1}, 0}, 100]]

Out[13]=

Rules with range involve all cells with offsets through . Sometimes it is convenient to think about rules that involve only cells with specific offsets. You can do this by replacing a single r with a list of offsets.

Any cellular automaton rule can be thought of as corresponding to a Boolean function. In the simplest case, basic Boolean functions like And or Nor take two arguments. These are conveniently specified in a cellular automaton rule as being at offsets {{0}, {1}}. Note that for compatibility with handling higher-dimensional cellular automata, offsets must always be given in lists, even for one-dimensional cellular automata.

This generates the truth table for 2-cell-neighborhood rule number 7, which turns out to be the Boolean function Nand.

In[14]:= Map[CellularAutomaton[{7, 2, {{0}, {1}}}, #, 1][[2, 2]] &,
{{1, 1}, {1, 0}, {0, 1}, {0, 0}}]

Out[14]=

Rule numbers provide a highly compact way to specify cellular automaton rules. But sometimes it is more convenient to specify rules by giving an explicit function that should be applied to each possible neighborhood.

This runs an additive cellular automaton whose rule adds all values in each neighborhood modulo 4.

In[15]:= CAPlot[CellularAutomaton[
{Mod[Apply[Plus, #], 4]&, {}, 1}, {{1}, 0}, 100]]

Out[15]=

The function is given a second argument, equal to the step number.

In[16]:= CAPlot[CellularAutomaton[
{Mod[Apply[Plus, #] + #2, 4]&, {}, 1}, {{1}, 0}, 100]]

Out[16]=

When you specify rules by functions, the values of cells need not be integers.

In[17]:= CAPlot[CellularAutomaton[
{Mod[1/2 Apply[Plus, #], 1] &, {}, 1}, {{1}, 0}, 100]]

Out[17]=

They can even be symbolic.

In[18]:= Simplify[CellularAutomaton[{Mod[Apply[Plus, #], 2] &,
{}, 1}, {{a}, 0}, 2], a Element Integers]

Out[18]=

Selecting which steps to keep.

This runs rule 30 for 5 steps, keeping only the last step.

In[19]:= CellularAutomaton[30, {{1}, 0}, 5, -1]

Out[19]=

This keeps the last 2 steps.

In[20]:= CellularAutomaton[30, {{1}, 0}, 5, -2]

Out[20]=

The step specification works very much like taking elements from a list with Take. One difference, though, is that the initial condition for the cellular automaton is considered to be step 0. Note that any step specification of the form ... must be enclosed in an additional list.

Cellular automaton step specifications.

This evolves for 100 steps, but keeps only every other step.

In[21]:= CAPlot[CellularAutomaton[30, {{1}, 0}, 100, {{1, -1, 2}}]]

Out[21]=

Selecting steps and cells to keep.

Much as you can specify which steps to keep in a cellular automaton evolution, so also you can specify which cells to keep. If you give an initial condition such as , , ... , blist, then is taken to have offset 0 for the purpose of specifying which cells to keep.

Cellular automaton cell specifications.

This keeps all steps, but drops cells at offsets more than 20 on the left.

In[22]:= CAPlot[CellularAutomaton[30, {{1}, 0}, 100,
{All, {-20, 100}}]]

Out[22]=

This keeps just the center column of cells.

In[23]:= CellularAutomaton[30, {{1}, 0}, 20, {All, {0}}]

Out[23]=

If you give an initial condition such as , , ... , blist, then CellularAutomaton will always effectively do the cellular automaton as if there were an infinite number of cells. By using a such as , you can tell CellularAutomaton to include only cells at specific offsets through in its output. CellularAutomaton by default includes cells out just far enough that their values never simply stay the same as in the background blist.

In general, given a cellular automaton rule with range r, cells out to distance r t on each side could in principle be affected in the evolution of the system. With being All, all these cells are included; with the default setting of Automatic, cells whose values effectively stay the same as in blist are trimmed off.

By default, only the parts that are not constant black are kept.

In[24]:= CAPlot[CellularAutomaton[225, {{1}, 0}, 100]]

Out[24]=

Using All for includes all cells that could be affected by a cellular automaton with this range.

In[25]:= CAPlot[CellularAutomaton[225, {{1}, 0}, 100, {All, All}]]

Out[25]=

CellularAutomaton generalizes quite directly to any number of dimensions.

Higher-dimensional rule specifications.

This is the rule specification for the two-dimensional 9-neighbor totalistic cellular automaton with code 797.

In[26]:= code797 = {797, {2, 1}, {1, 1}};

This gives steps 0 and 1 in its evolution.

In[27]:= CellularAutomaton[code797, {{{1}}, 0}, 1]

Out[27]=

This shows step 70 in the evolution.

In[28]:= CAPlot[First[CellularAutomaton[code797, {{{1}}, 0},
70, -1]]]

Out[28]=

This shows all steps in a slice along the axis.

In[29]:= CAPlot[Map[First,
CellularAutomaton[code797, {{{1}}, 0}, 70,
{All, {0}, All}]]]

Out[29]=