WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Antisymmetric[{s1,…,sn}]

スロット si で反対称であるテンソルの対称性を表す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
考えられる問題  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

Antisymmetric

Antisymmetric[{s1,…,sn}]

スロット si で反対称であるテンソルの対称性を表す．

詳細

  • スロット si は異なる正の数でなければならない．リスト順は無関係である．
  • Antisymmetric[{}]およびAntisymmetric[{s}]はどちらも恒等対称に等しい．
  • Antisymmetric[All]はすべてのスロットで反対称であるテンソルの対称性を表す．
  • スロットの集合で配列が反対称のとき，それらのスロットはすべて同じ次元である．

例題

すべて開く すべて閉じる

例  (2)

この行列は反対称である：

Wolfram Language code: TensorSymmetry[{{0, 5, 6}, {-5, 0, 3}, {-6, -3, 0}}]

階数4の配列が3つのスロットで反対称であると宣言する：

Wolfram Language code: $Assumptions = A∈Arrays[{4, 4, 4, 4}, Reals, Antisymmetric[{1, 2, 4}]];

であるなら，それらのスロットを含む任意の転置は，符号を除いて，もとのテンソルに等しくなる：

Wolfram Language code: TensorTranspose[A, Cycles[{{2, 4}}]]//TensorReduce

スコープ  (3)

記号配列のすべてのスロットでの反対称性：

Wolfram Language code: $Assumptions = A∈Arrays[{3, 3, 3, 3}, Reals, Antisymmetric[{1, 2, 3, 4}]];
Wolfram Language code: TensorTranspose[A, {4, 1, 2, 3}]//TensorReduce

これは，以下のように指定することもできる：

Wolfram Language code: $Assumptions = A∈Arrays[{3, 3, 3, 3}, Reals, Antisymmetric[All]];
Wolfram Language code: TensorTranspose[A, {4, 1, 2, 3}]//TensorReduce

記号配列の指定されたスロットでの反対称性：

Wolfram Language code: $Assumptions = A∈Arrays[{3, 3, 3, 3}, Reals, Antisymmetric[{1, 2, 4}]];
Wolfram Language code: TensorTranspose[A, {4, 1, 2, 3}]//TensorReduce

Antisymmetric[{}]およびAntisymmetric[{s}]は対称性が不在の表現である：

Wolfram Language code: SymmetrizedArray[pos_ :> RandomInteger[100], {3, 3, 3}, Antisymmetric[{2}]]

そのような場合は生成元の空リストに正準化される：

Wolfram Language code: TensorSymmetry[%]

アプリケーション  (3)

対称化された配列の対称性を指定する：

Wolfram Language code: SymmetrizedArray[{{1, 2, 3} -> a, {2, 3, 4} -> b}, {4, 4, 4}, Antisymmetric[{1, 2, 3}]]
Wolfram Language code: Normal[%]
Wolfram Language code: TensorSymmetry[%]

対称配列の対称性を指定する：

Wolfram Language code: $Assumptions = A∈Arrays[{4, 4, 4}, Reals, Antisymmetric[{1, 2, 3}]];
Wolfram Language code: TensorSymmetry[A]

配列のいくつかのスロットを対称化する：

Wolfram Language code: A = Array[a, {2, 2, 2}]
Wolfram Language code: Symmetrize[A, Antisymmetric[{1, 3}]]//Normal

特性と関係  (3)

反対称行列を検出する：

Wolfram Language code: SeedRandom[0]; RandomInteger[100, {5, 5}]
Wolfram Language code: A = % - Transpose[%]
Wolfram Language code: Transpose[A] === -A
Wolfram Language code: TensorSymmetry[A]

対称テンソルは位相の明示的な生成元を与えることで指定することもできる：

Wolfram Language code: sym = {{{2, 3, 4, 5, 1}, 1}, {{2, 1, 3, 4, 5}, -1}}; $Assumptions = A∈Arrays[{d, d, d, d, d}, Reals, sym];

Wolfram言語は自動的に等価性を検出する：

Wolfram Language code: TensorSymmetry[A]

反対称性スロットの重なり合う集合はすべてのスロットについての完全な反対称性を与える：

Wolfram Language code: sym = {Antisymmetric[{1, 2, 3}], Antisymmetric[{3, 4, 5, 6}]}; A = SymmetrizedArray[pos_ :> RandomReal[], {6, 6, 6, 6, 6, 6}, sym]
Wolfram Language code: TensorSymmetry[A]

重なり合わない集合は完全な反対称性は与えない．結果の対称性は生成元を使って記述される：

Wolfram Language code: sym = {Antisymmetric[{1, 2}], Antisymmetric[{3, 4, 5, 6}]}; $Assumptions = B∈Arrays[{d, d, d, d, d, d}, Reals, sym];
Wolfram Language code: TensorSymmetry[B]

考えられる問題  (1)

次元はすべての対称スロットで一致しなければならない：

Wolfram Language code: Symmetrize[Array[a, {3, 2}], Antisymmetric[{1, 2}]]
Wolfram Research (2012), Antisymmetric, Wolfram言語関数， https://reference.wolfram.com/language/ref/Antisymmetric.html.

テキスト

Wolfram Research (2012), Antisymmetric, Wolfram言語関数， https://reference.wolfram.com/language/ref/Antisymmetric.html.

CMS

Wolfram Language. 2012. "Antisymmetric." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/Antisymmetric.html.

APA

Wolfram Language. (2012). Antisymmetric. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Antisymmetric.html

BibTeX

@misc{reference.wolfram_2026_antisymmetric, author="Wolfram Research", title="{Antisymmetric}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/Antisymmetric.html}", note=[Accessed: 09-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_antisymmetric, organization={Wolfram Research}, title={Antisymmetric}, year={2012}, url={https://reference.wolfram.com/language/ref/Antisymmetric.html}, note=[Accessed: 09-August-2026]}