WOLFRAM

Wolfram Language & System Documentation Center
Electric Potential and Field of a Dipole

Electric Potential and Field of a Dipole

    
Compute the electric field of a dipole from its potential and verify that it is a vacuum solution by computing the divergence:
Wolfram Language code: Vs = (p Cos[θ]) / r ^ 2
Wolfram Language code: Es = -Grad[Vs, {r, θ, φ}, "Spherical"]
Wolfram Language code: Div[Es, {r, θ, φ}, "Spherical"] == 0
Compute the equivalent fields in Cartesian coordinates for p1 and visualize the equipotential surfaces and lines of force:
Wolfram Language code: Vc = TransformedField[ "Spherical" -> "Cartesian", Vs, {r, θ, φ} -> {x, y, z}] /. p -> 1
Wolfram Language code: Ec = TransformedField["Spherical" -> "Cartesian", Es, {r, θ, φ} -> {x, y, z}] /. p -> 1
Wolfram Language code: equipotentials = ContourPlot3D[Vc, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, ContourStyle -> Table[{Opacity[.5], Hue[i / 10]}, {i, 7}], Contours -> {-50, -5, -1, 0, 1, 5, 50}, Mesh -> None];
Wolfram Language code: electricField = VectorPlot3D[Ec, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, VectorAspectRatio -> 1 / 4, VectorScaling -> Automatic];
Wolfram Language code: Show[equipotentials, electricField]