This is documentation for Mathematica 5, which was
based on an earlier version of the Wolfram Language.
View current documentation (Version 11.2)

Documentation / Mathematica / The Mathematica Book / Principles of Mathematica / Functional Operations /

2.2.8 Expressions with Heads That Are Not Symbols

In most cases, you want the head f of a Mathematica expression like f[x] to be a single symbol. There are, however, some important applications of heads that are not symbols.

This expression has f[3] as a head. You can use heads like this to represent "indexed functions".

In[1]:= f[3][x, y]


You can use any expression as a head. Remember to put in the necessary parentheses.

In[2]:= (a + b)[x]


One case where we have already encountered the use of complicated expressions as heads is in working with pure functions in Section 2.2.5. By giving Function[vars, body] as the head of an expression, you specify a function of the arguments to be evaluated.

With the head Function[x, x^2], the value of the expression is the square of the argument.

In[3]:= Function[x, x^2] [a + b]


There are several constructs in Mathematica which work much like pure functions, but which represent specific kinds of functions, typically numerical ones. In all cases, the basic mechanism involves giving a head which contains complete information about the function you want to use.

Some expressions which have heads that are not symbols.

NDSolve returns a list of rules that give y as an InterpolatingFunction object.

In[4]:= NDSolve[{y''[x] == y[x], y[0]==y'[0]==1}, y, {x, 0, 5}]


Here is the InterpolatingFunction object.

In[5]:= y /. First[%]


You can use the InterpolatingFunction object as a head to get numerical approximations to values of the function y.

In[6]:= % [3.8]


Another important use of more complicated expressions as heads is in implementing functionals and functional operators in mathematics.

As one example, consider the operation of differentiation. As will be discussed in Section 3.5.4, an expression like f' represents a derivative function, obtained from f by applying a functional operator to it. In Mathematica, f' is represented as Derivative[1][f]: the "functional operator" Derivative[1] is applied to f to give another function, represented as f'.

This expression has a head which represents the application of the "functional operator" Derivative[1] to the "function" f.

In[7]:= f'[x] // FullForm


You can replace the head f' with another head, such as fp. This effectively takes fp to be a "derivative function" obtained from f.

In[8]:= % /. f' -> fp