WOLFRAM

Wolfram 语言与系统参考资料中心

ElementMeshRegionProduct[mesh1,mesh2]

represents the Cartesian product of the ElementMesh mesh1 and mesh2.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
Scope  
Options  
"RegionMarkerFunction"  
参见
技术笔记
按以下格式引用：
FEMDocumentation`
FEMDocumentation`

ElementMeshRegionProduct

ElementMeshRegionProduct[mesh1,mesh2]

represents the Cartesian product of the ElementMesh mesh1 and mesh2.

更多信息和选项

  • ElementMeshRegionProduct is also known as outer product region.
  • ElementMeshRegionProduct[mesh1,mesh2] represents the region .
  • The embedding dimension of the product region is the sum of embedding dimensions, and the geometric dimension is the sum of geometric dimensions.
  • The highest product dimension supported is 3.
  • ElementMeshRegionProduct has the following options:
  • "RegionMarkerFunction"Nonespecify region markers

范例

打开所有单元 关闭所有单元

基本范例  (2)

Load the package:

Wolfram Language code: Needs["NDSolve`FEM`"]

Create an ElementMesh:

Wolfram Language code: mesh = ToElementMesh[Line[{{0}, {1}}]]

Compute the ElementMesh region product:

Wolfram Language code: productMesh = ElementMeshRegionProduct[mesh, mesh]

Visualize the region product mesh:

Wolfram Language code: productMesh["Wireframe"]

Create three ElementMesh instances:

Wolfram Language code: meshX = ToElementMesh[Line[{{0}, {2}}]]; meshY = ToElementMesh[Line[{{0}, {1}}]]; meshZ = ToElementMesh[Line[{{0}, {3}}]];

Compute the ElementMesh region product:

Wolfram Language code: productMesh = ElementMeshRegionProduct[meshX, meshY, meshZ]

Visualize the region product mesh:

Wolfram Language code: productMesh["Wireframe"]

Scope  (1)

Create two ElementMesh instances:

Wolfram Language code: meshXY = ToElementMesh[Disk[], MaxCellMeasure -> 0.1]; meshZ = ToElementMesh[Line[{{0}, {3}}]];

Compute the ElementMesh region product:

Wolfram Language code: productMesh = ElementMeshRegionProduct[meshXY, meshZ]

Visualize the region product mesh:

Wolfram Language code: productMesh["Wireframe"]

Options  (2)

"RegionMarkerFunction"  (2)

Create a marker association and a region member function:

Wolfram Language code: regs = <|"solid" -> 10, "fluid" -> 20|>; rmf = RegionMember[Rectangle[{1.2, 0}, {1.8, 3}]];

Define a region marker function:

Wolfram Language code: myRegionMarkerFunction = With[{rmf = rmf, rs = regs["solid"], rf = regs["fluid"]}, If[rmf[#], rs, rf]&];

Create ElementMesh that is used in each direction:

Wolfram Language code: mesh = ToElementMesh[Line[{{0.}, {3.}}]];

Compute the ElementMesh region product:

Wolfram Language code: mesh = ElementMeshRegionProduct[mesh, mesh, "RegionMarkerFunction" -> myRegionMarkerFunction]

Inspect the "MeshElementMarkerUnion" of the generated mesh:

Wolfram Language code: mesh["MeshElementMarkerUnion"]

Visualize the region product mesh with the region markers:

Wolfram Language code: Show[mesh["Wireframe"["MeshElementStyle" -> {Directive[FaceForm[Red]], Directive[FaceForm[Green]]}]], AspectRatio -> 1]

Create a marker association and a region member function:

Wolfram Language code: regs = <|"left" -> 1, "central" -> 3, "right" -> 2|>; rLeft = RegionMember[Cuboid[{0, 0, 0}, {0.8, 2, 2}]]; rCentral = RegionMember[Cuboid[{0.8, 0, 0}, {1.2, 2, 2}]]; rRight = RegionMember[Cuboid[{1.2, 0, 0}, {2, 2, 2}]];

Define a region marker function:

Wolfram Language code: myRegionMarkerFunction = With[{rmf = rmf, rl = regs["left"], rc = regs["central"], rr = regs["right"]}, If[rLeft[#], rl, If[rCentral[#], rc, rr]]&];

Create ElementMesh that is used in each direction:

Wolfram Language code: mesh = ToElementMesh[Line[{{0.}, {2.}}]];

Compute the ElementMesh region product:

Wolfram Language code: mesh = ElementMeshRegionProduct[mesh, mesh, mesh, "RegionMarkerFunction" -> myRegionMarkerFunction]

Inspect the "MeshElementMarkerUnion" of the generated mesh:

Wolfram Language code: mesh["MeshElementMarkerUnion"]

Visualize the region product mesh with the region markers:

Wolfram Language code: Show[Map[mesh["Wireframe"[ElementMarker == #[[1]], "MeshElement" -> "MeshElements", "ElementMeshDirective" -> Directive[EdgeForm[], FaceForm[#[[2]]]]]]&, {{1, Green}, {2, Orange}, {3, Red}}] , PlotRange -> {All, {1, 2}, All}]
Wolfram Research (2021)，ElementMeshRegionProduct，Wolfram 语言函数，https://reference.wolfram.com/language/FEMDocumentation/ref/ElementMeshRegionProduct.html.

文本

Wolfram Research (2021)，ElementMeshRegionProduct，Wolfram 语言函数，https://reference.wolfram.com/language/FEMDocumentation/ref/ElementMeshRegionProduct.html.

CMS

Wolfram 语言. 2021. "ElementMeshRegionProduct." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/FEMDocumentation/ref/ElementMeshRegionProduct.html.

APA

Wolfram 语言. (2021). ElementMeshRegionProduct. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/FEMDocumentation/ref/ElementMeshRegionProduct.html 年

BibTeX

@misc{reference.wolfram_2026_elementmeshregionproduct, author="Wolfram Research", title="{ElementMeshRegionProduct}", year="2021", howpublished="\url{https://reference.wolfram.com/language/FEMDocumentation/ref/ElementMeshRegionProduct.html}", note=[Accessed: 10-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_elementmeshregionproduct, organization={Wolfram Research}, title={ElementMeshRegionProduct}, year={2021}, url={https://reference.wolfram.com/language/FEMDocumentation/ref/ElementMeshRegionProduct.html}, note=[Accessed: 10-August-2026]}