Audio Processing
The Wolfram Language provides built-in support for both programmatic and interactive audio processing, fully integrated with other powerful mathematical and algorithmic capabilities. You can process audio objects by applying linear and nonlinear filters, add effects, and analyze them using audio-specific functions or by exploiting the extensive integration with the rest of the Wolfram Language.
| LowpassFilter[audio,ωc] | apply a lowpass filter with a cutoff frequency ωc to audio |
| HighpassFilter[audio,ωc] | apply a highpass filter with a cutoff frequency ωc to audio |
| WienerFilter[audio,r] | apply Wiener filter with a range of r samples to audio |
| MeanFilter[audio,r] | apply mean filter with a range of r samples to audio |
| TotalVariationFilter[audio] | apply total variation filter to audio |
| GaussianFilter[audio, r] | apply Gaussian filter with a range of r samples to audio |
Many of the filtering functions present in the Wolfram Language can be immediately used on audio objects. In many cases, it is possible to specify the cutoff frequency as a frequency Quantity.
a = ExampleData[{"Audio", "Apollo11ReturnSafely"}, "Audio"]lp = LowpassFilter[a, Quantity[800, "Hertz"], 101]hp = HighpassFilter[a, Quantity[1600, "Hertz"], 101]bs = BandstopFilter[a, {Quantity[800, "Hertz"], Quantity[1600, "Hertz"]}, 91]Periodogram[{a, bs, lp, hp}, 2000, PlotRange -> {{0, 3000}, Automatic}, Frame -> True, ImageSize -> Medium, PlotLegends -> {"Original", "Bandstop", "Lowpass", "Highpass"}]Use WienerFilter to denoise a recording:
a = ExampleData[{"Audio", "Apollo11ReturnSafely"}, "Audio"]WienerFilter[a, 25]Spectrogram[#, ImageSize -> Small, FrameTicks -> None]& /@ {a, %}Discrete-time transfer function models can be used to filter an audio object using RecurrenceFilter.
| RecurrenceFilter[tf,audio] | uses a discrete-time filter defined by the TransferFunctionModel tf |
| BiquadraticFilterModel[{"type",spec}] | creates a biquadratic filter of a given {"type",spec} |
| ButterworthFilterModel[{"type",spec}] | creates a Butterworth filter of a given {"type",spec} |
| TransferFunctionModel[m,s] | represents the model of the transfer-function matrix m with complex variable s |
| ToDiscreteTimeModel[lsys,τ] |
gives the discrete-time approximation, with sampling period
τ
, of the continuous-time systems models
lsys
|
The simplest way to use one of the analog (continuous-time) filter models is to discretize the transfer function using ToDiscreteTimeModel and apply the result to an audio object using RecurrenceFilter.
filterModel = BiquadraticFilterModel[{ω, q}]discreteFilter = ToDiscreteTimeModel[filterModel, 1 / 22050, z, Method -> {"BilinearTransform", "CriticalFrequency" -> ω}]a = \!\(\*AudioBox[""]\);RecurrenceFilter[discreteFilter /. {ω -> 1000 2 Pi, q -> 7}, a]A discrete transfer function can be created using TransferFunctionModel and applied to an audio object with RecurrenceFilter.
Define a comb filter using TransferFunctionModel and apply it to an audio object:
combFilterModel[f_, α_, sr : _ : 22050] := TransferFunctionModel[{{1 / ( 1 - α z^-Round[sr / f])}}, z, SamplingPeriod -> (1/sr)]combFilterModel[150, α]RecurrenceFilter[combFilterModel[150, -.9], a]| AudioTimeStretch[audio,r] | apply time stretching by the specified factor r to audio |
| AudioPitchShift[audio,r] | apply pitch shifting by the specified factor r to audio |
| AudioReverb[audio] | apply a reverberation effect to audio |
| AudioDelay[audio,delay] | apply a delay effect with delay time delay to audio |
| AudioChannelMix[audio,desttype] | mix the channel of audio to the specified desttype |
Use pitch shifting and time stretching to independently modify pitch and duration of an audio signal.
a = ExampleData[{"Audio", "MaleVoice"}, "Audio"]AudioTimeStretch[a, 1.5]AudioPitchShift[a, Quantity[2, IndependentUnit["semitones"]]]Delay and reverberation effects can be used to immerse a recording in a virtual environment or to produce special effects.
AudioDelay[a, .7, .8, .4, PaddingSize -> 2]AudioTrim[AudioReverb[a, ExampleData[{"Audio", "IRStMarysChurch"}]], 10]Perform Karplus–Strong synthesis by adding a short delay with a high feedback value to a burst of noise. This will simulate the sound of a vibrating string:
freq = 60;
feedback = 0.99;
AudioDelay[AudioGenerator["Pink", .01], 1 / freq, feedback, 1, PaddingSize -> 5, Method -> {"LowpassCutoff" -> Quantity[8000, "Hertz"]}]Downmixing and upmixing to an arbitrary number of channels can be achieved using AudioChannelMix.
a//AudioChannelsAudioChannelMix[a, "Mono"]//AudioChannelsAudioChannelMix[a, 3]//AudioChannelsIt is possible to alter a recording by taking advantage of performing arithmetic operations on the Audio object. All Wolfram Language operators and functions with attributes NumericFunction or Listable are overloaded to work with audio objects.
Apply a smooth distortion to an audio object using the Tanh function:
a = AudioNormalize[Import["ExampleData/Rule30.wav"]]Tanh[5a]Use the ChebyshevT function to obtain a "waveshaper" effect:
ChebyshevT[10, a]a×\!\(\*AudioBox[""]\)Analysis of the Whole Signal
| AudioMeasurements[audio,"prop"] | compute the property "prop" for the entire audio |
Both time domain and frequency domain properties can be measured with AudioMeasurements. The properties are computed on the average sample values over the channels of the audio object.
AudioMeasurements[ExampleData[{"Audio", "Drums"}], {"MinMax", "Mean", "StandardDeviation", "RMSAmplitude", "ZeroCrossings"}, "Dataset"]AudioMeasurements[ExampleData[{"Audio", "Drums"}], {"SpectralCentroid", "SpectralFlatness", "SpectralRollOff", "SpectralSpread"}, "Dataset"]a = AudioGenerator["Sin"];Moment[a, 2]Entropy[a]Unlike AudioMeasurements, overloaded functions are applied to the flattened version of the data. If the input is a multichannel audio object, the sample values from all channels will be flattened in a single array.
AssociationThread[{"MinMax", "Mean", "StandardDeviation", "RMSAmplitude", "ZeroCrossings"} ->
Through[{MinMax, Mean, StandardDeviation, Sqrt@Mean[# ^ 2]&, Total@CrossingDetect[#, CornerNeighbors -> None]&}@ExampleData[{"Audio", "Drums"}]]
]//DatasetAnalysis of the Partitioned Signal
In addition to global properties of audio objects, it is also possible to compute measurements locally.
| AudioLocalMeasurements[audio,"prop"] | compute the property "prop" locally for partitions of audio |
| AudioIntervals[audio,crit] | find the intervals of audio for which the criterion crit is satisfied |
In AudioLocalMeasurements, properties are computed locally. The signal is partitioned according to the PartitionGranularity specification, and the requested property is computed on each partition. The result is returned as a TimeSeries whose timestamps correspond to the center of each partition.
a = \!\(\*AudioBox[""]\);res = AudioLocalMeasurements[a, "RMSAmplitude", PartitionGranularity -> {Quantity[40, "Milliseconds"], Quantity[1, "Milliseconds"]}];
Show[AudioPlot[a], ListLinePlot[res, PlotStyle -> Red]]The result of AudioLocalMeasurements or AudioMeasurements can be used as an input for other functionality in the Wolfram Language.
Use the "SpectralCentroid" and "SpectralSpread" measurements to find clusters of similar audio objects in a list:
samples = {\!\(\*AudioBox[""]\), \!\(\*AudioBox[""]\), \!\(\*AudioBox[""]\), \!\(\*AudioBox[""]\), \!\(\*AudioBox[""]\), \!\(\*AudioBox[""]\), \!\(\*AudioBox[""]\), \!\(\*AudioBox[""]\), \!\(\*AudioBox[""]\)};
props = AudioMeasurements[#, {"SpectralCentroid", "SpectralSpread"}, "List"]& /@ samples;
clusters = FindClusters[props -> props]ListPlot[Partition[props, 1], PlotMarkers -> samples, ImageSize -> 300, Prolog -> ({Opacity[.3, RGBColor[1, 0.5, 0.5]], Disk[Mean@#, 400]& /@ clusters}), PlotRange -> {{00, 4000}, {0, 4000}}, AspectRatio -> 1]Use the MFCC measurement as a feature to compute the distance between various elements of the ExampleData["Audio"] collection:
list = Select[ExampleData["Audio"], ExampleData[#, "Duration"] < 10&];
a = ConformAudio[AudioNormalize@AudioChannelMix[#, 1]& /@ ExampleData[#, "Audio"]& /@ list, SampleRate -> 11025];mfcc = AudioLocalMeasurements[#, "MFCC", PartitionGranularity -> {.05, .01}]["Values"]& /@ a;ticks = Thread[{Range[Length@list], Text /@ list[[All, 2]]}];MatrixPlot[DistanceMatrix[mfcc], ImageSize -> Medium, FrameTicks -> {ticks, Apply[Rotate[#, Pi / 2]&, ticks, {2}]}]Using AudioIntervals allows you to extract intervals on which a user-defined criterion is satisfied.
a = ExampleData[{"Audio", "NoisyTalk"}, "Audio"];
nonVoicedIntervals = AudioIntervals[a, #RMSAmplitude < .02 && #SpectralFlatness > .0001&, .1, PartitionGranularity -> {.06, .01}]AudioPlot[a, Epilog -> {RGBColor[1, 0, 0, .3], Rectangle[{#[[1]], -1}, {#[[2]], 1}]& /@ nonVoicedIntervals}, ImageSize -> Medium]High-Level Analysis
It is possible to use neural networks–based functions to gain a deeper insight into the contents of a signal.
| SpeechRecognize[audio] | recognize the speech in audio and return it as a string |
| PitchRecognize[audio] | recognize the main pitch in audio |
| AudioIdentify[audio] | identify what audio is the recording of |
a = SpeechSynthesize["hello i am a computer"]SpeechRecognize[a]PitchRecognize[a]//ListLinePlotAudioIdentify[a]All the machine learning functions are aware of Audio objects and perform their computations starting with a semantically significant feature extraction.
| Classify[{audio1class1,audio2class2,…}] | generate a ClassifierFunction[…] trained on the examples and classes given |
| FeatureExtraction[{audio1,audio2,…}] | generate a FeatureExtractorFunction[…] trained on the examples given |
| FeatureSpacePlot[{audio1,audio2,…}] | plot the features extracted from audioi as a scatter plot |
This preprocessing transforms each audio object in a fixed-size vector, so that they can be easily compared.
data = Join@@Table[Thread[WebAudioSearch[instr, "Samples", Sequence[Slot["Duration"] < 5&, MaxItems -> 40]] -> instr], {instr, {"acoustic guitar", "drums", "trumpet"}}];
{train, test} = TakeDrop[RandomSample[data], 90];cl = Classify[train]ClassifierMeasurements[cl, test, "Report"]Plot the features of a audio collection using FeatureSpacePlot.
Plot a list of signals in a semantically meaningful space with FeatureSpacePlot:
FeatureSpacePlot[ExampleData[#] -> #[[2]]& /@ ExampleData["Audio"], LabelingFunction -> Callout]Neural Networks
The Audio object is tightly integrated in the powerful neural networks framework. NetEncoder provides an easy entry point into neural nets for various high-level constructs such as the Audio object.
| "Audio" | encode a signal as a waveform |
| "AudioSpectrogram" | encode a signal as a spectrogram |
| "AudioMFCC" | encode a signal as a mel spectrogram |
Some examples of audio NetEncoder.
Different encoders can be used to compute various kinds of features. Some maintain all of the information of the original signal (like "Audio" and "AudioSTFT"), while others provide a compromise between discarding some information but dramatically reducing the dimensionality (like "AudioMFCC").
a = ExampleData[{"Audio", "Bird"}, "Audio"]Labeled[ListLinePlot[First@Transpose@Normal[NetEncoder["Audio"][a]]], "Audio"]Labeled[MatrixPlot[Log@Transpose@Normal[NetEncoder["AudioSpectrogram"][a]], DataReversed -> {True, False}], "AudioSpectrogram"]Labeled[MatrixPlot[Transpose@Normal[NetEncoder["AudioMFCC"][a]], DataReversed -> {True, False}], "AudioMFCC"]Using the encoders, it is easy to train networks from scratch to solve audio-related tasks and produce measurements of the resulting performance.
| NetTrain[net,data] | train the network net on the dataset data |
| NetChain[{layer1,layer2,…}] | specify a net in which the output of layeri is connected to the input of layeri+1 |
| NetMeasurements[net,data,measurement] | compute the requested measurement for the net evaluated on data |
Use NetChain and NetGraph to create networks of arbitrary topology, and leverage sequence-focused layers such as GatedRecurrentLayer and LongShortTermMemoryLayer to analyze variable length signals.
net = NetChain[{GatedRecurrentLayer[64], GatedRecurrentLayer[64], GatedRecurrentLayer[10], AggregationLayer[Mean, 1], SoftmaxLayer[]}, "Input" -> NetEncoder["AudioMFCC"], "Output" -> NetDecoder[{"Class", Range[0, 9]}]]trainedNet = NetTrain[net, ResourceData["Spoken Digit Commands"], ValidationSet -> Scaled[.05]]NetMeasurements[trainedNet, ResourceData["Spoken Digit Commands", "TestDataset"], {"Accuracy", "ConfusionMatrixPlot"}]