Wolfram言語＆システムドキュメントセンター

HistogramTransformInterpolation

HistogramTransformInterpolation[{x₁,x₂,…}]

変換された値がほぼ均等に配布されるような関数を求める．

HistogramTransformInterpolation[{x₁,x₂,…},ref]

が分布 ref に従って配布されるような関数を求める．

HistogramTransformInterpolation[{x₁,x₂,…},ref,n]

等間隔の n 個の分位点を持つ関数を求める．

HistogramTransformInterpolation[image,…]

image のヒストグラムを整形する関数を求める．

HistogramTransformInterpolation

HistogramTransformInterpolation[{x₁,x₂,…}]

変換された値がほぼ均等に配布されるような関数を求める．

HistogramTransformInterpolation[{x₁,x₂,…},ref]

が分布 ref に従って配布されるような関数を求める．

HistogramTransformInterpolation[{x₁,x₂,…},ref,n]

等間隔の n 個の分位点を持つ関数を求める．

HistogramTransformInterpolation[image,…]

image のヒストグラムを整形する関数を求める．

詳細

HistogramTransformInterpolationは，画像ヒストグラムの形状を変更することによってヒストグラム変換を実行する関数を返す．これは通常，ヒストグラムの均等化またはマッチングに使用される．
HistogramTransformInterpolationは，各チャンネルについて，それぞれがInterpolatingFunctionで表される関数 f または関数のリストを返す．

HistogramTransformを使って対応する関数を使ったヒストグラム変換を行う．
HistogramTransformInterpolation[image]は，事実上，画素値の累積分布(CDF)である．この関数は画素値に適用されるとヒストグラムがほぼ平坦な画像を作成する．
HistogramTransformInterpolation[image,ref]は，変換された画素値が ref とほぼ同じ分布になるような関数を求める．
基準 ref は，他の画像，データ集合あるいは分布でよい．
HistogramTransformInterpolationは，2Dおよび3Dの画像，また，任意階数のデータ集合のリストに使うことができる．
HistogramTransformInterpolation[{data₁,data₂,…},…]はそれぞれのデータ集合に対応する関数のリストを与える．
HistogramTransformInterpolation[image,ref]では256個の分位点が使われる．
HistogramTransformInterpolation[data,ref,Automatic]のとき，分位点の数はHistogram[data]で使われるビンの数に等しい．

例題

すべて開くすべて閉じる

例 (4)

与えられたデータ集合のサンプルを均等に配布する関数を求める：

Wolfram Language code:

data = RandomVariate[RayleighDistribution[1], 2000];
func = HistogramTransformInterpolation[data]

Wolfram Language code: Histogram /@ {data, func[data]}

データ集合のヒストグラムを正規分布の確率密度関数にマッチするように整形する：

Wolfram Language code:

data = RandomVariate[RayleighDistribution[1], 2000];
Histogram[data]

Wolfram Language code:

dist = NormalDistribution[0, .2];
func = HistogramTransformInterpolation[data, dist]

Wolfram Language code: Histogram[func[data], Automatic, "PDF"]

画像のヒストグラムを平坦化する関数を求める：

Wolfram Language code: HistogramTransformInterpolation[img = [image]]

Wolfram Language code: ImageApply[%, img]

3D画像のヒストグラムを均質化する関数を求める：

Wolfram Language code: img = [image];

Wolfram Language code: HistogramTransformInterpolation[img]

Wolfram Language code: ImageApply[%, img]

スコープ (3)

データ集合のリストの平坦化関数を求める：

Wolfram Language code:

HistogramTransformInterpolation[
	Table[RandomVariate[dist, 1000], {dist, {NormalDistribution[.5, .2], UniformDistribution[{0, 1}]}}]]

Wolfram Language code: Plot[Quiet[#[t]]& /@ %, {t, 0, 1}]

各カラーチャンネルのヒストグラム整形関数を求める：

Wolfram Language code: funs = HistogramTransformInterpolation[img = [image]]

チャンネルごとに関数を適用する：

Wolfram Language code: MapThread[ImageApply, {funs, ColorSeparate@img}]//ColorCombine

変換関数を求める際に，さまざまな数の変位値を使う：

Wolfram Language code:

data = RandomVariate[NormalDistribution[], 1000];
funs = Table[HistogramTransformInterpolation[data, UniformDistribution[{0, 1}], n], {n, {4, 8, 16, 32}}];

Wolfram Language code: Histogram[#[data]]& /@ funs

アプリケーション (1)

局所的に適応可能なヒストグラムの均質化 (1)

局所的に適応可能なヒストグラムを完全に均質化することで，さまざまな強度レベルを持つ画像ではより魅力的な結果が与えられることがあるが，より長い時間がかかる：

Wolfram Language code:

img = [image];
radius = 10;

Wolfram Language code:

center = radius + 1;
(full = ImageFilter[
	HistogramTransformInterpolation[Flatten@#][#[[center, center]]]&, img, radius])//AbsoluteTiming

Wolfram Language code: {full, ImageApply[HistogramTransformInterpolation[img], img]}

重なり合わないブロックについて計算された均質化関数間の双一次補間の方がより速く近似できる：

Wolfram Language code:

HistogramTransformationWeightedLocalAdaptive[img_, radius_] := 
	Module[{funs, nodes, w, h, fun, fi}, 
	funs = Map[HistogramTransformInterpolation, ImagePartition[img, {2 * radius + 1}], {2}];
	{w, h} = ImageDimensions@img;
	nodes = Map[
	Mean@Flatten[N@ImageData[#, Automatic], 1]&, 
	ImagePartition[
	Image[Array[{#1, #2}&, {h, w}], "Bit16"], 
	{2 * radius + 1}], 
	{2}];
	nodes = ArrayPad[nodes, {{1, 1}, {1, 1}}, "Fixed"];
	nodes[[All, {1, -1}, 2]] = {1, w};
	nodes[[{1, -1}, All, 1]] = {1, h};
	funs = ArrayPad[funs, 1, "Fixed"];
	fi = Interpolation[Thread[{Round@Flatten[nodes, 1], Table[f[#], {f, Flatten@funs}]}], InterpolationOrder -> 1];
	fun[v_, {r_, c_}] := Evaluate[fi[r, c]]&[v];
	Quiet@ImageApplyIndexed[fun, img]
	];

Wolfram Language code: (partial = HistogramTransformationWeightedLocalAdaptive[img, radius])//AbsoluteTiming

特性と関係 (2)

HistogramTransformInterpolationを使ってHistogramTransformで使用する変換関数を求めることができる：

Wolfram Language code:

i = [image];
f = HistogramTransformInterpolation[i]

Wolfram Language code: ImageApply[f, i] == HistogramTransform[i]

HistogramTransformInterpolationの結果は，閉形式の解が存在する場合はこれを近似する：

Wolfram Language code:

dist1 = TruncatedDistribution[{0, 1}, NormalDistribution[.5, .2]];
dist2 = WeibullDistribution[1.5, 1];
exact = Composition[InverseCDF[dist2], CDF[dist1]];

Wolfram Language code: fun = HistogramTransformInterpolation[RandomVariate[dist1, 10000], dist2];

Wolfram Language code: Plot[exact[x] - Quiet@fun[x], {x, 0, 1}]

Top

その他のラーニングリソース

テクニカルサポート

データサイエンス，金融，ビジネス

工学

科学とテクノロジー

教育のためのテクノロジー

教育イニシアチブ

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

HistogramTransformInterpolation

詳細

例題

例 (4)

スコープ (3)

アプリケーション (1)

局所的に適応可能なヒストグラムの均質化 (1)

特性と関係 (2)

テキスト

CMS

APA

BibTeX

BibLaTeX

HistogramTransformInterpolation

詳細

例題

例 (4)

スコープ (3)

アプリケーション (1)

局所的に適応可能なヒストグラムの均質化 (1)

特性と関係 (2)

関連項目

関連するガイド

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX