Analyze the Performance of a Queueing Network

Define an open queueing network:

Wolfram Language code:

γ = {3, 6};μ = {7, 17};
r = {{1 / 6, 1 / 9}, {1 / 4, 1 / 8}};
c = {1, 1};

Wolfram Language code: 𝒩 = QueueingNetworkProcess[γ, r, μ, c];

Simulate the network:

Wolfram Language code: data = RandomFunction[𝒩, {0, 10}];

Plot the simulated values at the nodes in the network:

Wolfram Language code: ListLinePlot[data, Filling -> Axis]

Performance measures at the nodes in the network:

Wolfram Language code: Table[QueueProperties[{𝒩, i}], {i, 2}]//N

Stationary distribution for the network:

Wolfram Language code: 𝒟 = StationaryDistribution[𝒩];

Probability density function for the steady state of the network:

Wolfram Language code: PDF[𝒟, {m, n}]

Wolfram Language code: DiscretePlot3D[PDF[𝒟, {m, n}]//Evaluate, {m, 0, 4}, {n, 0, 4}, ExtentSize -> 0.5, PlotRange -> All]

Cumulative distribution function for the steady state of the network:

Wolfram Language code: CDF[𝒟, {m, n}]

Wolfram Language code: DiscretePlot3D[CDF[𝒟, {m, n}]//Evaluate, {m, 0, 35}, {n, 0, 35}, ExtentSize -> Right, PlotRange -> {0, 1.05}]

Top

More Learning