UPS Reliability

Introduction

This model and accompanying analysis show a dual usage of models, for both behavioral analysis and reliability analysis.

Explore the available scenarios by evaluating each cell in order. Evaluation is done by selecting a cell and pressing Shift+Enter.

In order to get the full experience of this example, you need the following:

Wolfram SystemModeler; a free trial download is available at www.wolfram.com/system-modeler

The model that came in the same bundle as this notebook

For more information about Wolfram SystemModeler, visit www.wolfram.com/system-modeler.

Initialize

Define the model name:

mmodel="IndustryExamples.Energy.UPS.PowerSupply";
mmodelhardened="IndustryExamples.Energy.UPS.PowerSupplyHardened";

Reliability Analysis

For the system to work, either the utility and the electrical lines or the charger, battery, and inverter need to work. The system configuration can be seen in the diagram:

SystemModel[mmodel,"Diagram"]

The reliability information has been entered into the model’s reliability view:

Each component has a lifetime distribution attached to it:

Retrieve the reliability information from the model and make it available to Mathematica:

upsStandard=SystemModelReliability[mmodel]

The PowerSupplyHardened model has a better battery, with a longer expected lifetime:

upsHardened=SystemModelReliability[mmodelhardened]

Mean Time to Failure

Compute the mean time to failure (MTTF):

{meanRAmp=Mean[upsStandard],meanRH=Mean[upsHardened]}

Compare the survival function for the two systems by plotting them, and indicate their MTTF in hours:

Plot[{SurvivalFunction[upsStandard,t],SurvivalFunction[upsHardened,t]},{t,0,2meanRH},Filling->Axis,PlotRange->{0,1},Epilog->{Directive[Red,Dotted,Thick],Line[{{meanRH,0},{meanRH,SurvivalFunction[upsHardened,meanRH]}}],Line[{{meanRAmp,0},{meanRAmp,SurvivalFunction[upsStandard,meanRAmp]}}]},AxesLabel->{"Time [h]",None},PlotLegends->{"Standard","Hardened"}]

It can be seen that the average lifetime for the system with a better battery is much longer.

Analysis of Physical Behavior

The model is also ready for transient simulation analysis. By simulating the model, you can see how the switch from utility-powered to battery-powered operation affects the equipment attached as a load.

Simulate the model:

switchOffTime=1+1/(60*4);
sim=SystemModelSimulate[mmodel,<|"ParameterValues"-> {"switchOffTime"-> switchOffTime}|>];

Plot the voltage in the load:

SystemModelPlot[sim,"Load Voltage Drop",{switchOffTime-1/(60*16),switchOffTime+1/(60*16)},PlotRange->Automatic,Epilog->{Directive[Red,Dotted,Thick],InfiniteLine[{{switchOffTime,0},{switchOffTime,1}}]}]

After the switch, a small dip in the voltage level can be seen.

Battery Lifetime

Simulate the UPS for a longer time to see how long the battery will last:

simLong=SystemModelSimulate[mmodel,{0,600},
<|"ParameterValues"-> {"switchOffTime"-> 0,"VMax"-> 10}|>,
Method->{"DASSL","InterpolationPoints"->2000}];

Sometime after 500 seconds, the battery is below the threshold voltage to power the inverter, and the circuit will turn off:

SystemModelPlot[simLong,"Battery Voltage Threshold",
Filling-> {1-> {2}},
PlotRange->All,
PlotStyle->{Automatic,Directive[Dotted,ColorData[97][1]]}]

Terms and Conditions of Use

This domain example is an informational resource made freely available by Wolfram Research.

Use of This Example

• You may not use this example for any purpose that is unlawful or dangerous.
• You assume total responsibility and risk for your use of this example.
• You may not present this example with any alteration to its trade dress, trademarks, or design.

License

All content in this bundle is licensed under the Creative Commons Attribution-NonCommercial-ShareAlike 3.0 Unported License. By accessing the content or using it in any way, you accept and agree to be bound by the terms of this license. If you do not agree to these Terms of Use, you may not use this content. Wolfram Research reserves the right to change, modify, add to, or remove portions of these Terms of Use at any time without notice. Please refer back to www.wolfram.com for the latest Terms of Use.

A summary of the licensing terms can be found at:
http://creativecommons.org/licenses/by-nc-sa/3.0

The full legal code can be found at: 
http://creativecommons.org/licenses/by-nc-sa/3.0/legalcode