WOLFRAM

Wolfram 语言与系统参考资料中心

ControllabilityGramian[ssm]

给出状态空间模型 ssm 的可控性格拉姆矩阵.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
属性和关系  
可能存在的问题  
参见
相关指南
历史
按以下格式引用：

ControllabilityGramian

ControllabilityGramian[ssm]

给出状态空间模型 ssm 的可控性格拉姆矩阵.

更多信息和选项

  • 状态空间模型 ssm 可以以 StateSpaceModel[{a,b,…}] 形式给出，其中 a 和 b 表示连续或离散时间系统的状态和输入矩阵：
  • 连续时间系统
    离散时间系统
  • 可控性格拉姆矩阵：
  • 连续时间系统
    离散时间系统
  • 对于渐近稳定系统，格拉姆 可以计算为李雅普诺夫（Lyapunov）方程的解：
  • 连续时间系统
    离散时间系统
  • 对于具有描述符矩阵的 StateSpaceModel，ControllabilityGramian 返回一个矩阵对 {wcs,wcf}，其中 wcs 与慢速子系统相关联，而 wcf 与快速子系统相关联.
  • 只有当描述符系统对于某个 λ 有 Det[λ e-a]≠0 成立时，可控性格拉姆矩阵存在.

范例

打开所有单元 关闭所有单元

基本范例  (1)

状态空间模型的可控性格拉姆矩阵：

Wolfram Language code: ControllabilityGramian[StateSpaceModel[{{{-1, -1}, {1, -1}}, {{-1}, {-2}}, {{0, 2}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]// MatrixForm

范围  (4)

连续时间系统的可控性格拉姆矩阵：

Wolfram Language code: ControllabilityGramian[StateSpaceModel[{{{0, -1, 1}, {1, -1, -1}, {-2, 0, -1}}, {{-2}, {-2}, {-2}}, {{1, 1, -2}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]

离散时间系统的可控性格拉姆矩阵：

Wolfram Language code: ControllabilityGramian[StateSpaceModel[{{{0.9512, 0}, {0, 0.9048}}, {{4.88, 4.88}, {-0.019, 0.0095}}, {{0.01, 0}, {0, 1}}, {{0, 0}, {0, 0}}}, SamplingPeriod -> 2, SystemsModelLabels -> None]]

符号系统的可控性格拉姆矩阵：

Wolfram Language code: ControllabilityGramian[StateSpaceModel[{{{-1, a}, {-a, -1}}, {{1}, {a}}}, SamplingPeriod -> None, SystemsModelLabels -> None]];
Wolfram Language code: Simplify[%, a∈Reals]

描述符系统的可控性格拉姆矩阵:

Wolfram Language code: ControllabilityGramian[StateSpaceModel[{{{-3, 0, 0}, {0, 1, 0}, {0, 0, 1}}, {{1}, {0}, {2}}, {{1, 1, 1}}, {{0}}, {{1, 0, 0}, {0, 0, 1}, {0, 0, 0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]

应用  (1)

验证系统是否可控：

Wolfram Language code: ssm = StateSpaceModel[{{{-1, -1}, {1, -3}}, {{1}, {2}}, {{1, 1}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None];
Wolfram Language code: MatrixRank[ControllabilityGramian[ssm]] == SystemsModelOrder[ssm]

属性和关系  (7)

可控性格拉姆矩阵具有与状态矩阵相同的维数：

Wolfram Language code: ssm = StateSpaceModel[{{{0, 1}, {-10, -11}}, {{0}, {1}}, {{5, 1}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None];
Wolfram Language code: Dimensions /@ {ControllabilityGramian[ssm], First[Normal[ssm]]}

如果可控性格拉姆矩阵是满秩，则该系统是可控的：

Wolfram Language code: ssm = StateSpaceModel[{{{-3, 0}, {1, -5}}, {{-2}, {0}}}, SamplingPeriod -> None, SystemsModelLabels -> None];
Wolfram Language code: {ControllableModelQ[ssm], MatrixRank[ControllabilityGramian[ssm]] == 2}
Wolfram Language code: ssm = StateSpaceModel[{{{-5/2, 1/2}, {1/2, -5/2}}, {{1}, {-1}}}, SamplingPeriod -> None, SystemsModelLabels -> None];
Wolfram Language code: {ControllableModelQ[ssm], MatrixRank[ControllabilityGramian[ssm]] == 2}

一个可控的和渐近稳定系统的可控性格拉姆矩阵是对称的和正定的：

Wolfram Language code: ControllabilityGramian[StateSpaceModel[{{{-3, 0}, {0, -5}}, {{-1}, {-1}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]
Wolfram Language code: SymmetricMatrixQ[%] && PositiveDefiniteMatrixQ[%]

渐近稳定系统的可控性格拉姆矩阵满足相应的李雅普诺夫（Lyapunov）方程：

Wolfram Language code: ssm = StateSpaceModel[{{{-0.5, 0}, {0, -1}}, {{0.5}, {1}}}, SamplingPeriod -> None, SystemsModelLabels -> None];
Wolfram Language code: {Subscript[a, c], Subscript[b, c]} = Normal[ssm][[1 ;; 2]];
Wolfram Language code: Chop[ControllabilityGramian[ssm] - LyapunovSolve[Subscript[a, c], -Subscript[b, c].Subscript[b, c]]]
Wolfram Language code: Subscript[ssm, 1] = StateSpaceModel[{{{0.85, -0.56, 0.22}, {0.2, 0.11, 1}, {-0.25, 0.5, 0}}, {{1}, {0}, {0}}}, SamplingPeriod -> 0.1, SystemsModelLabels -> None];
Wolfram Language code: {Subscript[a, d], Subscript[b, d]} = Normal[Subscript[ssm, 1]][[1 ;; 2]];
Wolfram Language code: Chop[ControllabilityGramian[Subscript[ssm, 1]] - DiscreteLyapunovSolve[Subscript[a, d], -Subscript[b, d].Subscript[b, d]]]

可控性格拉姆矩阵是对偶系统的可观测性格拉姆矩阵：

Wolfram Language code: ssm = StateSpaceModel[{{{-1, -1}, {1, -1}}, {{1}, {0}}, {{1, 0}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None];
Wolfram Language code: ControllabilityGramian[ssm] == ObservabilityGramian[DualSystemsModel[ssm]]

描述符状态空间模型给出两个格拉姆矩阵：

Wolfram Language code: ssm = StateSpaceModel[{{{-1, -1}, {1, -1}}, {{1}, {0}}, {{1, 0}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None];

当且仅当总和是正定时，该系统是完全可控的：

Wolfram Language code: PositiveDefiniteMatrixQ[Plus@@gramians]
Wolfram Language code: ControllableModelQ[Subscript[ssm, 1]]
Wolfram Language code: Subscript[ssm, 2] = StateSpaceModel[{{{1, 0, 0}, {0, -3, 0}, {0, 0, -2}}, {{1}, {1}, {0}}, {{1, 3, -2}}, {{0}}, {{0, 0, 0}, {0, 3, 0}, {1, 0, 0}}}, SamplingPeriod -> None, SystemsModelLabels -> None];
Wolfram Language code: PositiveDefiniteMatrixQ[Plus@@ControllabilityGramian[Subscript[ssm, 2]]]
Wolfram Language code: ControllableModelQ[Subscript[ssm, 2]]

快速与慢速子系统的格拉姆矩阵由克罗内克（Kronecker）分解计算得到：

Wolfram Language code: ssm = StateSpaceModel[{{{-1, 0, 0}, {0, -1, 1}, {0, 0, 1}}, {{1}, {0}, {5}}, {{1, 1, 1}}, {{0}}, {{1, 0, 0}, {0, 0, 1}, {0, 0, 0}}}, SamplingPeriod -> None, SystemsModelLabels -> None];
Wolfram Language code: {{p, q}, kssm} = KroneckerModelDecomposition[ssm]
Wolfram Language code: ssm = StateSpaceModel[{{{-1, 0, 0}, {0, -1, 1}, {0, 0, 1}}, {{1}, {0}, {5}}, {{1, 1, 1}}, {{0}}, {{1, 0, 0}, {0, 0, 1}, {0, 0, 0}}}, SamplingPeriod -> None, SystemsModelLabels -> None];

对解耦状态进行拆分：

Wolfram Language code: {slowssm, fastssm} = {SystemsModelExtract[kssm, All, All, 1], SystemsModelExtract[kssm, All, All, {2, 3}]}

慢速子系统生成慢状态和零矩阵的格拉姆矩阵：

Wolfram Language code: {slowgramian, zeromat} = ControllabilityGramian[slowssm]

快速子系统生成快状态和零矩阵的格拉姆矩阵：

Wolfram Language code: {zeromat, fastgramian} = ControllabilityGramian[fastssm]

对克罗内克变换求逆，得到原系统的格拉姆矩阵：

Wolfram Language code: Inverse[p].PadRight[slowgramian, {3, 3}].Inverse[p]//MatrixForm
Wolfram Language code: Inverse[p].PadLeft[fastgramian, {3, 3}].Inverse[p]//MatrixForm

这与直接使用 ControllabilityGramian 所得到的结果相同：

Wolfram Language code: MatrixForm /@ ControllabilityGramian[ssm]

可能存在的问题  (1)

可控性格拉姆矩阵不是为非渐近稳定系统定义的：

Wolfram Language code: ControllabilityGramian[StateSpaceModel[{{{0, 0, 0}, {0, -1, 0}, {0, 0, -2}}, {{1}, {-1}, {1}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]
Wolfram Research (2010)，ControllabilityGramian，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ControllabilityGramian.html （更新于 2012 年）.

文本

Wolfram Research (2010)，ControllabilityGramian，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ControllabilityGramian.html （更新于 2012 年）.

CMS

Wolfram 语言. 2010. "ControllabilityGramian." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2012. https://reference.wolfram.com/language/ref/ControllabilityGramian.html.

APA

Wolfram 语言. (2010). ControllabilityGramian. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/ControllabilityGramian.html 年

BibTeX

@misc{reference.wolfram_2026_controllabilitygramian, author="Wolfram Research", title="{ControllabilityGramian}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/ControllabilityGramian.html}", note=[Accessed: 07-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_controllabilitygramian, organization={Wolfram Research}, title={ControllabilityGramian}, year={2012}, url={https://reference.wolfram.com/language/ref/ControllabilityGramian.html}, note=[Accessed: 07-September-2026]}