WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ControllabilityGramian[ssm]

状態空間モデル ssm の可制御性グラミアンを与える．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
考えられる問題  
関連項目
関連するガイド
履歴
引用書式

ControllabilityGramian

ControllabilityGramian[ssm]

状態空間モデル ssm の可制御性グラミアンを与える．

詳細とオプション

  • 状態空間モデル ssm はStateSpaceModel[{a,b,…}]で与えられる．ただし，a と b は連続時間系あるいは離散時間系の状態行列および入力行列を表す．
  • 連続時間系
    離散時間系
  • 可制御性グラミアン
  • 連続時間系
    離散時間系
  • 漸近的に安定した系では，グラミアン はリャプノフ(Lyapunov)方程式の解として計算できる．
  • 連続時間系
    離散時間系
  • ディスクリプタ行列があるStateSpaceModelについて，ControllabilityGramianは行列のペア{wcs,wcf}を返す．ただし，wcsは遅い部分系に関連しており，wcfは速い部分系に関連している．
  • 可制御性グラミアンは，ある λ についてDet[λ e-a]≠0であるディスクリプタ系についてのみ存在する．

例題

すべて開く すべて閉じる

例  (1)

状態空間モデルの可制御性グラミアン：

Wolfram Language code: ControllabilityGramian[StateSpaceModel[{{{-1, -1}, {1, -1}}, {{-1}, {-2}}, {{0, 2}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]// MatrixForm

スコープ  (4)

連続時間系の可制御性グラミアン：

Wolfram Language code: ControllabilityGramian[StateSpaceModel[{{{0, -1, 1}, {1, -1, -1}, {-2, 0, -1}}, {{-2}, {-2}, {-2}}, {{1, 1, -2}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]

離散時間系の可制御性グラミアン：

Wolfram Language code: ControllabilityGramian[StateSpaceModel[{{{0.9512, 0}, {0, 0.9048}}, {{4.88, 4.88}, {-0.019, 0.0095}}, {{0.01, 0}, {0, 1}}, {{0, 0}, {0, 0}}}, SamplingPeriod -> 2, SystemsModelLabels -> None]]

記号系の可制御性グラミアン：

Wolfram Language code: ControllabilityGramian[StateSpaceModel[{{{-1, a}, {-a, -1}}, {{1}, {a}}}, SamplingPeriod -> None, SystemsModelLabels -> None]];
Wolfram Language code: Simplify[%, a∈Reals]

デスクリプタ系の可制御性グラミアン：

Wolfram Language code: ControllabilityGramian[StateSpaceModel[{{{-3, 0, 0}, {0, 1, 0}, {0, 0, 1}}, {{1}, {0}, {2}}, {{1, 1, 1}}, {{0}}, {{1, 0, 0}, {0, 0, 1}, {0, 0, 0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]

アプリケーション  (1)

系が可制御であるかどうか確認する：

Wolfram Language code: ssm = StateSpaceModel[{{{-1, -1}, {1, -3}}, {{1}, {2}}, {{1, 1}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None];
Wolfram Language code: MatrixRank[ControllabilityGramian[ssm]] == SystemsModelOrder[ssm]

特性と関係  (7)

可制御性グラミアンは状態行列の次元を持つ：

Wolfram Language code: ssm = StateSpaceModel[{{{0, 1}, {-10, -11}}, {{0}, {1}}, {{5, 1}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None];
Wolfram Language code: Dimensions /@ {ControllabilityGramian[ssm], First[Normal[ssm]]}

可制御性グラミアンがフルランクの場合，その系は可制御である：

Wolfram Language code: ssm = StateSpaceModel[{{{-3, 0}, {1, -5}}, {{-2}, {0}}}, SamplingPeriod -> None, SystemsModelLabels -> None];
Wolfram Language code: {ControllableModelQ[ssm], MatrixRank[ControllabilityGramian[ssm]] == 2}
Wolfram Language code: ssm = StateSpaceModel[{{{-5/2, 1/2}, {1/2, -5/2}}, {{1}, {-1}}}, SamplingPeriod -> None, SystemsModelLabels -> None];
Wolfram Language code: {ControllableModelQ[ssm], MatrixRank[ControllabilityGramian[ssm]] == 2}

可制御で漸近的に安定した系の可制御性グラミアンは対称かつ正定値である：

Wolfram Language code: ControllabilityGramian[StateSpaceModel[{{{-3, 0}, {0, -5}}, {{-1}, {-1}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]
Wolfram Language code: SymmetricMatrixQ[%] && PositiveDefiniteMatrixQ[%]

漸近的に安定した系の可制御性グラミアンは対応するリャプノフ方程式を満足する：

Wolfram Language code: ssm = StateSpaceModel[{{{-0.5, 0}, {0, -1}}, {{0.5}, {1}}}, SamplingPeriod -> None, SystemsModelLabels -> None];
Wolfram Language code: {Subscript[a, c], Subscript[b, c]} = Normal[ssm][[1 ;; 2]];
Wolfram Language code: Chop[ControllabilityGramian[ssm] - LyapunovSolve[Subscript[a, c], -Subscript[b, c].Subscript[b, c]]]
Wolfram Language code: Subscript[ssm, 1] = StateSpaceModel[{{{0.85, -0.56, 0.22}, {0.2, 0.11, 1}, {-0.25, 0.5, 0}}, {{1}, {0}, {0}}}, SamplingPeriod -> 0.1, SystemsModelLabels -> None];
Wolfram Language code: {Subscript[a, d], Subscript[b, d]} = Normal[Subscript[ssm, 1]][[1 ;; 2]];
Wolfram Language code: Chop[ControllabilityGramian[Subscript[ssm, 1]] - DiscreteLyapunovSolve[Subscript[a, d], -Subscript[b, d].Subscript[b, d]]]

可制御性グラミアンは双対系の可観測性グラミアンである：

Wolfram Language code: ssm = StateSpaceModel[{{{-1, -1}, {1, -1}}, {{1}, {0}}, {{1, 0}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None];
Wolfram Language code: ControllabilityGramian[ssm] == ObservabilityGramian[DualSystemsModel[ssm]]

デスクリプタ状態空間モデルは，2つのグラミアンを与える：

Wolfram Language code: Subscript[ssm, 1] = StateSpaceModel[{{{1, 0, 0}, {0, -3, 0}, {0, 0, -2}}, {{0}, {1}, {0}}, {{1, 3, -2}}, {{0}}, {{0, 0, 0}, {0, 3, 0}, {1, 0, 0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]; gramians = ControllabilityGramian[Subscript[ssm, 1]];

系は，総和が正定値であるとき，かつそのときに限り，完全に可制御である：

Wolfram Language code: PositiveDefiniteMatrixQ[Plus@@gramians]
Wolfram Language code: ControllableModelQ[Subscript[ssm, 1]]
Wolfram Language code: Subscript[ssm, 2] = StateSpaceModel[{{{1, 0, 0}, {0, -3, 0}, {0, 0, -2}}, {{1}, {1}, {0}}, {{1, 3, -2}}, {{0}}, {{0, 0, 0}, {0, 3, 0}, {1, 0, 0}}}, SamplingPeriod -> None, SystemsModelLabels -> None];
Wolfram Language code: PositiveDefiniteMatrixQ[Plus@@ControllabilityGramian[Subscript[ssm, 2]]]
Wolfram Language code: ControllableModelQ[Subscript[ssm, 2]]

速い部分系グラミアンと遅い部分系グラミアンは，クロネッカー(Kronecker)分解から計算される：

Wolfram Language code: ssm = StateSpaceModel[{{{-1, 0, 0}, {0, -1, 1}, {0, 0, 1}}, {{1}, {0}, {5}}, {{1, 1, 1}}, {{0}}, {{1, 0, 0}, {0, 0, 1}, {0, 0, 0}}}, SamplingPeriod -> None, SystemsModelLabels -> None];
Wolfram Language code: {{p, q}, kssm} = KroneckerModelDecomposition[ssm]

分離状態を分ける：

Wolfram Language code: {slowssm, fastssm} = {SystemsModelExtract[kssm, All, All, 1], SystemsModelExtract[kssm, All, All, {2, 3}]}

遅い部分系は，遅い状態のグラミアンと零行列を与える：

Wolfram Language code: {slowgramian, zeromat} = ControllabilityGramian[slowssm]

速い部分系は，速い状態のグラミアンと零行列を与える：

Wolfram Language code: {zeromat, fastgramian} = ControllabilityGramian[fastssm]

クロネッカー変換を逆にすると，もとの系のグラミアンが得られる：

Wolfram Language code: Inverse[p].PadRight[slowgramian, {3, 3}].Inverse[p]//MatrixForm
Wolfram Language code: Inverse[p].PadLeft[fastgramian, {3, 3}].Inverse[p]//MatrixForm

以下は，直接ControllabilityGramianを使った場合と同じ結果を返す：

Wolfram Language code: MatrixForm /@ ControllabilityGramian[ssm]

考えられる問題  (1)

可制御性グラミアンは漸近的に安定していない系については定義されない：

Wolfram Language code: ControllabilityGramian[StateSpaceModel[{{{0, 0, 0}, {0, -1, 0}, {0, 0, -2}}, {{1}, {-1}, {1}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]
Wolfram Research (2010), ControllabilityGramian, Wolfram言語関数， https://reference.wolfram.com/language/ref/ControllabilityGramian.html （2012年に更新）.

テキスト

Wolfram Research (2010), ControllabilityGramian, Wolfram言語関数， https://reference.wolfram.com/language/ref/ControllabilityGramian.html （2012年に更新）.

CMS

Wolfram Language. 2010. "ControllabilityGramian." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2012. https://reference.wolfram.com/language/ref/ControllabilityGramian.html.

APA

Wolfram Language. (2010). ControllabilityGramian. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ControllabilityGramian.html

BibTeX

@misc{reference.wolfram_2026_controllabilitygramian, author="Wolfram Research", title="{ControllabilityGramian}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/ControllabilityGramian.html}", note=[Accessed: 06-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_controllabilitygramian, organization={Wolfram Research}, title={ControllabilityGramian}, year={2012}, url={https://reference.wolfram.com/language/ref/ControllabilityGramian.html}, note=[Accessed: 06-September-2026]}