WOLFRAM

Wolfram 语言与系统参考资料中心

Antisymmetric[{s1,…,sn}]

表示位置（slot）si 处反对称的张量的对称性.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
属性和关系  
可能存在的问题  
参见
技术笔记
相关指南
历史
按以下格式引用：

Antisymmetric

Antisymmetric[{s1,…,sn}]

表示位置（slot）si 处反对称的张量的对称性.

更多信息

  • 位置 si 必须是不同的正数. 列表的顺序是无关的.
  • Antisymmetric[{}] 和 Antisymmetric[{s}] 都等于恒等对称性.
  • Antisymmetric[All] 表示在所有位置中反对称的张量的对称性.
  • 如果一个数组在位置集合中是反对称的，那么所有这些位置有相同的维度.

范例

打开所有单元 关闭所有单元

基本范例  (2)

该矩阵是反对称的：

Wolfram Language code: TensorSymmetry[{{0, 5, 6}, {-5, 0, 3}, {-6, -3, 0}}]

声明一个阶数为4的数组在三个位置中是反对称的：

Wolfram Language code: $Assumptions = A∈Arrays[{4, 4, 4, 4}, Reals, Antisymmetric[{1, 2, 4}]];

那么涉及这些位置的任意换位等价于原始张量，可能最多有符号变化：

Wolfram Language code: TensorTranspose[A, Cycles[{{2, 4}}]]//TensorReduce

范围  (3)

符号式数组中所有位置里的反对称性：

Wolfram Language code: $Assumptions = A∈Arrays[{3, 3, 3, 3}, Reals, Antisymmetric[{1, 2, 3, 4}]];
Wolfram Language code: TensorTranspose[A, {4, 1, 2, 3}]//TensorReduce

它也可以按如下方式指定：

Wolfram Language code: $Assumptions = A∈Arrays[{3, 3, 3, 3}, Reals, Antisymmetric[All]];
Wolfram Language code: TensorTranspose[A, {4, 1, 2, 3}]//TensorReduce

符号式数组的给定位置中的反对称性：

Wolfram Language code: $Assumptions = A∈Arrays[{3, 3, 3, 3}, Reals, Antisymmetric[{1, 2, 4}]];
Wolfram Language code: TensorTranspose[A, {4, 1, 2, 3}]//TensorReduce

Antisymmetric[{}] 和 Antisymmetric[{s}] 是没有对称性情况下的表示法：

Wolfram Language code: SymmetrizedArray[pos_ :> RandomInteger[100], {3, 3, 3}, Antisymmetric[{2}]]

这样的情况被规范化为生成元组成的空列表：

Wolfram Language code: TensorSymmetry[%]

应用  (3)

指定对称化数组的对称性：

Wolfram Language code: SymmetrizedArray[{{1, 2, 3} -> a, {2, 3, 4} -> b}, {4, 4, 4}, Antisymmetric[{1, 2, 3}]]
Wolfram Language code: Normal[%]
Wolfram Language code: TensorSymmetry[%]

指定符号式数组的对称性：

Wolfram Language code: $Assumptions = A∈Arrays[{4, 4, 4}, Reals, Antisymmetric[{1, 2, 3}]];
Wolfram Language code: TensorSymmetry[A]

将数组的某些位置进行对称化处理：

Wolfram Language code: A = Array[a, {2, 2, 2}]
Wolfram Language code: Symmetrize[A, Antisymmetric[{1, 3}]]//Normal

属性和关系  (3)

检测反对称矩阵：

Wolfram Language code: SeedRandom[0]; RandomInteger[100, {5, 5}]
Wolfram Language code: A = % - Transpose[%]
Wolfram Language code: Transpose[A] === -A
Wolfram Language code: TensorSymmetry[A]

反对称张量也可以通过提供具有相位 的显式生成元指定：

Wolfram Language code: sym = {{{2, 3, 4, 5, 1}, 1}, {{2, 1, 3, 4, 5}, -1}}; $Assumptions = A∈Arrays[{d, d, d, d, d}, Reals, sym];

Wolfram 语言自动检测相等性：

Wolfram Language code: TensorSymmetry[A]

反对称位置的重叠集合给出所有这些位置上的完全反对称性：

Wolfram Language code: sym = {Antisymmetric[{1, 2, 3}], Antisymmetric[{3, 4, 5, 6}]}; A = SymmetrizedArray[pos_ :> RandomReal[], {6, 6, 6, 6, 6, 6}, sym]
Wolfram Language code: TensorSymmetry[A]

非重叠集合没有给出完全的反对称性. 所得对称性使用生成元描述：

Wolfram Language code: sym = {Antisymmetric[{1, 2}], Antisymmetric[{3, 4, 5, 6}]}; $Assumptions = B∈Arrays[{d, d, d, d, d, d}, Reals, sym];
Wolfram Language code: TensorSymmetry[B]

可能存在的问题  (1)

维度必须与所有对称位置中的保持一致：

Wolfram Language code: Symmetrize[Array[a, {3, 2}], Antisymmetric[{1, 2}]]
Wolfram Research (2012)，Antisymmetric，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Antisymmetric.html.

文本

Wolfram Research (2012)，Antisymmetric，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Antisymmetric.html.

CMS

Wolfram 语言. 2012. "Antisymmetric." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/Antisymmetric.html.

APA

Wolfram 语言. (2012). Antisymmetric. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Antisymmetric.html 年

BibTeX

@misc{reference.wolfram_2026_antisymmetric, author="Wolfram Research", title="{Antisymmetric}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/Antisymmetric.html}", note=[Accessed: 07-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_antisymmetric, organization={Wolfram Research}, title={Antisymmetric}, year={2012}, url={https://reference.wolfram.com/language/ref/Antisymmetric.html}, note=[Accessed: 07-September-2026]}