WOLFRAM

Wolfram 语言与系统参考资料中心

expr/.rules 或 ReplaceAll[expr,rules]

应用一个规则或规则列表尽可能转换一个表达式 expr 的每个子部分.

ReplaceAll[rules]

表示可以应用于表达式的 ReplaceAll 的操作符格式.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
属性和关系  
可能存在的问题  
参见
技术笔记
相关指南
相关链接
历史
按以下格式引用：

ReplaceAll

expr/.rules 或 ReplaceAll[expr,rules]

应用一个规则或规则列表尽可能转换一个表达式 expr 的每个子部分.

ReplaceAll[rules]

表示可以应用于表达式的 ReplaceAll 的操作符格式.

更多信息

  • ReplaceAll 查看 expr 的每个部分，尝试所有的 rules，然后继续 expr 的下一部分. 使用应用到一个特定部分的第一个规则；在这个部分或它的任何子集没有尝试更多的规则.
  • ReplaceAll 仅对一个表达式应用特定规则一次.
  • 如果没有任何规则被应用，expr/.rules 返回 expr.
  • ReplaceAll[rules][expr] 等价于 ReplaceAll[expr,rules].

范例

打开所有单元 关闭所有单元

基本范例  (5)

用数值替换变量：

Wolfram Language code: {x, x ^ 2, y, z} /. x -> 1

用列表替换变量：

Wolfram Language code: {x, x ^ 2, y, z} /. x -> {a, b}

替换表达式的标头：

Wolfram Language code: Sin[x] /. Sin -> Cos
Wolfram Language code: {a, b, c} /. List -> f

用模式把变量和匹配的部分结合在一起：

Wolfram Language code: 1 + x ^ 2 + x ^ 4 /. x ^ p_ :> f[p]

应用第一个匹配的规则：

Wolfram Language code: x /. {x -> 1, x -> 3, x -> 7}

分别应用每个规则：

Wolfram Language code: x /. {{x -> 1}, {x -> 3}, {x -> 7}}

以操作符格式使用 ReplaceAll：

Wolfram Language code: ReplaceAll[x -> a][{x, x ^ 2, y, z}]

范围  (14)

如果没有相匹配的规则，则返回原来的表达式：

Wolfram Language code: x /. {y -> 2, z -> 3}

匹配只有一个参数的表达式：

Wolfram Language code: {f[2], f[x, y], h[], f[]} /. f[x_] -> "OK"

匹配有一个或更多参数的表达式：

Wolfram Language code: {f[2], f[x, y], h[], f[]} /. f[x__] -> "OK"

匹配有零个或更多参数的表达式：

Wolfram Language code: {f[2], f[x, y], h[], f[]} /. f[x___] -> "OK"

用特定的标头替换表达式：

Wolfram Language code: {1, 3, 2, x, 6, Pi} /. _Integer :> "int"

用 PatternTest 替换测试方程的结果为 True 的部分：

Wolfram Language code: {1, 3, 2, x, 6, Pi} /. _ ? PrimeQ -> "prime"

用 Condition 对满足布尔表达式的部分进行替换：

Wolfram Language code: {1, 3, 2, x, 6, Pi} /. t_ /; Mod[t, 3] == 0 -> "3k"

替换成对中的一对：

Wolfram Language code: {{a, 1}, {b, 2}} /. {x_, y_} :> Subscript[x, y]

通过限制模式取代每个内部对：

Wolfram Language code: {{a, 1}, {b, 2}} /. {x_Symbol, y_} :> Subscript[x, y]

ReplaceAll 还可用于 RuleDelayed：

Wolfram Language code: {x, x, x} /. x :> RandomReal[]

根据结构插入保留表达式中：

Wolfram Language code: Hold[x + x] /. x -> 7

在替换前不对规则的右侧进行运算：

Wolfram Language code: Hold[x + x] /. x :> 2 ^ 2

在替换前对规则的右侧进行运算：

Wolfram Language code: Hold[x + x] /. x -> 2 ^ 2

Dispatch 可以代替规则列表：

Wolfram Language code: {1, 2} /. Dispatch[{1 -> a, 3 -> b}]

Association 可以代替规则列表：

Wolfram Language code: {a, b} /. Association[{a -> 1, c -> 2}]

用 Association 作为替换用的模式：

Wolfram Language code: <|a -> 1|> /. <|a -> x_|> :> x

用 KeyValuePattern 在规则列表中进行替换：

Wolfram Language code: {a -> 1, b -> 2} /. KeyValuePattern[{a -> x_}] -> x

从 Association 中提取和规则匹配的键：

Wolfram Language code: ReplaceAll[<|a -> 1, b -> 2, c -> 3|>, KeyValuePattern[{x_ -> 1}] :> x]

从规则列表中找出满足某个标准的键：

Wolfram Language code: {a -> 1, b -> 2} /. KeyValuePattern[{x_ -> _ ? EvenQ}] -> x

属性和关系  (7)

空列表被视为不含有匹配的规则：

Wolfram Language code: x /. {}

当用列表的列表进行替换时，结果为同样长度的列表：

Wolfram Language code: x /. {{x -> 1}, {y -> 2}}

只有第一条匹配的规则被应用于每个部分：

Wolfram Language code: {a, b, c} /. {a -> b, b -> d}

反复调用 ReplaceAll 将每个规则应用于所有部分：

Wolfram Language code: {a, b, c} /. a -> b /. b -> d

当对保留表达式进行替换时，不强制进行计算：

Wolfram Language code: {g[1], Hold[g[1]]} /. g[n_] -> n + 1

ReplaceAll 替换所有匹配的部分：

Wolfram Language code: f[1, 2, z] /. _Integer :> "int"

缺省情况下，Replace 替换整个表达式：

Wolfram Language code: Replace[f[1, 2, z], _Integer :> "int"]

也允许替换指定层：

Wolfram Language code: Replace[f[1, 2, z], _Integer :> "int", {1}]

ReplaceAll 对所能替换的最大的子表达式进行替换，然后停止操作：

Wolfram Language code: rules = {f[x_] -> f[x, 5], f[x__] -> {x, 1}};
Wolfram Language code: {f[a], f[f[a, b]]} /. rules

ReplaceRepeated 重复应用 ReplaceAll 直到表达式不再变化为止：

Wolfram Language code: {f[a], f[f[a, b]]} //. rules
Wolfram Language code: % === ({f[a], f[f[a, b]]} /. rules /. rules /. rules)

带有参数 All 的 Replace 将尝试只对每个子表达式进行一次替换：

Wolfram Language code: Replace[{f[a], f[f[a, b]]}, rules, All]

ReplaceAll 替换和模式匹配的表达式的部分：

Wolfram Language code: {5, 4, 3, 2, 1} /. _ ? PrimeQ -> "p"

ReplacePart 替换位置和模式匹配的表达式的部分：

Wolfram Language code: ReplacePart[{5, 4, 3, 2, 1}, _ ? PrimeQ -> "p"]

可能存在的问题  (4)

应用较长的规则列表会比较慢：

Wolfram Language code: rules = Table[x[i] -> RandomInteger[{1, i}], {i, 10000}];
Wolfram Language code: Timing[Table[x[i] /. rules, {i, 10000}];]

使用 Dispatch 会大幅提高速度：

Wolfram Language code: disp = Dispatch[rules];
Wolfram Language code: Timing[Table[x[i] /. disp, {i, 10000}];]

可以用关联来指定替换规则，但是把键视为 Verbatim 值：

Wolfram Language code: assoc = <|1 -> True, _ -> False|>;
Wolfram Language code: {1, 2, _} /. assoc

与下式比较：

Wolfram Language code: list = Normal[assoc]
Wolfram Language code: {1, 2, _} /. list

等价于关联的规则列表如下所示：

Wolfram Language code: {1, 2, _} /. {1 -> True, Verbatim[_] -> False}

句号与数字的绑定关系要强过与斜杠的绑定关系，所以下面所示为除法操作：

Wolfram Language code: {0, 1} / .0 -> "zero"

在 /. 和数字间插入一个空格以避免这个问题：

Wolfram Language code: {0, 1} /. 0 -> "zero"

大多数情况下，模式只与关联的值进行比较：

Wolfram Language code: <|a -> f[b -> c]|> /. (k_ -> v_) :> g[k, v]

对于和 Association 匹配的混合模式，里面的模式同时匹配键和值：

Wolfram Language code: <|a -> f[b -> c]|> /. _[k_ -> v_] :> g[k, v]

去掉和 Association 匹配的标头，只与值进行比较：

Wolfram Language code: <|a -> f[b -> c]|> /. Except[Association][k_ -> v_] :> g[k, v]
Wolfram Research (1988)，ReplaceAll，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ReplaceAll.html （更新于 2015 年）.

文本

Wolfram Research (1988)，ReplaceAll，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ReplaceAll.html （更新于 2015 年）.

CMS

Wolfram 语言. 1988. "ReplaceAll." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2015. https://reference.wolfram.com/language/ref/ReplaceAll.html.

APA

Wolfram 语言. (1988). ReplaceAll. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/ReplaceAll.html 年

BibTeX

@misc{reference.wolfram_2026_replaceall, author="Wolfram Research", title="{ReplaceAll}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/ReplaceAll.html}", note=[Accessed: 02-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_replaceall, organization={Wolfram Research}, title={ReplaceAll}, year={2015}, url={https://reference.wolfram.com/language/ref/ReplaceAll.html}, note=[Accessed: 02-August-2026]}