WOLFRAM

Wolfram Language & System Documentation Center

Design a PID Room Temperature Controller

Design a PID controller that maintains room temperature near 22 °C even with fluctuations of the outside temperature, modeled as a disturbance.

Enter the models:
Wolfram Language code: {valve, burner, thermres, room} = {TransferFunctionModel[Unevaluated[{{(1/(1 + 4s))}}], s, SamplingPeriod -> None, SystemsModelLabels -> {{None}, {None}}], TransferFunctionModel[Unevaluated[{{5}}], s, SamplingPeriod -> None, SystemsModelLabels -> {{None}, {None}}], TransferFunctionModel[Unevaluated[{{0.1}}], s, SamplingPeriod -> None, SystemsModelLabels -> {{None}, {None}}], TransferFunctionModel[Unevaluated[{{(1/(1 + 8s))}}], s, SamplingPeriod -> None, SystemsModelLabels -> {{None}, {None}}]};
Wolfram Language code: hsys = SystemsModelSeriesConnect[valve, SystemsModelSeriesConnect[burner, thermres]];
Wolfram Language code: lsys = SystemsModelSeriesConnect[room, hsys];
Obtain the controller:
Wolfram Language code: pid = PIDTune[lsys, {Automatic, "AMIGO"}, "PIDData"];
The disturbance to output transfer function:
Wolfram Language code: doTFM = SystemsModelFeedbackConnect[room, SystemsModelSeriesConnect[pid["Feedback"], hsys]]
Get the outside temperature history for a particular location:
Wolfram Language code: {times, values} = WeatherData["Chicago", "Temperature", {DatePlus[Date[], -1], Date[]}]["Path"]//Transpose;
Wolfram Language code: values = QuantityMagnitude /@ values;
The temperature as a continuous function of time:
Wolfram Language code: timeSec = QuantityMagnitude[DateDifference[First[times], #, "Second"]]& /@ times;
Wolfram Language code: d = Interpolation[Transpose[{timeSec, values}]];
Compute the regulated room temperature and sample it every minute:
Wolfram Language code: temp = OutputResponse[pid["ReferenceOutput"], 22, {t, 0, Last[timeSec]}] + OutputResponse[doTFM, d[t], {t, 0, Last[timeSec]}];
Wolfram Language code: temps = Table[temp, {t, 0, Last[timeSec], 60}]//Flatten;
Plot the room temperature and the outside temperature:
Wolfram Language code: roomTplot = DateListPlot[temps, {First[times], Last[times]}, PlotStyle -> Red, Joined -> True, PlotLegends -> LineLegend[{"Room temperature"}]];
Wolfram Language code: outTplot = DateListPlot[Transpose[{times, values}], Joined -> True, PlotLegends -> LineLegend[{"Outside temperature"}]];
Wolfram Language code: Show[roomTplot, outTplot, ImageSize -> Medium, FrameLabel -> {"Hours", "°C"}, PlotRange -> {-5, 25}]