WOLFRAM

Wolfram 语言与系统参考资料中心

How to| 改变二维散点图中点的类型和颜色

Wolfram 语言中创建的图形的默认设置在大多数情况下是充分的，而几乎图形的每个方面事实上都是用户可以自定义的. 除了可以允许用户改变二维图形中的点的大小，Wolfram 语言也允许用户改变点的标号的颜色和类型.

This page requires that JavaScript be enabled in your browser.
Learn how »

Wolfram 语言允许用户通过 PlotMarkers 选项改变用作图形中点的记号的类型.

首先，定义用于绘制的一些数据：

Wolfram Language code: testData = Prime[Range[25]]

使用 ListPlot 和 PlotMarkers 绘制带有星号表示的数据点的数据：

Wolfram Language code: ListPlot[testData, PlotMarkers -> "*"]

Wolfram 语言包含许多特殊字符和符号，它们也可以用作图形中的点. 用户可以从 特殊字符 面板（位于 面板 菜单中）访问它们，或者使用字符的键盘别名. 若要查看某个字符的键盘别名，只要把鼠标移到面板中相应的位置上即可.

用户也可以从头开始创建自己的图形标号：

Wolfram Language code: marker1 = Graphics[{Blue, Disk[]}]

用户可以使用刚刚创建的图形作为图形标记，其大小为 .07：

Wolfram Language code: ListPlot[testData, PlotMarkers -> {marker1, .07}]

若要改变图形中点的颜色，可以使用 PlotStyle 选项. 下面，指定颜色 Red：

Wolfram Language code: ListPlot[testData, PlotMarkers -> "*", PlotStyle -> Red]

任何被 Wolfram 语言支持的颜色可以用来对图形中的点着色.

在这个例子中，RGBColor 和 Manipulate 一起使用，以允许颜色的动态设置. 移动滑杆来对 r、g 和 b 设置不同的值：

Wolfram Language code: Manipulate[ListPlot[testData, PlotMarkers -> "*", PlotStyle -> RGBColor[r, g, b]], {r, 0, 1, Appearance -> "Labeled"}, {g, 0, 1, Appearance -> "Labeled"}, {b, 0, 1, Appearance -> "Labeled"}, SaveDefinitions -> True]
    

对图形添加额外的数据集并对其进行样式化处理仅需要少量额外工作.

首先，定义一些用户要绘制的数据集：

Wolfram Language code: testData1 = Table[{x, Sqrt[x]}, {x, 0, 4, .2}]; testData2 = Table[{x, x^1 / 3}, {x, 0, 4, .2}]; testData3 = Table[{x, x^1 / 5}, {x, 0, 4, .18}];

使用 ListPlot 绘制数据：

Wolfram Language code: ListPlot[{testData1, testData2, testData3}]

使用 PlotMarkers 指定每个数据集的点的类型和大小. PlotMarkers 的右边列表中点类型和大小指定的位置对应于列表中相同位置的数据集，即 ListPlot 的第一个参数.

在下面的图形中，{●,10} 对数据集 testData1 等指定点的类型和大小. 这些记号来自 特殊字符 面板：

Wolfram Language code: ListPlot[{testData1, testData2, testData3}, PlotMarkers -> {{●, 10}, {▲, 10}, {■, 10}}]

通过使用具有相似语法的 PlotStyle 从默认方案改变颜色：

Wolfram Language code: ListPlot[{testData1, testData2, testData3}, PlotMarkers -> {{●, 10}, {▲, 10}, {■, 10}}, PlotStyle -> {Red, Green, Blue}]
    

Wolfram 语言也允许用户改变在三维图形中的点的颜色，就像由 ListPointPlot3D 产生的一样.

例如，用户可以使用 PlotStyle 来设置由 ListPointPlot3D 产生的点的颜色：

Wolfram Language code: ListPointPlot3D[Table[Sin[j ^ 2 + i], {i, 0, Pi, 0.1}, {j, 0, Pi, 0.1}], PlotStyle -> Orange]

用户也可以在三维图形中使用颜色梯度. 使用 ColorFunction 的一个方法是在 方向实现一个预定义的颜色梯度：

Wolfram Language code: ListPointPlot3D[Table[Sin[j ^ 2 + i], {i, 0, Pi, 0.1}, {j, 0, Pi, 0.1}], ColorFunction -> "Rainbow"]