---
title: "RegionMember"
language: "en"
type: "Symbol"
summary: "RegionMember[reg, {x, y, ...}] gives True if the numeric point {x, y, ...} is a member of the constant region reg and False otherwise. RegionMember[reg, {x, y, ...}] gives conditions for the point {x, y, ...} to be a member of reg. RegionMember[reg] returns a RegionMemberFunction[...] that can be applied repeatedly to different points."
keywords: 
- region member
- region membership
- elements of region
- point in region
- point in mesh
- point in region test
- point in mesh test
- point in polygon test
- point on line test
- point on circle test
- point in rectangle test
- point in cube test
- point in tetrahedron test
- point in disk test
canonical_url: "https://reference.wolfram.com/language/ref/RegionMember.html"
source: "Wolfram Language Documentation"
related_guides: 
  - 
    title: "Region Properties and Measures"
    link: "https://reference.wolfram.com/language/guide/GeometricPropertiesAndMeasures.en.md"
  - 
    title: "Polygons"
    link: "https://reference.wolfram.com/language/guide/Polygons.en.md"
  - 
    title: "Solid Geometry"
    link: "https://reference.wolfram.com/language/guide/SolidGeometry.en.md"
  - 
    title: "Plane Geometry"
    link: "https://reference.wolfram.com/language/guide/PlaneGeometry.en.md"
  - 
    title: "Polyhedra"
    link: "https://reference.wolfram.com/language/guide/Polyhedra.en.md"
  - 
    title: "Synthetic Geometry"
    link: "https://reference.wolfram.com/language/guide/SyntheticGeometry.en.md"
  - 
    title: "Interval Arithmetic"
    link: "https://reference.wolfram.com/language/guide/IntervalArithmetic.en.md"
related_functions: 
  - 
    title: "Element"
    link: "https://reference.wolfram.com/language/ref/Element.en.md"
  - 
    title: "RegionMemberFunction"
    link: "https://reference.wolfram.com/language/ref/RegionMemberFunction.en.md"
  - 
    title: "RegionDistance"
    link: "https://reference.wolfram.com/language/ref/RegionDistance.en.md"
  - 
    title: "SignedRegionDistance"
    link: "https://reference.wolfram.com/language/ref/SignedRegionDistance.en.md"
  - 
    title: "RegionEqual"
    link: "https://reference.wolfram.com/language/ref/RegionEqual.en.md"
  - 
    title: "RegionWithin"
    link: "https://reference.wolfram.com/language/ref/RegionWithin.en.md"
  - 
    title: "MemberQ"
    link: "https://reference.wolfram.com/language/ref/MemberQ.en.md"
  - 
    title: "Between"
    link: "https://reference.wolfram.com/language/ref/Between.en.md"
  - 
    title: "GeometricScene"
    link: "https://reference.wolfram.com/language/ref/GeometricScene.en.md"
---
# RegionMember

RegionMember[reg, {x, y, …}] gives True if the numeric point {x, y, …} is a member of the constant region reg and False otherwise.

RegionMember[reg, {x, y, …}] gives conditions for the point {x, y, …} to be a member of reg.

RegionMember[reg] returns a RegionMemberFunction[…] that can be applied repeatedly to different points.

## Details

* ``RegionMember`` is also known as point in region test, membership test, and membership conditions.

[image]

* A constant region is a region where ``ConstantRegionQ[reg]`` gives ``True``.

## Examples (35)

### Basic Examples (3)

Test whether a particular point is in a region:

```wl
In[1]:= RegionMember[Polygon[{{0, 0}, {1, 0}, {0, 1}}], {1 / 3, 1 / 3}]

Out[1]= True
```

---

Get conditions for point membership:

```wl
In[1]:= RegionMember[Disk[], {x, y}]

Out[1]= (x | y)∈ℝ && x^2 + y^2 ≤ 1
```

---

Create ``RegionMemberFunction`` to apply to different points:

```wl
In[1]:= mf = RegionMember[Disk[{0, 0}, 3]]

Out[1]= RegionMemberFunction[Disk[{0, 0}, 3], <>]

In[2]:= mf[RandomReal[4, {7, 2}]]

Out[2]= {True, False, False, True, True, True, True}
```

### Scope (21)

#### Basic Uses (4)

Directly test whether a point is in a region:

```wl
In[1]:= ℛ = Rectangle[{0, 0}, {2, 2}];

In[2]:= {RegionMember[ℛ, {1, 1}], RegionMember[ℛ, {3, 3}]}

Out[2]= {True, False}
```

---

Directly test whether a list of points is in a region:

```wl
In[1]:= ℛ = Ball[{0, 0, 0}, 2];

In[2]:= RegionMember[ℛ, RandomReal[2, {7, 3}]]

Out[2]= {False, True, False, True, False, True, False}
```

---

Get conditions for point membership by using variables ``{x, y}`` :

```wl
In[1]:= ℛ = Rectangle[{0, 0}, {2, 2}];

In[2]:= RegionMember[ℛ, {x, y}]

Out[2]= (x | y)∈ℝ && 0 ≤ x ≤ 2 && 0 ≤ y ≤ 2
```

---

Create ``RegionMemberFunction`` to apply to different points:

```wl
In[1]:= ℛ = Disk[{0, 0}, 2];

In[2]:= mf = RegionMember[ℛ]

Out[2]= RegionMemberFunction[Disk[{0, 0}, 2], <>]

In[3]:= mf[RandomReal[3, {7, 2}]]

Out[3]= {True, False, False, True, False, False, False}
```

#### Special Regions (6)

Regions in $\mathbb{R}^1$:

```wl
In[1]:= RegionMember[Point[{1}], {x}]

Out[1]= x∈ℝ && x == 1

In[2]:= RegionMember[Interval[{1, 5}], {x}]

Out[2]= x∈ℝ && 1 ≤ x ≤ 5

In[3]:= RegionMember[Interval[{1, 5}], {6}]

Out[3]= False
```

---

Regions in $\mathbb{R}^2$ :

```wl
In[1]:= RegionMember[Point[{1, 2}], {x, y}]

Out[1]= (x | y)∈ℝ && x == 1 && y == 2

In[2]:= RegionMember[Circle[{0, 0}, 2], {x, y}]

Out[2]= (x | y)∈ℝ && x^2 + y^2 == 4

In[3]:= RegionMember[Disk[{1, 2}, {3, 4}], {x, y}]

Out[3]= (x | y)∈ℝ && 16 (-1 + x)^2 + 9 (-2 + y)^2 ≤ 144

In[4]:= RegionMember[Circle[{0, 0}, 2], {3, 3}]

Out[4]= False
```

---

Visualize region membership in $\mathbb{R}^2$ :

```wl
In[1]:= ℛ = Triangle[{{0, 0}, {1, 2}, {2, 1}}];
```

Get the region bounds:

```wl
In[2]:= bounds = RegionBounds[ℛ]

Out[2]= {{0, 2}, {0, 2}}
```

Uniformly sample over the bounding box for the region:

```wl
In[3]:= pts = RandomVariate[UniformDistribution[bounds], 10 ^ 4];

In[4]:=
col = RegionMember[ℛ, pts] /. {False -> Gray, True -> Red};
Graphics[{AbsolutePointSize[1], {col, Point /@ pts}\[Transpose]}]

Out[4]= [image]
```

---

Regions in $\mathbb{R}^3$ :

```wl
In[1]:= RegionMember[Point[{1, 2, 3}], {x, y, z}]

Out[1]= (x | y | z)∈ℝ && x == 1 && y == 2 && z == 3

In[2]:= RegionMember[Line[{{1, 2, 3}, {4, 5, 6}}], {x, y, z}]

Out[2]= (x | y | z)∈ℝ && 2 + x == z && 1 + x == y && 6 ≤ x + y + z ≤ 15

In[3]:= RegionMember[Polygon[{{1, 0, 0}, {0, 1, 0}, {0, 0, 1}}], {x, y, z}]

Out[3]= (x | y | z)∈ℝ && RegionMemberFunction[MeshRegion[<3>, <2>], <>][{x, y, z}]

In[4]:= RegionMember[Cylinder[{{0, 0, 0}, {1, 1, 1}}, 2], {x, y, z}]

Out[4]= (x | y | z)∈ℝ && 0 ≤ x + y + z ≤ 3 && x^2 + y^2 + z^2 ≤ 6 + y z + x (y + z)

In[5]:= RegionMember[Ball[{0, 0, 0}, 2], {3, 3, 3}]

Out[5]= False
```

---

Visualize region membership in $\mathbb{R}^3$ :

```wl
In[1]:=
ℛ = Cuboid[{-1, -1, -1}, {1, 1, 1}];
in = RegionCentroid[ℛ];
out = {2, 0, 0};

In[2]:= {RegionMember[ℛ, in], RegionMember[ℛ, out]}

Out[2]= {True, False}

In[3]:= Graphics3D[{{Opacity[0.2], ℛ}, PointSize[Large], {Green, Point[in]}, {Red, Point[out]}}, Boxed -> False]

Out[3]= [image]
```

---

Regions in $\mathbb{R}^n$ :

```wl
In[1]:= RegionMember[Simplex[{{1, 0, 0, 0}, {0, 1, 0, 0}, {0, 0, 1, 0}, {0, 0, 0, 1}}], {x, y, z, t}]

Out[1]= (x | y | z | t)∈ℝ && t + x + y + z == 1 && y ≥ 0 && z ≥ 0 && x + y + z ≤ 1 && x ≥ 0

In[2]:= RegionMember[Cuboid[{1, 2, 3, 4, 5}, {6, 7, 8, 9, 10}], {x, y, z, t, u}]

Out[2]= (x | y | z | t | u)∈ℝ && 1 ≤ x ≤ 6 && 2 ≤ y ≤ 7 && 3 ≤ z ≤ 8 && 4 ≤ t ≤ 9 && 5 ≤ u ≤ 10

In[3]:= RegionMember[Ball[{0, 0, 0, 0, 0, 0, 0}, 8], {1, 2, 3, 4, 5, 6, 7}]

Out[3]= False
```

#### Formula Regions (3)

Implicit regions:

```wl
In[1]:= RegionMember[ImplicitRegion[x^2 + y^2 ≤ 1, {x, y}], {x, y}]

Out[1]= (x | y)∈ℝ && x^2 + y^2 ≤ 1

In[2]:= RegionMember[ImplicitRegion[x^2 + y^2 ≤ 1, {x, y, {z, 0, 2}}], {x, y, z}]

Out[2]= (x | y | z)∈ℝ && x^2 + y^2 ≤ 1 && 0 ≤ z ≤ 2
```

---

Visualize region membership in $\mathbb{R}^2$ :

```wl
In[1]:= ℛ = ImplicitRegion[x ^ 2 - 2y ^ 2 <= 1, {{x, -3, 3}, {y, -4, 4}}];
```

Get the region bounds:

```wl
In[2]:= bounds = RegionBounds[ℛ]

Out[2]= {{-3, 3}, {-4, 4}}
```

Uniformly sample over the bounding box for the region:

```wl
In[3]:= pts = RandomVariate[UniformDistribution[bounds], 10 ^ 4];

In[4]:=
col = RegionMember[ℛ, pts] /. {False -> Gray, True -> Red};
Graphics[{AbsolutePointSize[1], {col, Point /@ pts}\[Transpose]}]

Out[4]= [image]
```

---

Parametric regions:

```wl
In[1]:= RegionMember[ParametricRegion[{(1 - t ^ 2) / (1 + t ^ 2), 2t / (1 + t ^ 2)}, {t}], {x, y}]

Out[1]= (x | y)∈ℝ && -1 < x ≤ 1 && x^2 + y^2 == 1

In[2]:= RegionMember[ParametricRegion[{{u + v + w, u + v - w, u - v - w, -u - v - w}, -1 ≤ u ≤ 1 && -1 ≤ v ≤ 1 && -1 ≤ w ≤ 1}, {u, v, w}], {x, y, z, t}]

Out[2]= (x | y | z | t)∈ℝ && t + x == 0 && 2 + x + z ≥ 0 && x + z ≤ 2 && z ≤ 2 + y && y ≤ 2 + z && y ≤ 2 + x && x ≤ 2 + y
```

#### Mesh Regions (4)

``MeshRegion`` in 2D:

```wl
In[1]:=
ℛ = DelaunayMesh[RandomReal[8, {100, 2}]];
in = RegionCentroid[ℛ];
out = {9, 9};

In[2]:= {RegionMember[ℛ, in], RegionMember[ℛ, out]}

Out[2]= {True, False}

In[3]:= Show[ℛ, Graphics[{PointSize[Large], {Green, Point[in]}, {Red, Point[out]}}]]

Out[3]= [image]
```

---

In 3D:

```wl
In[1]:=
ℛ = DelaunayMesh[RandomReal[8, {100, 3}]];
in = RegionCentroid[ℛ];
out = {9, 9, 9};

In[2]:= {RegionMember[ℛ, in], RegionMember[ℛ, out]}

Out[2]= {True, False}

In[3]:= Show[HighlightMesh[RegionBoundary[ℛ], Style[2, Opacity[0.1]]], Graphics3D[{PointSize[Large], {Green, Point[in]}, {Red, Point[out]}}]]

Out[3]= [image]
```

---

``BoundaryMeshRegion`` in 2D:

```wl
In[1]:=
ℛ = ConvexHullMesh[RandomReal[8, {100, 2}]];
in = RegionCentroid[ℛ];
out = {9, 9};

In[2]:= {RegionMember[ℛ, in], RegionMember[ℛ, out]}

Out[2]= {True, False}

In[3]:= Show[ℛ, Graphics[{PointSize[Large], {Green, Point[in]}, {Red, Point[out]}}]]

Out[3]= [image]
```

---

``BoundaryMeshRegion`` in 3D:

```wl
In[1]:=
ℛ = ConvexHullMesh[RandomReal[8, {1000, 3}]];
in = RegionCentroid[ℛ];
out = {9, 9, 9};

In[2]:= {RegionMember[ℛ, in], RegionMember[ℛ, out]}

Out[2]= {True, False}

In[3]:= Show[HighlightMesh[ℛ, Style[2, Opacity[0.2]]], Graphics3D[{PointSize[Large], {Green, Point[in]}, {Red, Point[out]}}]]

Out[3]= [image]
```

#### Derived Regions (4)

``RegionIntersection`` of two regions:

```wl
In[1]:= ℛ = RegionIntersection[Disk[{0, 0}, 1], Disk[{0, 1}, 1]];

In[2]:= RegionMember[ℛ, {x, y}]

Out[2]= (x | y)∈ℝ && x^2 + y^2 ≤ 1 && x^2 + y^2 ≤ 2 y
```

Get the region bounds:

```wl
In[3]:= bounds = RegionBounds[ℛ]

Out[3]= {{-1, 1}, {0, 1}}
```

Uniformly sample over the bounding box for the region:

```wl
In[4]:= pts = RandomVariate[UniformDistribution[bounds], 10 ^ 4];

In[5]:=
col = RegionMember[ℛ, pts] /. {False -> Gray, True -> Red};
Graphics[{AbsolutePointSize[1], {col, Point /@ pts}\[Transpose]}]

Out[5]= [image]
```

---

``RegionUnion`` of mixed-dimensional regions:

```wl
In[1]:=
ℛ = RegionUnion[Circle[{1, 0}, 1], Disk[{0, 0}, 1]];
Region[ℛ]

Out[1]= [image]

In[2]:= RegionMember[ℛ, {x, y}]

Out[2]= (x | y)∈ℝ && (x^2 + y^2 == 2 x || x^2 + y^2 ≤ 1)
```

---

``TransformedRegion``:

```wl
In[1]:= ℛ = TransformedRegion[Disk[{0, 0}, 1], ShearingTransform[θ, {1, 0}, {0, 1}]];

In[2]:= RegionMember[ℛ, {x, y}]

Out[2]= (x | y)∈ℝ && x^2 + y^2 + y^2 Tan[θ]^2 ≤ 1 + 2 x y Tan[θ]
```

---

``RegionBoundary``:

```wl
In[1]:=
ℛ = RegionBoundary[Disk[{0, 0}, 1]];
Region[ℛ]

Out[1]= [image]

In[2]:= RegionMember[ℛ, {x, y}]

Out[2]= (x | y)∈ℝ && x^2 + y^2 == 1
```

### Applications (6)

#### Basic (2)

Convert polygon data for the given country to a ``MeshRegion`` :

```wl
In[1]:= ℛ = DiscretizeGraphics[CountryData["Austria", {"FullPolygon", "Mercator"}]]

Out[1]= [image]
```

Determine membership of a city:

```wl
In[2]:= city = GeoGridPosition[GeoPosition[Entity["City", {"Vienna", "Vienna", "Austria"}]], "Mercator"]["Data"]

Out[2]= {16.37, 55.1883}

In[3]:= RegionMember[ℛ, city]

Out[3]= True

In[4]:= Show[ℛ, Epilog -> {Red, Point@city}]

Out[4]= [image]
```

---

For a parameterized region, ``RegionMember`` can give conditions on the parameters to determine when a given point is a member:

```wl
In[1]:=
ℛ = Disk[{0, 0}, {Subscript[r, x], Subscript[r, y]}];
RegionMember[ℛ, {3, 4}]

Out[1]= Subscript[r, x] > 0 && Subscript[r, y] > 0 && (9/Subsuperscript[r, x, 2]) + (16/Subsuperscript[r, y, 2]) ≤ 1
```

Find an instance where the region includes the point:

```wl
In[2]:= FindInstance[%, {Subscript[r, x], Subscript[r, y]}]

Out[2]= {{Subscript[r, x] -> 6, Subscript[r, y] -> 5}}
```

Visualize it:

```wl
In[3]:= Graphics[{LightGray, ℛ /. %, Red, Point[{3, 4}]}]

Out[3]= [image]
```

#### Random Points in a Region (2)

Generate points on a region by filtering a uniform set of points:

```wl
In[1]:= ℛ = ImplicitRegion[1 < x ^ 2 + y ^ 2 < 3, {x, y}];
```

Get the region bounds:

```wl
In[2]:= bounds = RegionBounds[ℛ];
```

Uniformly sample over the bounding box of the region:

```wl
In[3]:= pts = RandomVariate[UniformDistribution[bounds], 10 ^ 4];
```

Select member points:

```wl
In[4]:= mpts = Select[pts, RegionMember[ℛ]];
```

Visualize member points:

```wl
In[5]:= Graphics[{AbsolutePointSize[1], Point[mpts]}]

Out[5]= [image]
```

---

Convert polygon data for the given country to a ``MeshRegion`` :

```wl
In[1]:= ℛ = [image];
```

Get the region bounds:

```wl
In[2]:= bounds = RegionBounds[ℛ]

Out[2]= {{-124.733, -66.9498}, {25.1246, 49.3845}}
```

Uniformly sample over the bounding box of the region:

```wl
In[3]:= pts = RandomVariate[UniformDistribution[bounds], 10 ^ 4];

In[4]:=
col = RegionMember[ℛ, pts] /. {False -> Gray, True -> Red};
Graphics[{AbsolutePointSize[1], {col, Point /@ pts}\[Transpose]}]

Out[4]= [image]
```

#### Monte Carlo Integration (2)

Perform Monte Carlo integration to estimate the area of a unit disk:

```wl
In[1]:=
ℛ = Disk[{0, 0}, 1];
Region[ℛ]

Out[1]= [image]
```

Get the region bounds:

```wl
In[2]:= bounds = RegionBounds[ℛ]

Out[2]= {{-1, 1}, {-1, 1}}
```

Uniformly sample over the bounding box of the region:

```wl
In[3]:= pts = RandomVariate[UniformDistribution[bounds], 10 ^ 4];

In[4]:=
col = RegionMember[ℛ, pts] /. {False -> Gray, True -> Red};
Graphics[{ℛ, AbsolutePointSize[1], {col, Point /@ pts}\[Transpose]}]

Out[4]= [image]
```

Count the number of samples inside the region:

```wl
In[5]:= inside = Count[RegionMember[ℛ, pts], True]

Out[5]= 7891
```

Get the ratio of samples inside the region to the total number of sample points:

```wl
In[6]:= ratio = N[(inside/Length[pts])]

Out[6]= 0.7891
```

Get the bounding area:

```wl
In[7]:= area = Area[Cuboid@@(bounds\[Transpose])]

Out[7]= 4
```

Get the approximate area of the region:

```wl
In[8]:= area * ratio

Out[8]= 3.1564
```

---

Use random points in a region to perform Monte Carlo integration:

```wl
In[1]:=
ℛ = ImplicitRegion[2 ≤ x^2 + y^2 ≤ 4, {x, y}];
pts = Select[RandomVariate[UniformDistribution[RegionBounds[ℛ]], 10 ^ 5], RegionMember[ℛ, #]&];
```

Evaluate a function at each sample point and take their average:

```wl
In[2]:=
f[x_, y_] := x^3 + y^4;
intVal = Mean[f@@@pts]RegionMeasure[ℛ]

Out[2]= 21.8398
```

Compare with the exact value:

```wl
In[3]:= Integrate[f[x, y], {x, y}∈ℛ]

Out[3]= 7 π

In[4]:= %//N

Out[4]= 21.9911
```

### Properties & Relations (5)

``Element`` can be used to test region membership for constant regions:

```wl
In[1]:= ℛ = Disk[{0, 0}, 2];

In[2]:= {RegionMember[ℛ, {0, 0}], {0, 0}∈ℛ}

Out[2]= {True, True}
```

---

``RegionDistance`` is 0 for a member:

```wl
In[1]:= ℛ = Disk[{0, 0}, 2];

In[2]:= {RegionMember[ℛ, {0, 0}], RegionDistance[ℛ, {0, 0}]}

Out[2]= {True, 0}
```

---

``SignedRegionDistance`` is non-positive for a member:

```wl
In[1]:= ℛ = Disk[{0, 0}, 1];

In[2]:= {RegionMember[ℛ, {0, 0}], SignedRegionDistance[ℛ, {0, 0}]}

Out[2]= {True, -1}
```

``SignedRegionDistance`` is positive for a non-member:

```wl
In[3]:= {RegionMember[ℛ, {-2, 0}], SignedRegionDistance[ℛ, {-2, 0}]}

Out[3]= {False, 1}
```

---

Use ``RegionNearest`` to find the nearest member:

```wl
In[1]:= ℛ = Disk[{0, 0}, 2];

In[2]:= {RegionMember[ℛ, RegionNearest[ℛ, {3, 3}]], RegionMember[ℛ, {3, 3}]}

Out[2]= {True, False}
```

Visualize it:

```wl
In[3]:= Graphics[{{LightBlue, ℛ}, {Green, Point[RegionNearest[ℛ, {3, 3}]]}, {Red, Point[{3, 3}]}}]

Out[3]= [image]
```

---

Use ``FindInstance`` to find multiple instances for special and formula regions:

```wl
In[1]:= ℛ = ImplicitRegion[x ^ 2 - 2y ^ 2 <= 1, {{x, -3, 3}, {y, -4, 4}}];

In[2]:= Region[ℛ]

Out[2]= [image]
```

Find points that are in both regions:

```wl
In[3]:= pts = FindInstance[{x, y}∈ℛ, {x, y}, 100];

In[4]:= RegionPlot[ℛ, Epilog -> {Red, Point[{x, y} /. pts]}]

Out[4]= [image]
```

## See Also

* [`Element`](https://reference.wolfram.com/language/ref/Element.en.md)
* [`RegionMemberFunction`](https://reference.wolfram.com/language/ref/RegionMemberFunction.en.md)
* [`RegionDistance`](https://reference.wolfram.com/language/ref/RegionDistance.en.md)
* [`SignedRegionDistance`](https://reference.wolfram.com/language/ref/SignedRegionDistance.en.md)
* [`RegionEqual`](https://reference.wolfram.com/language/ref/RegionEqual.en.md)
* [`RegionWithin`](https://reference.wolfram.com/language/ref/RegionWithin.en.md)
* [`MemberQ`](https://reference.wolfram.com/language/ref/MemberQ.en.md)
* [`Between`](https://reference.wolfram.com/language/ref/Between.en.md)
* [`GeometricScene`](https://reference.wolfram.com/language/ref/GeometricScene.en.md)

## Related Guides

* [Region Properties and Measures](https://reference.wolfram.com/language/guide/GeometricPropertiesAndMeasures.en.md)
* [`Polygons`](https://reference.wolfram.com/language/guide/Polygons.en.md)
* [Solid Geometry](https://reference.wolfram.com/language/guide/SolidGeometry.en.md)
* [Plane Geometry](https://reference.wolfram.com/language/guide/PlaneGeometry.en.md)
* [`Polyhedra`](https://reference.wolfram.com/language/guide/Polyhedra.en.md)
* [Synthetic Geometry](https://reference.wolfram.com/language/guide/SyntheticGeometry.en.md)
* [Interval Arithmetic](https://reference.wolfram.com/language/guide/IntervalArithmetic.en.md)

## History

* [Introduced in 2014 (10.0)](https://reference.wolfram.com/language/guide/SummaryOfNewFeaturesIn100.en.md)