SQLSelect

DatabaseLink`

SQLSelect

SQLSelect[conn,table]

SQL接続中の表からデータを抽出する．

SQLSelect[conn,table,cols]

特定の列からデータを抽出する．

SQLSelect[conn,table,cols,cond]

cond に合致するデータのみを抽出する．

詳細とオプション

SQLSelectを使うためには，まずNeeds["DatabaseLink`"]を使って DatabaseLink をロードする必要がある．
使用可能なオプション

"Distinct"	False	重複しない結果だけを返すかどうか
"FetchSize"	Automatic	JDBCドライバへの結果セットの大きさの提示
"GetAsStrings"	False	結果を文字列として返すかどうか
"MaxFieldSize"	Automatic	可変長の列のタイプのバイト制限
"MaxRows"	Automatic	返される最大行数
"ShowColumnHeadings"	False	結果とともに列見出しを返すかどうか
"SortingColumns"	None	データのソート方法
"ColumnSymbols"	None	結果に関連付けるシンボル
"Timeout"	$SQLTimeout	クエリのタイムアウト

例題

すべて開くすべて閉じる

例 (1)

Wolfram Language code: Needs["DatabaseLink`"]

このセクションの例を実際に試してみて，記載の通りに動作しなかった場合は，データベースの例の使用で述べているようにDatabaseLink`DatabaseExamples`パッケージを使ってデータベースをインストールするか，もとの状態に戻す必要がある可能性がある．

接続を開始する：

Wolfram Language code: conn = OpenSQLConnection["publisher"];

表のすべてのデータを選択する：

Wolfram Language code: SQLSelect[conn, "ROYSCHED"]

特定の列のみを選択する：

Wolfram Language code: SQLSelect[conn, "ROYSCHED", {"TITLE_ID", "ROYALTY"}]

複数の表のデータを結合する：

Wolfram Language code:

SQLSelect[conn, {"TITLES", "ROYSCHED"}, {{"TITLES", "TITLE"}, {"TITLES", "TITLE_ID"}, {"ROYSCHED", "ROYALTY"}}, SQLColumn[{"TITLES", "TITLE_ID"}] == SQLColumn[{"ROYSCHED", "TITLE_ID"}]]//Short[#, 15]&

条件に合致するデータを選択する：

Wolfram Language code: SQLSelect[conn, "ROYSCHED", {"TITLE_ID", "ROYALTY"}, .10 < SQLColumn["ROYALTY"] < .15]

パターンに合致するデータを選択する：

Wolfram Language code: SQLSelect[conn, "ROYSCHED", {"TITLE_ID", "ROYALTY"}, SQLStringMatchQ[SQLColumn["TITLE_ID"], "C%"]]

Wolfram Language code: SQLSelect[conn, "ROYSCHED", {"TITLE_ID", "ROYALTY"}, SQLStringMatchQ[SQLColumn["TITLE_ID"], "_S%"]]

リストに合致するデータを選択する：

Wolfram Language code: SQLSelect[conn, "ROYSCHED", {"TITLE_ID", "ROYALTY"}, SQLMemberQ[{.14, .16}, SQLColumn["ROYALTY"]]]

Wolfram Language code: CloseSQLConnection[conn];

スコープ (1)

Wolfram Language code: Needs["DatabaseLink`"]

Wolfram Language code: conn = OpenSQLConnection["publisher"];

条件に合致するデータを選択する：

Wolfram Language code: SQLSelect[conn, "ROYSCHED", {"TITLE_ID", "ROYALTY"}, .13 > SQLColumn["ROYALTY"] > .10]

Wolfram Language code: SQLSelect[conn, "ROYSCHED", {"TITLE_ID", "ROYALTY"}, SQLColumn["ROYALTY"] == .12]

Wolfram Language code: SQLSelect[conn, "ROYSCHED", {"TITLE_ID", "ROYALTY"}, SQLColumn["ROYALTY"] != .12]

Wolfram Language code: SQLSelect[conn, "ROYSCHED", {"TITLE_ID", "ROYALTY"}, SQLColumn["ROYALTY"] > .12]

Wolfram Language code: SQLSelect[conn, "ROYSCHED", {"TITLE_ID", "ROYALTY"}, SQLColumn["ROYALTY"] < .12]

Wolfram Language code: SQLSelect[conn, "ROYSCHED", {"TITLE_ID", "ROYALTY"}, SQLColumn["ROYALTY"] ≥ .12]

Wolfram Language code: SQLSelect[conn, "ROYSCHED", {"TITLE_ID", "ROYALTY"}, SQLColumn["ROYALTY"] ≤ .12]

AndとOrを使って条件を組み合せる：

Wolfram Language code:

SQLSelect[conn, "ROYSCHED", {"TITLE_ID", "LORANGE", "ROYALTY"}, SQLColumn["ROYALTY"] == .12 && SQLColumn["LORANGE"] > 1000]

Wolfram Language code: SQLSelect[conn, "ROYSCHED", {"TITLE_ID", "ROYALTY"}, SQLColumn["ROYALTY"] == .12 || SQLColumn["ROYALTY"] == .14]

Wolfram Language code: CloseSQLConnection[conn];

オプション (8)

"Distinct" (1)

Wolfram Language code: Needs["DatabaseLink`"]

重複しない値を取り出す：

Wolfram Language code: conn = OpenSQLConnection["publisher"]

Wolfram Language code: Flatten@SQLSelect[conn, "ROYSCHED", {"ROYALTY"}, "Distinct" -> True]

Wolfram Language code: CloseSQLConnection[conn];

"FetchSize" (1)

Wolfram Language code:

Needs["JLink`"];


Needs["DatabaseLink`"];

"FetchSize"オプションは，データベースへの各アクセスの際に取り出す行数をJDBCドライバに提案する．パラメータを増やすと，使用メモリ量が増え，代りにクエリの実行に必要なネットワークトラフィック量が減る：

Wolfram Language code:

AddToClassPath["/Users/me/Documents/DatabaseLink/drivers"];
connSpec = {JDBC["oracle.jdbc.driver.OracleDriver", "jdbc:oracle:thin:@server.domain.wolfram.com:1521:xe"], Username -> "GUEST", Password -> "GUEST"};conn = OpenSQLConnection@@connSpec

カーネル層とJava層の両方を含む使用メモリ量を計算する：

Wolfram Language code:

javaMem[] := Module[{rt}, 
	LoadJavaClass["java.lang.Runtime"];
	rt = Runtime`getRuntime[];
	rt@totalMemory[](* allocated; some is free for jvm use *)
	];
memReport[] := TableForm[List@{MemoryInUse[], javaMem[], MemoryInUse[] + javaMem[]}, TableHeadings -> {None, {"Kernel", "Java", "Total"}}]

Wolfram Language code: memReport[]

小さい取出しサイズで大きい結果を取り出す：

Wolfram Language code:

AbsoluteTiming[
	ByteCount@SQLSelect[conn, "test_tab", "MaxRows" -> 20000, "FetchSize" -> 5]
	]

Wolfram Language code: memReport[]

再設定する：

Wolfram Language code:

CloseSQLConnection[conn];
ReinstallJava[];
conn = OpenSQLConnection@@connSpec;
memReport[]

大きい取出しサイズで大きい結果を取り出す：

Wolfram Language code:

AbsoluteTiming[
	ByteCount@SQLExecute[conn, "SELECT * FROM test_tab", "MaxRows" -> 20000, "FetchSize" -> 10000]
	]

Wolfram Language code: memReport[]

Wolfram Language code: CloseSQLConnection[conn];

"GetAsStrings" (1)

Wolfram Language code: Needs["DatabaseLink`"]

データをWolfram言語型に変換しないで読み取る：

Wolfram Language code: conn = OpenSQLConnection["publisher"]

Wolfram Language code: SQLSelect[conn, "ROYSCHED", {"ROYALTY"}, "GetAsStrings" -> True]//InputForm

Wolfram Language code: CloseSQLConnection[conn];

"MaxFieldSize" (1)

Wolfram Language code: Needs["DatabaseLink`"]

可変長の列のタイプによっては，"MaxFieldSize"オプションを使ってフィールドに返されるバイト数を制限することができる：

Wolfram Language code:

conn = OpenSQLConnection[JDBC["Derby(Embedded)", FileNameJoin[{$TemporaryDirectory, "scratch"}]], "Properties" -> {"create" -> "true"}]

VARCHARフィールドで表を作成する：

Wolfram Language code: SQLCreateTable[conn, SQLTable["STRINGS"], {SQLColumn["string", "DataTypeName" -> "VARCHAR(512)"]}]

文字列データを挿入する：

Wolfram Language code:

SQLInsert[conn, SQLTable["STRINGS"], {SQLColumn["string"]}, {StringTake[ExampleData[{"Text", "AeneidEnglish"}], 512]}
	]

結果のバイト長を制限して，文字列の内容を選択する：

Wolfram Language code: res = SQLSelect[conn, "STRINGS", "string", "MaxFieldSize" -> 64]

Wolfram Language code: StringLength@res[[1, 1]]

Wolfram Language code: SQLDropTable[conn, "STRINGS"]

Wolfram Language code: CloseSQLConnection[conn];

"MaxRows" (1)

Wolfram Language code: Needs["DatabaseLink`"]

結果に返される行数を制限する：

Wolfram Language code: conn = OpenSQLConnection["publisher"];

Wolfram Language code: SQLSelect[conn, "AUTHORS", "MaxRows" -> 5]//TableForm

Wolfram Language code: CloseSQLConnection[conn];

"ShowColumnHeadings" (1)

Wolfram Language code: Needs["DatabaseLink`"]

結果の最初の行に列名を含む：

Wolfram Language code: conn = OpenSQLConnection["publisher"];

Wolfram Language code: SQLSelect[conn, "ROYSCHED", {"TITLE_ID", "ROYALTY"}, "ShowColumnHeadings" -> True]//Take[#, 10]&//TableForm

Wolfram Language code: CloseSQLConnection[conn];

"SortingColumns" (1)

Wolfram Language code: Needs["DatabaseLink`"]

並べる基準に使用する列を指定する：

Wolfram Language code: conn = OpenSQLConnection["publisher"];

Wolfram Language code:

SQLSelect[conn, "ROYSCHED", {"TITLE_ID", "ROYALTY"}, 
	"SortingColumns" -> {
	SQLColumn["ROYALTY"] -> "Ascending", 
	SQLColumn["TITLE_ID"] -> "Ascending"
	}
	]

Wolfram Language code: CloseSQLConnection[conn];

"ColumnSymbols" (1)

Wolfram Language code: Needs["DatabaseLink`"]

クエリの結果が割り当てられるシンボルのリストを与える：

Wolfram Language code: conn = OpenSQLConnection["demo"];

Wolfram Language code:

Clear[entries, values, names];SQLSelect[conn, "SAMPLETABLE1", {"ENTRY", "VALUE", "NAME"}, "ColumnSymbols" -> {entries, values, names}];

Wolfram Language code: entries

Wolfram Language code: values

Wolfram Language code: names

自動的にシンボルを作成する：

Wolfram Language code: Clear[entries, values, names];SQLSelect[conn, "SAMPLETABLE1", {"ENTRY", "VALUE", "NAME"}, "ColumnSymbols" -> Automatic];

Wolfram Language code: Names["Global`col*"]

Wolfram Language code: Global`col1

Wolfram Language code: Global`col2

Wolfram Language code: Global`col3

列の名前と結果に作用する関数を与える．列見出しが要求されていない場合は，関数の最初の引数はNullとなる：

Wolfram Language code:

SQLSelect[conn, "SAMPLETABLE1", {"ENTRY", "VALUE"}, "ShowColumnHeadings" -> True, 
	"ColumnSymbols" -> Function[{cols, res}, 
	With[{syms = Symbol["SAMPLETABLE1" <> #]& /@ cols}, 
	Evaluate[syms] = Transpose[res]
	]
	]
	]

Wolfram Language code: SAMPLETABLE1ENTRY

Wolfram Language code: SAMPLETABLE1VALUE

Wolfram Language code:

Clear@values;
SQLSelect[conn, "SAMPLETABLE1", "VALUE", "ColumnSymbols" -> ((values = Flatten[#2])&)];

Wolfram Language code: values

Wolfram Language code: CloseSQLConnection[conn];

アプリケーション (1)

Wolfram Language code: Needs["DatabaseLink`"]

Wolfram Language code: conn = OpenSQLConnection["publisher"];

Wolfram Language code: data = SQLSelect[conn, "ROYSCHED", {"TITLE_ID", "ROYALTY"}]

Wolfram Language code: Histogram[data[[All, -1]]]

Wolfram Language code: CloseSQLConnection[conn];

Top

その他のラーニングリソース

テクニカルサポート

Wolframソリューション

教育のためのWolframソリューション

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

SQLSelect

詳細とオプション

例題

例 (1)

スコープ (1)

オプション (8)

"Distinct" (1)

"FetchSize" (1)

"GetAsStrings" (1)

"MaxFieldSize" (1)

"MaxRows" (1)

"ShowColumnHeadings" (1)

"SortingColumns" (1)

"ColumnSymbols" (1)

アプリケーション (1)

SQLSelect

詳細とオプション

例題

例 (1)

スコープ (1)

オプション (8)

"Distinct" (1)

"FetchSize" (1)

"GetAsStrings" (1)

"MaxFieldSize" (1)

"MaxRows" (1)

"ShowColumnHeadings" (1)

"SortingColumns" (1)

"ColumnSymbols" (1)

アプリケーション (1)

関連項目

テクニカルノート

関連するガイド