WOLFRAM

Wolfram Language & System Documentation Center

Show Path with Arrows in a Matrix

Easily style vertices, edges, and their labels, and apply interesting functions. For a small increase in code sophistication, you gain quite an advantage.

    
Define a path:
Wolfram Language code: poli = {{1, 1}, {2, 1}, {3, 1}, {4, 1}, {5, 1}, {5, 2}, {4, 2}, {3, 2}, {2, 2}, {1, 2}, {1, 3}, {2, 3}, {3, 3}, {4, 3}, {5, 3}, {5, 4}, {4, 4}, {4, 5}, {5, 5}};
Define the edge shape function:
Wolfram Language code: arrow[coord_, e_] := Style[Arrow[coord], Red, Thickness[.01], Arrowheads[0.06]]
Create the path graph:
Wolfram Language code: pg = PathGraph[Range[19], VertexCoordinates -> poli, EdgeShapeFunction -> arrow, ImageSize -> 300, PlotRangePadding -> .2, VertexLabels -> ""]
Create the overall grid:
Wolfram Language code: gg = GridGraph[{5, 5}, EdgeStyle -> Dashed, VertexLabels -> "Name", ImageSize -> 300, PlotRangePadding -> .2]
Overlay them:
Wolfram Language code: Overlay[{gg, pg}]
A different approach uses GridGraph with the GraphHighlight option:
Wolfram Language code: vertex = (5 (#[[1]] - 1) + #[[2]])& /@ poli; edge = (#[[1]]#[[2]])& /@ Partition[vertex, 2, 1];
Wolfram Language code: lab = MapThread[Rule[#1, ToString@#2]&, {vertex, poli}];
Highlight the path:
Wolfram Language code: GridGraph[{5, 5}, EdgeStyle -> Dashed, GraphHighlight -> edge, VertexLabels -> lab, PlotRangePadding -> .3]
Add arrows to indicate the path direction:
Wolfram Language code: arr[coord_, e_] := Style[Arrow[If[Positive[(e)[[2]] - (e)[[1]]], Identity[coord], Reverse[coord]]], Red, Thickness[.01], Arrowheads[0.06]]
Wolfram Language code: GridGraph[{5, 5}, EdgeStyle -> Dashed, GraphHighlight -> edge, VertexLabels -> lab, PlotRangePadding -> .5, EdgeShapeFunction -> (# -> arr& /@ edge)]