WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

AbsoluteDashing[{d1,d2,…}]

グラフィックス指示子であり，これに続く線を絶対的な長さ d1, d2, … （周期的に繰り返される）を各節とする破線で描く．

AbsoluteDashing[d]

AbsoluteDashing[{d,d}]と等価である．

AbsoluteDashing[{d1,d2,…},offset]

破線にオフセット offset を加える．

AbsoluteDashing[{d1,d2,…},offset,capform]

個々の破線にCapForm capform を設定する．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
破線指定  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

AbsoluteDashing

AbsoluteDashing[{d1,d2,…}]

グラフィックス指示子であり，これに続く線を絶対的な長さ d1, d2, … （周期的に繰り返される）を各節とする破線で描く．

AbsoluteDashing[d]

AbsoluteDashing[{d,d}]と等価である．

AbsoluteDashing[{d1,d2,…},offset]

破線にオフセット offset を加える．

AbsoluteDashing[{d1,d2,…},offset,capform]

個々の破線にCapForm capform を設定する．

詳細

  • 破線とオフセットの長さは，印刷用ポイント数を単位にして指定する．1ポイントは，拡大前でインチに相当する．
  • AbsoluteDashing[{}]は，線が実線になるように指定する． »
  • AbsoluteDashingは，2Dと3Dの両方のグラフィックス，それにStyle指定に使うことができる．
  • d には，Tiny，Small，Medium，Largeの記号形式を使うことができる． »
  • 長さが0に指定された線分の長さが diである場合，この線分は直径が線の太さである点として描画される．
  • offset は正または負の印刷用ポイントサイズで指定される．offset は，指定されていない場合は0である．
  • capform はCapForm[form]の任意の正当な form の値を取ることができる．これが指定されていない場合は，すべての線分が"Butt"キャップ形式で描画される．

例題

すべて開く すべて閉じる

例  (2)

線の破線の長さを印刷用ポイント数で表し，連続する線分として指定する：

Wolfram Language code: Table[Graphics[{AbsoluteDashing[{d, 15 - d}], Line[{{0, 0}, {2, 1}}]}], {d, {2, 5, 8, 12}}]
Wolfram Language code: Table[Graphics3D[{AbsoluteDashing[{d, 15 - d}], Line[{{0, 0, 0}, {2, 1, 1}}]}], {d, {2, 5, 8, 12}}]

Dashed，Dotted，DotDashedを使って定義済みの絶対破線を指定する：

Wolfram Language code: {Graphics[{Dashed, Line[{{0, 0}, {2, 1}}]}], Graphics[{Dotted, Line[{{0, 0}, {2, 1}}]}], Graphics[{DotDashed, Line[{{0, 0}, {2, 1}}]}]}

スコープ  (4)

破線指定  (4)

破線は使わない：

Wolfram Language code: Graphics[{AbsoluteDashing[{}], Line[{{0, 0}, {2, 1}}]}]

AbsoluteDashing[d]はAbsoluteDashing[{d,d}]に等しい：

Wolfram Language code: Table[Graphics[{AbsoluteDashing[d], Line[{{0, 0}, {2, 1}}]}], {d, {2, 5, 8, 12}}]

定義済みの絶対破線の記号としての値：

Wolfram Language code: Table[Graphics[{AbsoluteDashing[d], Line[{{0, 0}, {2, 1}}]}], {d, {Tiny, Small, Medium, Large}}]

破線の線分のオフセットを指定する：

Wolfram Language code: Table[Graphics[{Line[{{0, 0}, {2, 1}}], AbsoluteDashing[{10, 5}, o], Red, Opacity[.5], AbsoluteThickness[5], Line[{{0, 0}, {2, 1}}]}], {o, {-5, 0, 5}}]

破線の線分のキャップを指定する：

Wolfram Language code: Table[Graphics[{Line[{{0, 0}, {2, 1}}], AbsoluteDashing[{10, 10}, 0, CapForm[c]], Red, Opacity[.5], AbsoluteThickness[5], Line[{{0, 0}, {2, 1}}]}], {c, {"Round", "Butt", "Square"}}]

特性と関係  (3)

AbsoluteDashingは線分の長さを印刷用ポイント数を単位として定義する：

Wolfram Language code: Graphics[{Thickness[.02], AbsoluteDashing[{15}], Line[{{0, 0}, {1, 0}}], Text[Style["15 points", FontSize -> 15], {0.5, 0.1}]}]

AbsoluteDashingは画像サイズに依存しない：

Wolfram Language code: Table[Graphics[{AbsoluteDashing[10], Line[{{0, 0}, {2, 1}}]}, ImageSize -> s], {s, {50, 100, 150}}]

Dashingは線分の長さをグラフィックスの全体幅の比で定義する：

Wolfram Language code: Graphics[{Thick, Dashing[{0.05, 0.1}], Line[{{-1, 0}, {1, 0}}]}, Frame -> True]

Dashingは画像サイズに依存する：

Wolfram Language code: Table[Graphics[{Dashing[.05], Line[{{0, 0}, {2, 1}}]}, ImageSize -> s], {s, {50, 100, 150}}]

AbsoluteDashingはCapForm指示子を無効にする：

Wolfram Language code: Graphics[{AbsoluteDashing[{20, 15}], CapForm["Round"], AbsoluteThickness[10], Line[{{0, 0}, {1, 1}}]}]

Dashingの第3引数を指定してすべての破線のキャップ形式を設定する：

Wolfram Language code: Graphics[{AbsoluteDashing[{20, 15}, 0, "Round"], AbsoluteThickness[10], Line[{{0, 0}, {1, 1}}]}]

考えられる問題  (1)

線にキャップを付けると個々の破線の長さが増すので，間隔が狭い破線の場合は重なってしまうかもしれない：

Wolfram Language code: Table[Graphics[{AbsoluteDashing[{20, 8}, 0, cap], AbsoluteThickness[10], Line[{{1, 0}, {0, 1}}]}], {cap, {None, "Round"}}]

おもしろい例題  (1)

原点から出る破線の放射線のオフセットを変える：

Wolfram Language code: Animate[Graphics[{AbsoluteDashing[{20, 10}, a], Table[Line[{{0, 0}, {Cos[b], Sin[b]}}], {b, 0, 2 π, π / 20}]}], {a, 90, 0}]
Wolfram Research (1991), AbsoluteDashing, Wolfram言語関数， https://reference.wolfram.com/language/ref/AbsoluteDashing.html （2021年に更新）.

テキスト

Wolfram Research (1991), AbsoluteDashing, Wolfram言語関数， https://reference.wolfram.com/language/ref/AbsoluteDashing.html （2021年に更新）.

CMS

Wolfram Language. 1991. "AbsoluteDashing." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2021. https://reference.wolfram.com/language/ref/AbsoluteDashing.html.

APA

Wolfram Language. (1991). AbsoluteDashing. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/AbsoluteDashing.html

BibTeX

@misc{reference.wolfram_2026_absolutedashing, author="Wolfram Research", title="{AbsoluteDashing}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/AbsoluteDashing.html}", note=[Accessed: 18-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_absolutedashing, organization={Wolfram Research}, title={AbsoluteDashing}, year={2021}, url={https://reference.wolfram.com/language/ref/AbsoluteDashing.html}, note=[Accessed: 18-August-2026]}