WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

GeometricStylingRules

GeometricSceneのオプションで，GeometricScene内の構造のスタイリング方法を指定する．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
テクニカルノート
履歴
引用書式

GeometricStylingRules

GeometricStylingRules

GeometricSceneのオプションで，GeometricScene内の構造のスタイリング方法を指定する．

詳細

  • GeometricStylingRulesは，通常，GeometricScene内の構造のハイライトに使われる．
  • GeometricStylingRulesの設定は規則のリストとして入力される．各規則の左辺には以下の可能性が置かれる．
  • "PointStyle"点をハイライト
    "StylingPatterns"第2引数の仮説をハイライト
    "ConclusionStyle"第3引数の結論をハイライト
  • "PointStyle"の設定としては以下が使える．
  • Automatic点の自動スタイル付け
    None点は表示しない
    {d1,d2,…}スタイリング指示子のリスト
  • "StylingPatterns"の設定としては以下が使える．
  • None追加のスタイリングなし
    {p1d1,p2d2,…}構造 piにスタイリング指示子 diを使う
  • スタイリング規則のリストの piはGeometricSceneに入力された幾何学構造にマッチする任意のパターン，diはスタイリング指示子の任意のリストでよい．
  • "ConclusionStyle"の設定としては以下が使える．
  • Automatic結論を自動的にスタイリング
    None結論に追加のスタイリングなし
    {d1,d2,…}スタイリング指示子のリスト

例題

すべて開く すべて閉じる

例  (3)

点を茶色にする：

Wolfram Language code: RandomInstance[GeometricScene[{a, b, c, d}, {Polygon[{a, b, c, d}]}, GeometricStylingRules -> {"PointStyle" -> Brown}]]

すべての緑色にする：

Wolfram Language code: RandomInstance[GeometricScene[{a, b, c}, {CircleThrough[{a, b, c}], Triangle[{a, b, c}]}, {}, GeometricStylingRules -> {"StylingPatterns" -> {_ -> Darker[Green]}}]]

結論で言及された三角形を紫色でハイライトする：

Wolfram Language code: RandomInstance[GeometricScene[{a, b, c}, {GeometricStep[{Line[{a, b}]}], GeometricStep[{CircleThrough[{b, c}, a], CircleThrough[{a, c}, b]}], GeometricStep[{Triangle[{a, b, c}]}]}, {GeometricAssertion[Triangle[{a, b, c}], "Regular"]}, GeometricStylingRules -> {"ConclusionStyle" -> {Purple}}]]

スコープ  (6)

点のラベルの大きさとフォントを指定する：

Wolfram Language code: RandomInstance[GeometricScene[{a, b, c}, {Triangle[{a, b, c}]}, {}, GeometricStylingRules -> {"PointStyle" -> Directive[PointSize[0.1], FontSize -> 40, FontFamily -> "Comic Sans MS"]}]]

点のラベルを削除する：

Wolfram Language code: RandomInstance[GeometricScene[{a, b, c}, {Triangle[{a, b, c}]}, {}, GeometricStylingRules -> {"PointStyle" -> None}]]

FindGeometricConjecturesが返す結論のみにスタイル付けする：

Wolfram Language code: FindGeometricConjectures[GeometricScene[{a, b, c, o}, {Triangle[{a, b, c}], CircleThrough[{a, b, c}, o], o == Midpoint[{a, c}]}, {PlanarAngle[{a, b, c}] == 90Degree}, GeometricStylingRules -> {"ConclusionStyle" -> {Green}}]]

すべての結論にスタイル付けできる訳ではない：

Wolfram Language code: RandomInstance[GeometricScene[{a, b, c, o}, {Triangle[{a, b, c}], CircleThrough[{a, b, c}, o], o == Midpoint[{a, c}]}, {PlanarAngle[{a, c, b}] + PlanarAngle[{b, a, c}] == 90Degree}, GeometricStylingRules -> {"ConclusionStyle" -> {Green}}]]

第2引数で作成されたスタイリング指示子はオプションによる指示子より優先順位が高い：

Wolfram Language code: RandomInstance[GeometricScene[{a, b, c}, {Style[CircleThrough[{a, b, c}], Blue], Triangle[{a, b, c}]}, {}, GeometricStylingRules -> {"StylingPatterns" -> {_ -> Red}}]]

スタイリング規則は遅延規則でもよい：

Wolfram Language code: RandomInstance[GeometricScene[{a, b, c, d, e, o}, {Polygon[{a, b, c, d, e}], p1 == Triangle[{a, b, o}], p2 == Triangle[{b, o, c}], p3 == Triangle[{c, d, o}], p4 == Triangle[{d, o, e}], p5 == Triangle[{e, o, a}], GeometricAssertion[{p1, p2, p3, p4, p5}, "Similar"] }, GeometricStylingRules -> {"StylingPatterns" -> {_ :> RandomColor[]}} ]]

特性と関係  (1)

結論のスタイリングが指定されていない場合，FindGeometricConjecturesが返す結論はオレンジ色でハイライトされる：

Wolfram Language code: scene = FindGeometricConjectures[GeometricScene[{a, b, c}, {GeometricStep[{Line[{a, b}]}], GeometricStep[{CircleThrough[{b, c}, a], CircleThrough[{a, c}, b]}], GeometricStep[{Triangle[{a, b, c}]}]}]]

ハイライトする色をマジェンタに変える：

Wolfram Language code: GeometricScene[scene, GeometricStylingRules -> {"ConclusionStyle" -> Magenta}]

結論からすべてのスタイリングを削除する：

Wolfram Language code: GeometricScene[scene, GeometricStylingRules -> {"ConclusionStyle" -> None}]

考えられる問題  (1)

デフォルトで，二次元領域は完全に透明には描かれないので，そのような領域2つの共有部分は指定された色にはならないかもしれない：

Wolfram Language code: RandomInstance[GeometricScene[{{a, b}, {d}}, {Disk[a, d], Disk[b, d], EuclideanDistance[a, b] == d}, GeometricStylingRules -> {"StylingPatterns" -> {Disk[a, d] -> Green, Disk[b, d] -> Blue}}]]

おもしろい例題  (3)

「Le Petit Caporal」自身を使ったナポレオン(Napoleon)の定理：

Wolfram Language code: RandomInstance[Append[Entity["GeometricScene", "NapoleonsTheorem"]["Scene"], GeometricStylingRules -> {"StylingPatterns" -> {_Triangle -> PatternFilling[[image], 100]}}]]

それ自体の小さめの表現を使ってBarrowの方程式にスタイル付けする：

Wolfram Language code: With[{s = Entity["GeometricScene", "BarrowsEquality"]["Scene"]}, Append[RandomInstance[s], GeometricStylingRules -> {"StylingPatterns" -> {_Triangle -> PatternFilling[Rasterize[RandomInstance[s]], 50]}}]]

シーンに動的にスタイル付けする：

Wolfram Language code: RandomInstance[GeometricScene[{a, b, c}, {Disk[a, EuclideanDistance[b, c] / 2], Disk[b, EuclideanDistance[a, c] / 2], Disk[c, EuclideanDistance[a, b] / 2], Triangle[{a, b, c}]}, GeometricStylingRules -> {"StylingPatterns" -> {_Triangle -> Dynamic[PatternFilling[{"XGridPoint", RandomColor[]}, RandomReal[{0, 20}]], UpdateInterval -> 1], _Disk -> Dynamic[PatternFilling[{"Grain", RandomColor[]}, RandomReal[{0, 20}]], UpdateInterval -> 1 / Pi]}}]]
Wolfram Research (2022), GeometricStylingRules, Wolfram言語関数， https://reference.wolfram.com/language/ref/GeometricStylingRules.html.

テキスト

Wolfram Research (2022), GeometricStylingRules, Wolfram言語関数， https://reference.wolfram.com/language/ref/GeometricStylingRules.html.

CMS

Wolfram Language. 2022. "GeometricStylingRules." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/GeometricStylingRules.html.

APA

Wolfram Language. (2022). GeometricStylingRules. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/GeometricStylingRules.html

BibTeX

@misc{reference.wolfram_2026_geometricstylingrules, author="Wolfram Research", title="{GeometricStylingRules}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/GeometricStylingRules.html}", note=[Accessed: 31-July-2026]}

BibLaTeX

@online{reference.wolfram_2026_geometricstylingrules, organization={Wolfram Research}, title={GeometricStylingRules}, year={2022}, url={https://reference.wolfram.com/language/ref/GeometricStylingRules.html}, note=[Accessed: 31-July-2026]}