WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

BuildCompiledComponent[comp]

コンパイルされたコンポーネント comp をビルドする．

BuildCompiledComponent[comp,dest]

コンパイルされたコンポーネント comp をビルドし，結果を dest に置く．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
CompilerOptions  
CompilerEnvironment  
CreateIntermediateDirectories  
ProgressReporting  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

BuildCompiledComponent

BuildCompiledComponent[comp]

コンパイルされたコンポーネント comp をビルドする．

BuildCompiledComponent[comp,dest]

コンパイルされたコンポーネント comp をビルドし，結果を dest に置く．

詳細とオプション

  • コンパイルされたコンポーネントを使ってコンパイラ宣言の名前付きグループを表す．
  • コンパイルされたコンポーネントを使ってコンパイラからビルドされた共有ライブラリを表す．
  • コンパイルされたコンポーネントはパクレットに埋め込める．
  • comp はCompiledComponentオブジェクトとしてあるいはコンパイルされたコンポーネントの名前を持つ文字列として与えることができる．
  • コンパイルされたコンポーネントはDeclareCompiledComponentによって作成される．
  • 通常，BuildCompiledComponentによるコンポーネントのビルドには，ライブラリ関数のコンパイル版とターゲットコンポーネントからのインストールされた関数を含む共有ライブラリの作成が含まれる．
  • BuildCompiledComponentでビルドしたライブラリはLoadCompiledComponentでロードできる．
  • BuildCompiledComponentの行き先が設定されていなければ，ライブラリは"$UserBaseDirectory/SystemFiles/LibraryResources/$SystemID"に格納される．
  • BuildCompiledComponentの行き先は文字列としてあるいはFileオブジェクトを使って与えられたファイルパスでよい．
  • BuildCompiledComponentの行き先はPacletObjectでよい．これはライブラリをパクレット内の"LibraryResources/$SystemID"に置く．
  • 次は使用可能なオプションである．
  • CompilerEnvironment Automaticデフォルトでコンポーネント内に宣言を含むコンパイラ環境
    CompilerOptions Automaticコンパイルを制御するオプション
    CreateIntermediateDirectories Automatic宛先パスに中間ディレクトリを作成するかどうか
    ProgressReporting Automaticコンパイル中の進捗状況の報告方法

例題

すべて開く すべて閉じる

例  (1)

コンパイルされたコンポーネントを作成する：

Wolfram Language code: DeclareCompiledComponent["demoComp", "LibraryFunctions" -> <| "square" -> Function[{Typed[arg, "Real64"]}, arg ^ 2] |>];

コンポーネントをビルドする：

Wolfram Language code: BuildCompiledComponent["demoComp"]

コンポーネントをロードする：

Wolfram Language code: res = LoadCompiledComponent["demoComp"]

ビルドされたコンポーネントに含まれる関数を呼び出す：

Wolfram Language code: res["LibraryFunctions"]["square"][10.5]

スコープ  (1)

コンポーネント内の宣言のリストを宣言する：

Wolfram Language code: DeclareCompiledComponent["fullComponent", { FunctionDeclaration[return12, Typed[{} -> "MachineInteger"]@Function[{}, 12]], FunctionDeclaration[addtwo, Typed[{"MachineInteger"} -> "MachineInteger"]@Function[x, x + 2]] }];

ライブラリ関数を宣言する：

Wolfram Language code: DeclareCompiledComponent["fullComponent", "LibraryFunctions" -> <| "libFunc" -> Function[Typed[arg, "Real64"], Sqrt[arg]] |>];

インストールされた関数を宣言する：

Wolfram Language code: DeclareCompiledComponent["fullComponent", "InstalledFunctions" -> addtwo];
Wolfram Language code: BuildCompiledComponent["fullComponent"]

インストールされた関数を使って自動的にビルドをロードする：

Wolfram Language code: addtwo[3]

コンポーネントを明示的にロードしてビルドされたライブラリ関数にアクセスする：

Wolfram Language code: LoadCompiledComponent["fullComponent"]

オプション  (4)

CompilerOptions  (1)

コンポーネントを宣言する：

Wolfram Language code: DeclareCompiledComponent["optComponent", "LibraryFunctions" -> <|"square" -> Function[{Typed[x, "Real64"]}, x * x]|>]

追加的なコンパイラオプションでコンポーネントをビルドする：

Wolfram Language code: BuildCompiledComponent["optComponent", CompilerOptions -> {"TraceFunction" -> Echo}]

CompilerEnvironment  (1)

新しいコンパイラ環境を作成し，それに定義を加える：

Wolfram Language code: compEnv = CreateCompilerEnvironment[]; CompilerEnvironmentAppendTo[ compEnv, FunctionDeclaration[add42, Typed[{"MachineInteger"} -> "MachineInteger"]@Function[x, x + 42]] ]

このコンパイラ環境を参照する関数を，コンパイル済みコンポーネント内で宣言する：

Wolfram Language code: DeclareCompiledComponent["environmentComponent", "LibraryFunctions" -> <| "add42" -> Function[{Typed[x, "MachineInteger"]}, add42[x]] |>]

コンポーネントをビルドする：

Wolfram Language code: BuildCompiledComponent["environmentComponent", CompilerEnvironment -> compEnv]

コンポーネントをロードしてライブラリ関数を実行する：

Wolfram Language code: loadedComp = LoadCompiledComponent["environmentComponent"]; loadedComp["LibraryFunctions", "add42"][10]

CreateIntermediateDirectories  (1)

単純なコンパイルされたコンポーネントを宣言する：

Wolfram Language code: DeclareCompiledComponent["demoCreateDirs", "LibraryFunctions" -> <|"cube" -> Function[{Typed[x, "Real64"]}, x ^ 3]|> ]

存在しないネストしたビルドディレクトリを定義する：

Wolfram Language code: buildDir = FileNameJoin[{$TemporaryDirectory, "compiled", "components", "nested"}]

中間ディレクトリを作成せずにビルドすると失敗する：

Wolfram Language code: BuildCompiledComponent["demoCreateDirs", buildDir, CreateIntermediateDirectories -> False]

欠落した親ディレクトリの自動作成を許可する：

Wolfram Language code: BuildCompiledComponent["demoCreateDirs", buildDir, CreateIntermediateDirectories -> True]

ProgressReporting  (1)

コンパイル中の進捗状況は報告される：

Wolfram Language code: DeclareCompiledComponent["progressComponent", "LibraryFunctions" -> <| "libFunc" -> Function[{Typed[s, "String"]}, ToCharacterCode[s]] |>]; BuildCompiledComponent["progressComponent"]
Wolfram Language code: [image]

ProgressReportingをFalseに設定すると報告されなくなる．

Wolfram Language code: BuildCompiledComponent["progressComponent", ProgressReporting -> False]

ProgressReportingのデフォルト値はAutomaticであるが，これは大域設定$ProgressReportingが使われることを意味する．これをFalseに設定すると，進捗状況は報告されなくなる．

Wolfram Research (2022), BuildCompiledComponent, Wolfram言語関数， https://reference.wolfram.com/language/ref/BuildCompiledComponent.html.

テキスト

Wolfram Research (2022), BuildCompiledComponent, Wolfram言語関数， https://reference.wolfram.com/language/ref/BuildCompiledComponent.html.

CMS

Wolfram Language. 2022. "BuildCompiledComponent." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/BuildCompiledComponent.html.

APA

Wolfram Language. (2022). BuildCompiledComponent. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/BuildCompiledComponent.html

BibTeX

@misc{reference.wolfram_2026_buildcompiledcomponent, author="Wolfram Research", title="{BuildCompiledComponent}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/BuildCompiledComponent.html}", note=[Accessed: 18-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_buildcompiledcomponent, organization={Wolfram Research}, title={BuildCompiledComponent}, year={2022}, url={https://reference.wolfram.com/language/ref/BuildCompiledComponent.html}, note=[Accessed: 18-August-2026]}