This is documentation for Mathematica 5, which was
based on an earlier version of the Wolfram Language.
View current documentation (Version 11.1)

Documentation / Mathematica / The Mathematica Book / Principles of Mathematica / MathLink and External Program Communication /

2.13.6 Using MathLink to Communicate between Mathematica Sessions

MathLink connections between Mathematica sessions.

Session A

This starts up a link on port number 8000.

In[1]:= link = LinkCreate["8000"]

Out[1]=LinkObject[8000@frog.wolfram.com, 4, 4]

Session B

This connects to the link on port 8000.

In[1]:=Link = LinkConnect["8000"]

Out[1]=LinkObject["8000@frog.wolfram.com", 4, 4]

Session A

This evaluates 15! and writes it to the link.

In[2]:=LinkWrite[link, 15!]

Session B

This reads from the link, getting the 15! that was sent.

In[2]:=LinkRead[link]

Out[2]=1307674368000

This writes data back on the link.

In[3]:=LinkWrite[link, N[%^6]]

Session A

And this reads the data written in session B.

In[3]:=LinkRead[link]

Out[3]=

One use of MathLink connections between Mathematica sessions is simply as a way to transfer data without using intermediate files.

Another use is as a way to dispatch different parts of a computation to different sessions.

Session A

This writes the expression 2 + 2 without evaluating it.

In[4]:=LinkWrite[link, Unevaluated[2 + 2]]

Session B

This reads the expression from the link, immediately wrapping it in Hold.

In[4]:=LinkRead[link, Hold]

Out[4]=Hold[2 + 2]

This evaluates the expression.

In[5]:=ReleaseHold[%]

Out[5]=4

When you call LinkWrite, it writes an expression to the MathLink connection and immediately returns. But when you call LinkRead, it will not return until it has read a complete expression from the MathLink connection.

You can tell whether anything is ready to be read by calling LinkReadyQ[link]. If LinkReadyQ returns True, then you can safely call LinkRead and expect immediately to start reading an expression. But if LinkReadyQ returns False, then LinkRead would block until an expression for it to read had been written by a LinkWrite in your other Mathematica session.

Session A

There is nothing waiting to be read on the link, so if LinkRead were to be called, it would block.

In[5]:=LinkReadyQ[link]

Out[5]=False

Session B

This writes an expression to the link.

In[6]:=LinkWrite[link, x + y]

Session A

Now there is an expression waiting to be read on the link.

In[6]:=LinkReadyQ[link]

Out[6]=True

LinkRead can thus be called without fear of blocking.

In[7]:=LinkRead[link]

Out[7]=x + y

Ways to set up MathLink links.

MathLink can use whatever mechanism for interprogram communication your computer system supports. In setting up connections between concurrent Mathematica sessions, the most common mechanism is internet TCP ports.

Most computer systems have a few thousand possible numbered ports, some of which are typically allocated to standard system services.

You can use any of the unallocated ports for MathLink connections.

Session on frog.wolfram.com

This finds an unallocated port on frog.wolfram.com.

In[8]:=link = LinkCreate[ ]

Out[8]=LinkObject["2981@frog.wolfram.com", 5, 5]

Session on toad.wolfram.com

This connects to the port on frog.wolfram.com.

In[7]:=link = LinkConnect["2981@frog.wolfram.com"]

Out[7]=LinkObject["2981@frog.wolfram.com", 5, 5]

This sends the current machine name over the link.

In[8]:=LinkWrite[link, $MachineName]

Session on frog.wolfram.com

This reads the expression written on toad.

In[9]:=LinkRead[link]

Out[9]=toad

By using internet ports for MathLink connections, you can easily transfer data between Mathematica sessions on different machines. All that is needed is that an internet connection exists between the machines.

Note that because MathLink is completely system independent, the computers at each end of a MathLink connection do not have to be of the same type. MathLink nevertheless notices when they are, and optimizes data transmission in this case.