Mean
Mean
詳細
- Meanは期待値あるいは平均としても知られている．
- Meanはデータあるいは分布についての位置尺度である．
- VectorQ data
についての平均推定 
は 
で与えられる． - MatrixQ data の平均推定
は，各列ベクトルについて計算される．Mean[{{x1,y1,…},{x2,y2,…},…}]は{Mean[{x1,x2,…}],Mean[{y1,y2,…}],…}に等しい． » - ArrayQ data については，平均推定はArrayReduce[Mean,data,1]に等しい． »
- WeightedData[{x1,x2,…},{w1,w2,…}]についての平均推定は
で与えられる． » - Meanは数値と記号両方の data を扱うことができる．
- data は次の追加的な形式と解釈を持つことがある．
-
Association 値（キーは無視される） » WeightedData 重み付き平均，もとになっているEmpiricalDistribution に基づく » EventData もとになっているSurvivalDistributionに基づく » TimeSeries, TemporalData, … ベクトルまたは配列の値（タイムスタンプは無視される） » Image,Image3D RGBチャンネル値またはグレースケールの強度値 » Audio すべてのチャンネルの振幅値 » DateObject,TimeObject 日付または時間のリスト » - 日付のリスト
の平均は 
で与えられるが，これは日付 
に継続時間の合計
を加えたものである． - 一変量分布 dist の平均は μ=Expectation[x,xdist]で与えられる． »
- 多変量分布 dist の平均は{μx ,μy,…}=Expectation[{x,y,…},{x,y,…}dist]で与えられる． »
- ランダム過程 proc については，平均関数は時点 t におけるスライス分布SliceDistribution[proc,t]について μ[t]=Mean[SliceDistribution[proc,t]]として計算できる． »
例題
すべて開く すべて閉じる例 (5)
Mean[{1.21, 3.4, 2.15, 4, 1.55}]Mean[{a, b, c, d}]Mean[{{a, u}, {b, v}, {c, w}}]RandomDate[4]Mean[%]Mean[LogNormalDistribution[μ, σ]]スコープ (22)
基本的な用法 (6)
Mean[{1, 2, 3, 4}]Mean[{π, E, 2}]Mean[{1., 2., 3., 4.}]Mean[N[{1, 2, 3, 4}, 30]]WeightedDataの平均値を求める：
Mean[WeightedData[{1, 2, 3}, {Subscript[w, 1], Subscript[w, 2], Subscript[w, 3]}]]data = {8, 3, 5, 4, 9, 0, 4, 2, 2, 3};
weights = {0.15, 0.09, 0.12, 0.10, 0.16, 0., 0.11, 0.08, 0.08, 0.09};Mean[WeightedData[data, weights]]EventDataの平均値を求める：
e = {1.0, 2.1, 3.2, 4.5, 5.7};
ci = {0, 0, 0, 1, 0};Mean[EventData[e, ci]]TimeSeriesの平均値を求める：
v = {3, 8, 4, 11, 9, 2};
t = {1, 3, 5, 7, 8, 10};
ts = TimeSeries[v, {t}];Mean[ts]//NMean[ts["Values"]]//NMean[WeightedData[ts]]//Ndata = Quantity[RandomReal[1, 6], "Meters"]Mean[data]配列データ (5)
行列のMeanは列ごとの平均を与える：
Mean[Array[Subscript[a, ##]&, {2, 2}]]配列のMeanは第1レベルの列ごとの平均を与える：
Mean[Array[Subscript[a, ##]&, {2, 2, 2}]]Mean[RandomReal[1, 10 ^ 7]]Mean[RandomReal[1, {10 ^ 6, 5}]]入力がAssociationのとき，Meanはその値に作用する：
mat = RandomReal[1, {2, 2}];
assoc = AssociationThread[Range[2], mat]Mean[assoc]SparseArrayデータは密な配列と同じように使うことができる：
Mean[SparseArray[{{1} -> 1, {100} -> 1}]]Mean[SparseArray[{{1, 1} -> 1, {2, 2} -> 2, {3, 3} -> 3, {1, 3} -> 4}]]sp = SparseArray[{{i_, i_} :> i, {i_, j_} /; j == i + 1 :> i - 1}, {100, 10}]Mean[sp]QuantityArrayの平均を求める：
data = QuantityArray[RandomReal[1, 6], "Pounds"]Mean[data]画像データと音声データ (2)
Mean[[image]]RGBColor[%]Mean[[image]]音声オブジェクトについては，Meanはチャンネルごとに作用する：
a = ExampleData[{"Audio", "Bee"}]AudioMeasurements[a, "Channels"]Mean[a]日付と時間 (4)
dates = WolframLanguageData[All, "DateIntroduced"];DateHistogram[dates]Mean[dates]dates = RandomDate[4]weights = {1, 1, 1, 3};Mean[WeightedData[dates, weights]]dates = {DateObject[{2024, 2, 29}, CalendarType -> "Julian"], DateObject[{1524, 1, 1}, CalendarType -> "Islamic"], DateObject[{6024, 1, 15}, CalendarType -> "Jewish"]}TimelinePlot[dates, ImageSize -> Medium]Mean[dates]%["CalendarType"]RandomTime[3]Mean[%]{TimeObject[{12}, TimeZone -> 0], TimeObject[{12}, TimeZone -> 2], TimeObject[{12}, TimeZone -> "Asia/Tokyo"]}Mean[%]DateValue[%, "TimeZone"]分布と過程 (5)
Mean[BinomialDistribution[n, p]]Mean[NormalDistribution[μ, σ]]Mean[MultivariateHypergeometricDistribution[n, {Subscript[m, 1], Subscript[m, 2]}]]Mean[BinormalDistribution[{Subscript[μ, 1], Subscript[μ, 2]}, {σ1, σ2}, ρ]]Mean[TransformedDistribution[x^2, xNormalDistribution[μ, σ]]]Mean[ProbabilityDistribution[Sqrt[2] / π / (1 + (x - 2)^4), {x, -∞, ∞}]]data = RandomVariate[NormalDistribution[], 10 ^ 3];Mean[HistogramDistribution[data]]Mean[QuantityDistribution[MaxwellDistribution[σ], "Meters" / "Seconds"]]Mean[QuantityDistribution[BinormalDistribution[{190, 72}, {10, 5}, 1 / 2], {"Pounds", "Inches"}]]Mean[SmoothKernelDistribution[QuantityArray[ExampleData[{"Statistics", "OldFaithful"}], {"Seconds", "Minutes"}]]]Mean[QueueingProcess[λ, μ, ∞][t]]Plot[Evaluate[% /. {μ -> 3, λ -> 2}], {t, 0, 4}, PlotRange -> All]時点 t=0.5におけるTemporalDataの平均値を求める：
td = RandomFunction[WienerProcess[1, 1], {0, 10, 0.05}, 100]Mean[td[0.5]]Show[ListLinePlot[td, PlotStyle -> Directive[GrayLevel[0.75, .5], Thin]], Plot[Mean[td[t]], {t, 0, 10}, PlotStyle -> Thick]]アプリケーション (11)
基本的なアプリケーション (5)
dists = {NormalDistribution[3, 1], WeibullDistribution[2, 2]};Table[With[{m = Mean[𝒟]}, Plot[PDF[𝒟, x], {x, 0, 6}, Filling -> Axis, Epilog -> {Directive[Red, Dashed, Thick], Line[{{m, 0}, {m, PDF[𝒟, m]}}]}]], {𝒟, dists}]dists = {ExponentialDistribution[1], MixtureDistribution[{2, 1}, {NormalDistribution[2, 1], NormalDistribution[5, 1 / 2]}]};Table[With[{m = Mean[𝒟]}, Plot[PDF[𝒟, x], {x, 0, 6}, Filling -> Axis, Epilog -> {Directive[Red, Dashed, Thick], Line[{{m, 0}, {m, PDF[𝒟, m]}}]}]], {𝒟, dists}]dists = {BinormalDistribution[{1 / 2, 1 / 2}, {0.2, 0.2}, 1 / 2], DirichletDistribution[{2, 3, 2}]};Table[{mx, my} = Mean[𝒟];Show[Plot3D[PDF[𝒟, {x, y}], {x, 0, 1}, {y, 0, 1}, Filling -> Axis, PlotStyle -> Opacity[0.5], Mesh -> None, PlotRange -> All], Graphics3D[{Red, Tube[{{mx, my, 0}, {mx, my, PDF[𝒟, {mx, my}]}}, 0.01]}]], {𝒟, dists}]2Dセルオートマトンの進化の連続するステップにおけるセルの値の平均：
ArrayPlot[Mean[CellularAutomaton[{14, {2, 1}, {1, 1}}, {{{1}}, 0}, 30]]]data = RandomFunction[WienerProcess[1, 1], {0, 1, .02}, 10 ^ 3];times = Range[0, 1, .1];m = Map[{#, Mean[data[#]]}&, times];Show[ListPlot[data, PlotStyle -> Directive[Thin, Opacity[.1]]], ListLinePlot[m, PlotStyle -> Green]]アプリケーション (6)
heights = {134, 143, 131, 140, 145, 136, 131, 136, 143, 136, 133, 145, 147,
150, 150, 146, 137, 143, 132, 142, 145, 136, 144, 135, 141};ListPlot[heights, Filling -> Axis](m = Mean[heights])//NListPlot[{heights, {{0, m}, {25, m}}}, Joined -> {False, True}, Filling -> Axis]heights = Quantity[{134, 143, 131, 140, 145, 136, 131, 136, 143, 136, 133, 145, 147,
150, 150, 146, 137, 143, 132, 142, 145, 136, 144, 135, 141}, "Centimeters"];ListPlot[heights, Filling -> Axis, AxesLabel -> Automatic](m = Mean[heights])//NListPlot[{heights, {{0, m}, {25, m}}}, Joined -> {False, True}, Filling -> Axis, AxesLabel -> Automatic]セラミック素材の480個のサンプルについての平均強度を求める：
data = ExampleData[{"Statistics", "CeramicStrength"}];Length[data]m = Mean[data]平均位置をハイライトしてデータについてのHistogramをプロットする：
highlightbar[{{x0_, x1_}, {y0_, y1_}}, d_, meta___] := {If[x0 ≤ First[meta] < x1, Red, {}], Rectangle[{x0, y0}, {x1, y1}]}Histogram[data -> m, ChartElementFunction -> highlightbar]NProbability[x > m, xdata]
MeanLifeTime = Mean[ExponentialDistribution[λ]]移動平均を計算することで，不規則な間隔の時系列を平滑化する：
data = TemporalData[TimeSeries, {{{26.27, 24.26, 23.94, 23.08, 24.17, 23.99, 23.27, 24.09, 22.78, 21.51,
21.68, 21.74, 20.97, 18.74, 18.27, 17.52, 17.52, 17.73, 17.81, 18.24, 18.02, 17.74, 17.43,
16.44, 16.34, 16.91, 17.44, 16.82, 17.44, 17.18, ... 200, 3628281600,
3628368000, 3628540800, 3628800000, 3628886400, 3628972800, 3629145600}}}, 1,
{"Continuous", 1}, {"Discrete", 1}, 1, {ValueDimensions -> 1,
ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}}}, True, 10.1];med = MovingMap[Mean, data, {Quantity[90, "Day"]}];Show[DateListPlot[data, PlotStyle -> GrayLevel[.7]], DateListPlot[med, Joined -> True, PlotStyle -> Thick]]小型の電子加速器中の真空装置内に，円状に並んだ20個の真空管がある．隣り合った真空管の少なくとも3個が故障すると，この真空装置は故障する：
n = 20;k = 3;bexpr = And@@Map[Or@@#&, Partition[Array[Subscript[x, #]&, n], k, 1, {-1, -1}]];dists = Array[{Subscript[x, #], ExponentialDistribution[1]}&, n];ℛ = ReliabilityDistribution[bexpr, dists];Plot[SurvivalFunction[ℛ, t]//Evaluate, {t, 0, 1}]Mean[ℛ]//N特性と関係 (17)
Mean[{a, b, c, d}]Total[{a, b, c, d}] / Length[{a, b, c, d}]Meanは，正の値の1ノルムをLengthで割ったものに等しい：
data = RandomReal[10, 10];Norm[data, 1] / Length[data]Mean[data]WeightedDataのMeanは，そのデータのEmpiricalDistributionの平均に等しい：
wdata = WeightedData[RandomReal[10, 100], RandomReal[1, 100]]Mean[wdata]dist = EmpiricalDistribution[wdata]Mean[dist]EventDataのMeanは，そのデータのSurvivalDistributionの平均に等しい：
edata = EventData[{8, 22, 6, 4, 12, 11, 2, 34, 25, 15, 8, 6, 34, 6, 32, 1, 15, 9, 9, 6}, {0, 0, 0, 0, 0, 0, 0, 1, 1, 0, 0, 0, 1, 1, 1, 0, 0, 1, 1, 0}]Mean[edata]dist = SurvivalDistribution[edata]Mean[dist]ほぼ対称のサンプルの場合，MeanとMedianはほぼ等しい：
Mean[{1, 2, 3, 4, 4, 3, 1, 1}]//NMedian[{1, 2, 3, 4, 4, 3, 1, 1}]//Ndata = RandomReal[100, 10 ^ 6];Mean[data]Median[data]Meanからの絶対偏差のMeanはMeanDeviationである：
data = RandomReal[10, 10];MeanDeviation[data]Mean[Abs[data - Mean[data]]]Meanは，正の値についてGeometricMeanに対数的に関連している：
Log[GeometricMean[{a, b, c, d}]]//PowerExpandMean[Log[{a, b, c, d}]]Meanは，データの逆のHarmonicMeanの逆である：
data = RandomReal[10, 10];1 / HarmonicMean[1 / data]Mean[data]二乗したデータのMeanの平方根はRootMeanSquareである：
data = RandomReal[10, 10];RootMeanSquare[data] == Sqrt[Mean[data ^ 2]]n 次CentralMomentは n 乗した偏差の平均(Mean)である：
CentralMoment[{a, b, c}, n]Mean[({a, b, c} - Mean[{a, b, c}]) ^ n]VarianceはMeanからの偏差を二乗したものをスケールしたMeanである：
data = RandomReal[5, 20];Variance[data]Mean[(data - Mean[data]) ^ 2] Length[data] / (Length[data] - 1)リストのExpectationはMeanである：
Expectation[f[x], xRange[5]]Mean[Map[f, Range[5]]]MovingAverageは一連の平均である：
MovingAverage[{a, b, c, d, e, f}, 3]Table[Mean[Take[{a, b, c, d, e, f}, {i, i + 2}]], {i, 4}]0% TrimmedMeanはMeanに等しい：
TrimmedMean[Range[10], 0]Mean[Range[10]]分布における確率変数のExpectationはMeanである：
Expectation[x, xBetaDistribution[α, β]]Mean[BetaDistribution[α, β]]LocationTestは，平均が0に近いかどうかの検定を行う：
data = RandomVariate[NormalDistribution[0, 1], 100];Mean[data]
LocationTest[data, 0]LocationTest[data, 0, "TestConclusion"]LocationEquivalenceTestは，2つ以上のデータ集合の平均が等しいかどうかの検定を行う：
data1 = RandomVariate[NormalDistribution[.2, .1], 100];
data2 = RandomVariate[NormalDistribution[0, .1], 100];{Mean[data1], Mean[data2]}
LocationEquivalenceTest[{data1, data2}]LocationEquivalenceTest[{data1, data2}, "TestConclusion"]考えられる問題 (2)
外れ値はMeanに対して不均衡な影響を与えることがある：
Mean[{-100, 1, 1, 1, 1, 20}]//NTrimmedMeanを使って最小要素および最大要素をある割合で除く：
TrimmedMean[{-100, 1, 1, 1, 1, 20}, 0.2]外れ値に対して感度が非常に低いものとしてMedianを使う：
Median[{-100, 1, 1, 1, 1, 20}]data = {1.21, 3.4, 2.15, Missing[], 1.55};
Mean[data]データをTabularColumnに変換して，欠損値ではない値を計算に使う：
Mean[TabularColumn[data]]Queryを使う：
Query[Mean][data]おもしろい例題 (1)
10個，100個，300個のサンプルについての，Meanによる推定値の分布：
SmoothHistogram[Table[Mean[RandomVariate[ExponentialDistribution[1], {s, 1000}]], {s, {10, 100, 300}}], Filling -> Axis, PlotLegends -> {10, 100, 300}, PlotRange -> {{0.2, 1.8}, Automatic}]
Wolfram Research (2003), Mean, Wolfram言語関数， https://reference.wolfram.com/language/ref/Mean.html （2024年に更新）.
テキスト
Wolfram Research (2003), Mean, Wolfram言語関数， https://reference.wolfram.com/language/ref/Mean.html （2024年に更新）.
CMS
Wolfram Language. 2003. "Mean." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2024. https://reference.wolfram.com/language/ref/Mean.html.
APA
Wolfram Language. (2003). Mean. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Mean.html