This is documentation for Mathematica 5, which was
based on an earlier version of the Wolfram Language.
View current documentation (Version 11.1)

Documentation / Mathematica / The Mathematica Book / Principles of Mathematica / Patterns /

2.3.7 Flat and Orderless Functions

Although Mathematica matches patterns in a purely structural fashion, its notion of structural equivalence is quite sophisticated. In particular, it takes account of properties such as commutativity and associativity in functions like Plus and Times.

This means, for example, that Mathematica considers the expressions x + y and y + x equivalent for the purposes of pattern matching. As a result, a pattern like g[x_ + y_, x_] can match not only g[a + b, a], but also g[a + b, b].

This expression has exactly the same form as the pattern.

In[1]:= g[a + b, a] /. g[x_ + y_, x_] -> p[x, y]

Out[1]=

In this case, the expression has to be put in the form g[b + a, b] in order to have the same structure as the pattern.

In[2]:= g[a + b, b] /. g[x_ + y_, x_] -> p[x, y]

Out[2]=

Whenever Mathematica encounters an orderless or commutative function such as Plus or Times in a pattern, it effectively tests all the possible orders of arguments to try and find a match. Sometimes, there may be several orderings that lead to matches. In such cases, Mathematica just uses the first ordering it finds. For example, h[x_ + y_, x_ + z_] could match h[a + b, a + b] with xa, yb, zb or with xb, ya, za. Mathematica tries the case xa, yb, zb first, and so uses this match.

This can match either with x a or with x b. Mathematica tries x a first, and so uses this match.

In[3]:= h[a + b, a + b] /. h[x_ + y_, x_ + z_] -> p[x, y, z]

Out[3]=

ReplaceList shows both possible matches.

In[4]:= ReplaceList[h[a + b, a + b],
h[x_ + y_, x_ + z_] -> p[x, y, z]]

Out[4]=

As discussed in Section 2.6.3, Mathematica allows you to assign certain attributes to functions, which specify how those functions should be treated in evaluation and pattern matching. Functions can for example be assigned the attribute Orderless, which specifies that they should be treated as commutative or symmetric, and allows their arguments to be rearranged in trying to match patterns.

Some attributes that can be assigned to functions.

Plus has attributes Orderless and Flat, as well as others.

In[5]:= Attributes[Plus]

Out[5]=

This defines q to be an orderless or commutative function.

In[6]:= SetAttributes[q, Orderless]

The arguments of q are automatically sorted into order.

In[7]:= q[b, a, c]

Out[7]=

Mathematica rearranges the arguments of q functions to find a match.

In[8]:= f[q[a, b], q[b, c]] /.
f[q[x_, y_], q[x_, z_]] -> p[x, y, z]

Out[8]=

In addition to being orderless, functions like Plus and Times also have the property of being flat or associative. This means that you can effectively "parenthesize" their arguments in any way, so that, for example, x + (y + z) is equivalent to x + y + z, and so on.

Mathematica takes account of flatness in matching patterns. As a result, a pattern like g[x_ + y_] can match g[a + b + c], with x a and y (b + c).

The argument of g is written as a + (b + c) so as to match the pattern.

In[9]:= g[a + b + c] /. g[x_ + y_] -> p[x, y]

Out[9]=

If there are no other constraints, Mathematica will match x_ to the first element of the sum.

In[10]:= g[a + b + c + d] /. g[x_ + y_] -> p[x, y]

Out[10]=

This shows all the possible matches.

In[11]:= ReplaceList[g[a + b + c], g[x_ + y_] -> p[x, y]]

Out[11]=

Here x_ is forced to match b + d.

In[12]:= g[a + b + c + d, b + d] /. g[x_ + y_, x_] -> p[x, y]

Out[12]=

Mathematica can usually apply a transformation rule to a function only if the pattern in the rule covers all the arguments in the function. However, if you have a flat function, it is sometimes possible to apply transformation rules even though not all the arguments are covered.

This rule applies even though it does not cover all the terms in the sum.

In[13]:= a + b + c /. a + c -> p

Out[13]=

This combines two of the terms in the sum.

In[14]:= u[a] + u[b] + v[c] + v[d] /. u[x_] + u[y_] -> u[x + y]

Out[14]=

Functions like Plus and Times are both flat and orderless. There are, however, some functions, such as Dot, which are flat, but not orderless.

Both x_ and y_ can match any sequence of terms in the dot product.

In[15]:= a . b . c . d . a . b /. x_ . y_ . x_ -> p[x, y]

Out[15]=

This assigns the attribute Flat to the function r.

In[16]:= SetAttributes[r, Flat]

Mathematica writes the expression in the form r[r[a, b], r[a, b]] to match the pattern.

In[17]:= r[a, b, a, b] /. r[x_, x_] -> rp[x]

Out[17]=

Mathematica writes this expression in the form r[a, r[r[b], r[b]], c] to match the pattern.

In[18]:= r[a, b, b, c] /. r[x_, x_] -> rp[x]

Out[18]=

In an ordinary function that is not flat, a pattern such as x_ matches an individual argument of the function. But in a function f[a, b, c, ... ] that is flat, x_ can match objects such as f[b, c] which effectively correspond to a sequence of arguments. However, in the case where x_ matches a single argument in a flat function, the question comes up as to whether the object it matches is really just the argument a itself, or f[a]. Mathematica chooses the first of these cases if the function carries the attribute OneIdentity, and chooses the second case otherwise.

This adds the attribute OneIdentity to the function r.

In[19]:= SetAttributes[r, OneIdentity]

Now x_ matches individual arguments, without r wrapped around them.

In[20]:= r[a, b, b, c] /. r[x_, x_] -> rp[x]

Out[20]=

The functions Plus, Times and Dot all have the attribute OneIdentity, reflecting the fact that Plus[x] is equivalent to x, and so on. However, in representing mathematical objects, it is often convenient to deal with flat functions that do not have the attribute OneIdentity.