WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

"ListVector" （コンパイルタイプ）

"ListVector"::[type]

指定された要素型を持つ一様のリストを表す．

詳細

  • "ListVector"はTypedおよび型を指定する関連した構造で使うことができる．
  • "ListVector"オブジェクトは自動的にメモリ管理される．
  • "ListVector"の要素は任意のコンパイル型を持つことができる．
  • "ListVector"の要素はすべて同じ型を持つ．
  • 階数が1より大きい数値テンソルの場合は，"PackedArray"または"NumericArray"を使うことができる．

コンストラクタ

  • "ListVector"オブジェクトはコンパイルされたコードでTyped[{…},"ListVector"::[type]]を使って作成することができる． »
  • CreateTypeInstance["ListVector"::[type],carr,len]は長さ len の"CArray" carr から"ListVector"を構築する．carr はオプショナルで"Managed"でラップすることができる．

特性

  • 型"ListVector"::[type]の list に対するInformation[list,"ContainedType"]は type を与える．
  • 型"ListVector"::[type]の list に対するInformation[list,"ElementType"]は type を与える．

変換

    式

  • リストのすべての要素が type に変換できる限り，List式は"ListVector"::[type]に変換することも"ListVector"::[type]から変換することもできる．

    • "PackedArray"

  • "ListVector"オブジェクトは"PackedArray"オブジェクトに変換することも"PackedArray"オブジェクトから変換することもできる．

    • "NumericArray"

  • "ListVector"オブジェクトは"NumericArray"オブジェクトに変換することも"NumericArray"オブジェクトから変換することもできる．

ランタイムエラー

    ArrayPartError

  • "ListVector"から要素を抽出することが必要な操作は，その要素が存在しない場合にはランタイムエラーを与えることがある．

例題

すべて開く すべて閉じる

例  (2)

"ListVector"はCompiledCodeFunctionの入力および出力として使うことができる：

Wolfram Language code: cf = FunctionCompile[Function[Typed[arg, "ListVector"::["MachineInteger"]], arg]]
Wolfram Language code: cf[{1, 2, 3}]

コンパイルされたコードで"ListVector"を作成する：

Wolfram Language code: cf = FunctionCompile[Function[Typed[arg, "MachineInteger"], Typed[{1, 2, arg}, "ListVector"::["MachineInteger"]] ]]
Wolfram Language code: cf[12]

スコープ  (3)

"ListVector"オブジェクトはコンパイル可能な任意の型を持つオブジェクトを含むことができる：

Wolfram Language code: cf = FunctionCompile[Function[Typed[rules, "ListVector"::["Rule"::["String", "MachineInteger"]]], First[rules]]]
Wolfram Language code: cf[{"hello" -> 1, "world" -> 3}]

高階の配列は，ネストされた"ListVector"インスタンスで表すことができる：

Wolfram Language code: cf = FunctionCompile[Function[Typed[arg, "ListVector"::["ListVector"::["MachineInteger"]]], Catenate[arg]]]
Wolfram Language code: cf[{{1, 2, 3}, {4, 5, 6, 7, 8}, {9, 10}}]

"ListVector"の要素型を得る：

Wolfram Language code: cf = FunctionCompile[Function[Typed[arg, "ListVector"::["Real64"]], Information[arg, "ElementType"]]]
Wolfram Language code: cf[{1.2, 4.5, 5.3}]

特性と関係  (1)

"PackedArray"は数値配列を表すために使うことができる：

Wolfram Language code: cf = FunctionCompile[Function[Typed[arg, "PackedArray"::["MachineInteger", 1]], First[arg]]]
Wolfram Language code: cf[{1, 2, 3, 4, 5}]

しかし，非数値データには使えない：

Wolfram Language code: cf = FunctionCompile[Function[Typed[arg, "PackedArray"::["String", 1]], First[arg]]]

これとは対照的に，"ListVector"型は階数1のリストしか表せないが，コンパイル可能な任意の型を持つ要素を含むことができる：

Wolfram Language code: cf = FunctionCompile[Function[Typed[arg, "ListVector"::["String"]], First[arg]]]
Wolfram Language code: cf[{"hello", "to", "the", "world"}]

考えられる問題  (1)

部分アクセスによりエラーが生じる：

Wolfram Language code: cf = FunctionCompile[Function[Typed[arg, "ListVector"::["Real64"]], arg[[5]]]]
Wolfram Language code: cf[{1., 2., 3., 4.}]