WOLFRAM

Wolfram Language & System Documentation Center

Kronecker Decomposition

TransferFunctionModel supports improper transfer functions. When converted to the time domain, an improper transfer function creates a descriptor StateSpaceModel. The proper and polynomial parts of the transfer function can be decoupled in the state-space model with KroneckerModelDecomposition.

Wolfram Language code: {poly, proper} = {Subscript[a, 2]s ^ 2 + Subscript[a, 1]s + Subscript[a, 0], (k(s - Subscript[z, 1])/(Subscript[τ, 1 ]s + 1)(Subscript[τ, 2 ]s + 1))};
Wolfram Language code: tfm = TransferFunctionModel[poly + proper, s];
Wolfram Language code: ssm = Simplify@Last@KroneckerModelDecomposition[StateSpaceModel[tfm]]
The descriptor matrix is block diagonal with an identity matrix for the states of the proper subsystem and a nilpotent matrix for the states of the polynomial subsystem:
Wolfram Language code: Simplify@TransferFunctionModel[SystemsModelExtract[ssm, All, All, 1 ;; 2], s]
Wolfram Language code: TransferFunctionModel[SystemsModelExtract[ssm, All, All, 3 ;; 5], s]
The solution to the full system is the sum of the solutions to the two parts:
Wolfram Language code: params = {k -> 1.5, Subscript[τ, 1] -> 1 / 10, Subscript[τ, 2] -> 1 / 4, Subscript[z, 1] -> 1, Subscript[a, 2] -> 1, Subscript[a, 1] -> 1, Subscript[a, 0] -> 2};
Wolfram Language code: polyresponse = OutputResponse[TransferFunctionModel[poly, s], Sin[t], t]; properresponse = OutputResponse[TransferFunctionModel[proper, s], Sin[t], t]; totalresponse = OutputResponse[ssm, Sin[t], t];
Wolfram Language code: Simplify[polyresponse + properresponse - totalresponse]
Wolfram Language code: Plot[Evaluate[{polyresponse, properresponse, totalresponse} /. params], {t, 0, 20}, PlotLegends -> {"poly", "proper", "total"}]