WOLFRAM

Wolfram 语言与系统参考资料中心

AbsoluteDashing[{d1,d2,…}]

是一个图形指令，指定后面的线段将使用绝对长度为 d1、d2，… （反复循环）的虚线逐段画出.

AbsoluteDashing[d]

等价于 AbsoluteDashing[{d,d}].

AbsoluteDashing[{d1,d2,…},offset]

在每个短线前添加 offset.

AbsoluteDashing[{d1,d2,…},offset,capform]

将每个短线的 CapForm 设置为 capform.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
虚线指定  
属性和关系  
可能存在的问题  
巧妙范例  
参见
技术笔记
相关指南
历史
按以下格式引用：

AbsoluteDashing

AbsoluteDashing[{d1,d2,…}]

是一个图形指令，指定后面的线段将使用绝对长度为 d1、d2，… （反复循环）的虚线逐段画出.

AbsoluteDashing[d]

等价于 AbsoluteDashing[{d,d}].

AbsoluteDashing[{d1,d2,…},offset]

在每个短线前添加 offset.

AbsoluteDashing[{d1,d2,…},offset,capform]

将每个短线的 CapForm 设置为 capform.

更多信息

  • 短线和偏移量的长度以打印点为单位度量，放大前等于 英寸.
  • AbsoluteDashing[{}] 指定线段应是实线. »
  • AbsoluteDashing 可用于二维和三维图形以及 Style 指定.
  • d 可以使用以下符号形式：Tiny、Small、Medium 以及 Large. »
  • 如果短线的长度 di 的被指定为 0，则该短线被绘制为一个点，其直径为该线段的宽度.
  • 用打印点为单位指定 offset，可以为正，也可以为负. 如果没有指定 offset，则为 0.
  • capform 可接受 CapForm[form] 形式的任何正常的 form 值. 如果没有指定，将以 "Butt" 端点格式绘制所有短线.

范例

打开所有单元 关闭所有单元

基本范例  (2)

指定长度用打印点度量的逐段虚线：

Wolfram Language code: Table[Graphics[{AbsoluteDashing[{d, 15 - d}], Line[{{0, 0}, {2, 1}}]}], {d, {2, 5, 8, 12}}]
Wolfram Language code: Table[Graphics3D[{AbsoluteDashing[{d, 15 - d}], Line[{{0, 0, 0}, {2, 1, 1}}]}], {d, {2, 5, 8, 12}}]

用 Dashed、Dotted 和 DotDashed 指明预定义的绝对虚线：

Wolfram Language code: {Graphics[{Dashed, Line[{{0, 0}, {2, 1}}]}], Graphics[{Dotted, Line[{{0, 0}, {2, 1}}]}], Graphics[{DotDashed, Line[{{0, 0}, {2, 1}}]}]}

范围  (4)

虚线指定  (4)

非虚线：

Wolfram Language code: Graphics[{AbsoluteDashing[{}], Line[{{0, 0}, {2, 1}}]}]

AbsoluteDashing[d] 等价于 AbsoluteDashing[{d,d}]：

Wolfram Language code: Table[Graphics[{AbsoluteDashing[d], Line[{{0, 0}, {2, 1}}]}], {d, {2, 5, 8, 12}}]

预定义绝对虚线的符号值：

Wolfram Language code: Table[Graphics[{AbsoluteDashing[d], Line[{{0, 0}, {2, 1}}]}], {d, {Tiny, Small, Medium, Large}}]

指定短线的偏移量：

Wolfram Language code: Table[Graphics[{Line[{{0, 0}, {2, 1}}], AbsoluteDashing[{10, 5}, o], Red, Opacity[.5], AbsoluteThickness[5], Line[{{0, 0}, {2, 1}}]}], {o, {-5, 0, 5}}]

指定短线端点的格式：

Wolfram Language code: Table[Graphics[{Line[{{0, 0}, {2, 1}}], AbsoluteDashing[{10, 10}, 0, CapForm[c]], Red, Opacity[.5], AbsoluteThickness[5], Line[{{0, 0}, {2, 1}}]}], {c, {"Round", "Butt", "Square"}}]

属性和关系  (3)

AbsoluteDashing 定义以打印点为单位的线段长度：

Wolfram Language code: Graphics[{Thickness[.02], AbsoluteDashing[{15}], Line[{{0, 0}, {1, 0}}], Text[Style["15 points", FontSize -> 15], {0.5, 0.1}]}]

AbsoluteDashing 与图像尺寸无关：

Wolfram Language code: Table[Graphics[{AbsoluteDashing[10], Line[{{0, 0}, {2, 1}}]}, ImageSize -> s], {s, {50, 100, 150}}]

Dashing 以图形总宽度的分式定义线段长度：

Wolfram Language code: Graphics[{Thick, Dashing[{0.05, 0.1}], Line[{{-1, 0}, {1, 0}}]}, Frame -> True]

Dashing 取决于图像尺寸：

Wolfram Language code: Table[Graphics[{Dashing[.05], Line[{{0, 0}, {2, 1}}]}, ImageSize -> s], {s, {50, 100, 150}}]

AbsoluteDashing 将覆盖 CapForm 指令：

Wolfram Language code: Graphics[{AbsoluteDashing[{20, 15}], CapForm["Round"], AbsoluteThickness[10], Line[{{0, 0}, {1, 1}}]}]

指定 Dashing 的第三个参数来设置所有短线的端点格式：

Wolfram Language code: Graphics[{AbsoluteDashing[{20, 15}, 0, "Round"], AbsoluteThickness[10], Line[{{0, 0}, {1, 1}}]}]

可能存在的问题  (1)

短线端点处的不同格式会增加短线的长度，可能使得间隔较小的短线重叠在一起：

Wolfram Language code: Table[Graphics[{AbsoluteDashing[{20, 8}, 0, cap], AbsoluteThickness[10], Line[{{1, 0}, {0, 1}}]}], {cap, {None, "Round"}}]

巧妙范例  (1)

改变从原点发出的虚射线的偏移量：

Wolfram Language code: Animate[Graphics[{AbsoluteDashing[{20, 10}, a], Table[Line[{{0, 0}, {Cos[b], Sin[b]}}], {b, 0, 2 π, π / 20}]}], {a, 90, 0}]
Wolfram Research (1991)，AbsoluteDashing，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AbsoluteDashing.html （更新于 2021 年）.

文本

Wolfram Research (1991)，AbsoluteDashing，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AbsoluteDashing.html （更新于 2021 年）.

CMS

Wolfram 语言. 1991. "AbsoluteDashing." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2021. https://reference.wolfram.com/language/ref/AbsoluteDashing.html.

APA

Wolfram 语言. (1991). AbsoluteDashing. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/AbsoluteDashing.html 年

BibTeX

@misc{reference.wolfram_2026_absolutedashing, author="Wolfram Research", title="{AbsoluteDashing}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/AbsoluteDashing.html}", note=[Accessed: 18-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_absolutedashing, organization={Wolfram Research}, title={AbsoluteDashing}, year={2021}, url={https://reference.wolfram.com/language/ref/AbsoluteDashing.html}, note=[Accessed: 18-August-2026]}