Electrical Circuit Reliability

Introduction

This example shows how to use reliability annotations from a System Modeler model in the Wolfram Language. Two models with different annotations are used. Both models use the same components, but have different reliability annotations.

Explore the available scenarios by evaluating each cell in order. Evaluation is done by selecting a cell and pressing Shift+Enter.

In order to get the full experience of this example, you need the following:

Wolfram System Modeler; a free trial download is available at www.wolfram.com/system-modeler

The model that came in the same bundle as this notebook

For more information about Wolfram System Modeler, visit www.wolfram.com/system-modeler.

Initialize

Define the model names:

model="EducationExamples.ElectricalEngineering.AmplifierReliability.Amplifier";
modelHot="EducationExamples.ElectricalEngineering.AmplifierReliability.AmplifierHot";

Analyze the Reliability of Two Different Circuits

Retrieve the ReliabilityDistribution from the models:

{rAmp,rAmpH}={SystemModelReliability[model],SystemModelReliability[modelHot]};

The two different models use different parameters, as can be seen by looking at them in the reliability view in Model Center or by evaluating them:

rAmp

rAmpH

One of them corresponds to a system operating at 30°C and the other to a system operating at 70°C.

Temperature Dependence

The temperature dependence for the failure rate of the resistors in the circuit comes from MIL-HDBK-217F, and is given by the equation ((4.5` (e^((12 (T+273))/343)) (e^((5 (T+273))/(6 273))))/(10^9)), where T is the temperature in °C.

Define a function for the temperature dependence:

fun[T_]:=4.5 (10^(-9))Exp[12(((T+273)/343))]Exp[(5/6)(((T+273)/273))]

Plot the temperature dependence:

Plot[fun[t],{t,0,100},PlotLabel->"Temperature dependence",AxesLabel->{"Temperature [°C]","Failures/(10^6) h"}]

This temperature dependence was used to find the lifetime distributions of the components.

Mean Time to Failure

Compute the mean time to failure (MTTF):

{meanRAmp=Mean[rAmp],meanRH=Mean[rAmpH]}

Compare the survival function for the two systems by plotting them, and indicate their MTTF in hours:

Plot[{SurvivalFunction[rAmp,t],SurvivalFunction[rAmpH,t]},{t,0,4meanRH},Filling->Axis,PlotRange->{0,1},Epilog->{Directive[Red,Dotted,Thick],Line[{{meanRH,0},{meanRH,SurvivalFunction[rAmpH,meanRH]}}],Line[{{meanRAmp,0},{meanRAmp,SurvivalFunction[rAmp,meanRAmp]}}]},AxesLabel->{"Time [h]",None},PlotLegends->{"Standard","Hot"}]

It can be seen that the average lifetime for the system operating at a higher temperature is significantly shorter.

Survival Function, Hazard Function, PDF, and CDF

Four common properties in reliability analysis are the SurvivalFunction, HazardFunction, PDF, and CDF. Create plots showing them:

GraphicsGrid[Partition[Table[Plot[df[rAmp,t],{t,0,2Mean[rAmp]},PlotLabel->df,ImageSize->200],{df,{SurvivalFunction,HazardFunction,PDF,CDF}}],2],ImageSize->Large]

Note that the hazard function is constant. This happens when all lifetime distributions in a ReliabilityDistribution are following the ExponentialDistribution.

Component Importance

Get the names for the different components:

names=SystemModelReliability[model,"Components"]

Calculate the BirnbaumImportance for the system operating at 30° after 500,000 hours of operation:

bi=BirnbaumImportance[rAmp,t]/.t->500000

BarChart[{bi},ChartLegends->Placed[names,Below],PlotLabel->"Birnbaum Importance"]

As can be seen, the operational amplifier (opAmp) is more important than the resistors.

Terms and Conditions of Use

This domain example is an informational resource made freely available by Wolfram Research.

Use of This Example

• You may not use this example for any purpose that is unlawful or dangerous.
• You assume total responsibility and risk for your use of this example.
• You may not present this example with any alteration to its trade dress, trademarks, or design.

License

All content in this bundle is licensed under the Creative Commons Attribution-NonCommercial-ShareAlike 3.0 Unported License. By accessing the content or using it in any way, you accept and agree to be bound by the terms of this license. If you do not agree to these Terms of Use, you may not use this content. Wolfram Research reserves the right to change, modify, add to, or remove portions of these Terms of Use at any time without notice. Please refer back to www.wolfram.com for the latest Terms of Use.

A summary of the licensing terms can be found at:
http://creativecommons.org/licenses/by-nc-sa/3.0

The full legal code can be found at: 
http://creativecommons.org/licenses/by-nc-sa/3.0/legalcode