WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

MissingFallback[arg1,arg2,…]

MissingQではない最初の引数 argiを与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

MissingFallback

MissingFallback[arg1,arg2,…]

MissingQではない最初の引数 argiを与える．

詳細

例題

すべて開く すべて閉じる

例  (2)

MissingFallbackは，引数のうちMissing[…]ではない最初のものを返す：

Wolfram Language code: MissingFallback[1, 2]
Wolfram Language code: MissingFallback[Missing[], 2]
Wolfram Language code: MissingFallback[Missing["reason"], Missing[], 2]

欠落要素しかない場合は，その最後のものが返される：

Wolfram Language code: MissingFallback[Missing["Unknown"], Missing["NotAvailable"]]

MissingFallbackを使ってTabularオブジェクト内の欠落値を別の列の値で置換する：

Wolfram Language code: tab = Tabular[{{1, 3, 5}, {2, Missing[], 6}}, {"a", "b", "c"}]
Wolfram Language code: TransformColumns[tab, "b" -> Function[MissingFallback[#b, #a]]]

代りに固定値を使う：

Wolfram Language code: TransformColumns[tab, "b" -> Function[MissingFallback[#b, -99]]]

スコープ  (1)

MissingFallbackの列の関数を使ってTabularオブジェクト内の欠落値を埋める：

Wolfram Language code: tab = ToTabular[{"a" -> {1, 2, 3}, "b" -> {4, Missing[], 6}, "c" -> {7, 8, 9}}, "Columns"]

別の列の行の値の合計を使う：

Wolfram Language code: TransformColumns[tab, "b" -> Function[MissingFallback[#b, #a + #c]]]

近傍列の行の値の平均を使う：

Wolfram Language code: TransformColumns[tab, "b" -> Function[MissingFallback[#b, Mean[{#a, #c}]]]]

アプリケーション  (2)

列に冥王星の衛星を含むTabularオブジェクトを構築する：

Wolfram Language code: plutoMoons = ToTabular[{"moon" -> EntityList[EntityClass["PlanetaryMoon", "PlutoMoon"]]}, "Columns"]

これらの衛星の中には，"PolarRadius"特性がMissing["NotAvailable"]のものがある：

Wolfram Language code: TransformColumns[plutoMoons, "size" -> Function[#moon["PolarRadius"]]]

フォールバックとして"Radius"特性を使う：

Wolfram Language code: TransformColumns[plutoMoons, "size" -> Function[MissingFallback[#moon["PolarRadius"], #moon["Radius"]]]]

パーマーペンギンのデータのTabularオブジェクトを取得する：

Wolfram Language code: penguins = ResourceData["Sample Tabular Data: Palmer Penguins"]

各島のペンギンの種と性別の分布のピボット表を作成する：

Wolfram Language code: pt = PivotTable[penguins, Length[#species]&, {"island"}, {"species", "sex"}]

結果の表には欠落値がある：

Wolfram Language code: TabularStructure[pt, {ExtendedKey["Gentoo", "female"], ExtendedKey["Gentoo", "male"], ExtendedKey["Chinstrap", "female"], ExtendedKey["Chinstrap", "male"]}, "MissingCount"]

MissingFallbackを使ってMissing値を埋め，各島のメスのペンギンの総数を計算する：

Wolfram Language code: mf[key_] := MissingFallback[key, 0]
Wolfram Language code: females = ColumnKeys[pt, MatchQ[#ColumnKey, ExtendedKey[_, "female"]]&]
Wolfram Language code: ConstructColumns[pt, {"island", "females" -> Function[Total[mf /@ (# /@ females)]]}]

特性と関係  (2)

MissingFallbackのすべての引数がMissing[…]オブジェクトの際は，最後のものが返される：

Wolfram Language code: MissingFallback[Missing["reason1"], Missing[], Missing["reason2"]]

シンボルMissingは欠落オブジェクトとしては扱われない：

Wolfram Language code: MissingFallback[Missing, x]
Wolfram Language code: MissingQ[Missing]

引数がないMissing[]は欠落オブジェクトとして扱われる：

Wolfram Language code: MissingFallback[Missing[], x]
Wolfram Language code: MissingQ[Missing[]]
Wolfram Research (2025), MissingFallback, Wolfram言語関数， https://reference.wolfram.com/language/ref/MissingFallback.html.

テキスト

Wolfram Research (2025), MissingFallback, Wolfram言語関数， https://reference.wolfram.com/language/ref/MissingFallback.html.

CMS

Wolfram Language. 2025. "MissingFallback." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/MissingFallback.html.

APA

Wolfram Language. (2025). MissingFallback. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/MissingFallback.html

BibTeX

@misc{reference.wolfram_2026_missingfallback, author="Wolfram Research", title="{MissingFallback}", year="2025", howpublished="\url{https://reference.wolfram.com/language/ref/MissingFallback.html}", note=[Accessed: 04-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_missingfallback, organization={Wolfram Research}, title={MissingFallback}, year={2025}, url={https://reference.wolfram.com/language/ref/MissingFallback.html}, note=[Accessed: 04-November-2026]}