WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

CycleIndexPolynomial[perm,{x1,…,xn}]

置換 perm の変数 xiにおける巡回指標単項式を構築する．

CycleIndexPolynomial[group,{x1,…,xn}]

group の変数 xiにおける巡回指標多項式を構築する．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

CycleIndexPolynomial

CycleIndexPolynomial[perm,{x1,…,xn}]

置換 perm の変数 xiにおける巡回指標単項式を構築する．

CycleIndexPolynomial[group,{x1,…,xn}]

group の変数 xiにおける巡回指標多項式を構築する．

詳細

  • 置換群の巡回指標多項式は，対象の集合に対するその群の動作に関連する列挙の問題を解決するための有用な情報を提供する．これが，ポリア(Polya)理論の基本的な目的である．
  • CycleIndexPolynomial[perm,{x1,…,xk}]は，巡回構造が a1の1巡回，a2 の2巡回というような巡回を含む置換 perm に対してモニックな単項式 x1a1x2a2 … xkak を返す．
  • CycleIndexPolynomial[group,{x1,…,xk}]は，単項式 x1a1x2a2 … xkak の係数が群の元の数を多項式を返す．この元の巡回構造は，a1の1巡回，a2 の2巡回というような巡回を群の位数で割ったものを含む．これは，その元の巡回指標多項式の平均である．
  • 置換あるいは群 p について， CycleIndexPolynomial[p,vars,n]は p が n 個の点の領域に作用することを示す．ただし，n はPermutationMax[p]以上でなければならない．
  • 置換あるいは群 p について，CycleIndexPolynomial[p,vars]はCycleIndexPolynomial[p,vars,PermutationMax[p]]に等しい．
  • 群の元には存在しない巡回の長さに対応する変数は無視される．
  • 群の元が与えられた変数の数を超える巡回の長さを含む場合，結果は事実上欠損した変数の代りに値1を使う．
  • 置換あるいは置換群の巡回の長さは常にその台によって，PermutationLengthで与えられるように上に有界である．したがって，CycleIndexPolynomialの第2引数として変数の数が含まれることはほぼ間違いのないことである．

例題

すべて開く すべて閉じる

例  (2)

置換の巡回指標単項式：

Wolfram Language code: CycleIndexPolynomial[Cycles[{{3, 2, 6}, {1, 7}, {4, 5}}], {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3]}]

5つの点についての交代群の巡回指標多項式：

Wolfram Language code: CycleIndexPolynomial[AlternatingGroup[5], {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3], Subscript[x, 4], Subscript[x, 5]}]

スコープ  (4)

置換の巡回指標単項式：

Wolfram Language code: CycleIndexPolynomial[Cycles[{{1, 7, 3}, {4, 10}, {6, 2, 8}, {9, 11}, {13, 15}}], {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3]}]
Wolfram Language code: CycleIndexPolynomial[{8, 9, 3, 13, 10, 11, 6, 12, 14, 4, 7, 1, 5, 2, 15}, {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3], Subscript[x, 4], Subscript[x, 5]}]

作用領域の大きさを指定する：

Wolfram Language code: CycleIndexPolynomial[Cycles[{{3, 4}, {5, 6}, {8, 10}}], {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3]}, 15]
Wolfram Language code: CycleIndexPolynomial[{1, 2, 3, 4, 7, 5, 6, 8, 9, 10}, {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3]}, 15]

置換群の巡回指標多項式：

Wolfram Language code: CycleIndexPolynomial[DihedralGroup[8], Array[Subscript[x, ##]&, 8]]
Wolfram Language code: CycleIndexPolynomial[PermutationGroup[{Cycles[{{1, 2}}], Cycles[{{1, 3}, {2, 4}}]}], {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3], Subscript[x, 4]}]

作用領域の大きさを指定する：

Wolfram Language code: CycleIndexPolynomial[CyclicGroup[10], Array[Subscript[x, ##]&, 10], 15]
Wolfram Language code: CycleIndexPolynomial[PermutationGroup[{Cycles[{{1, 2}}], Cycles[{{1, 3}, {2, 4}}]}], {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3], Subscript[x, 4]}, 10]

アプリケーション  (1)

巡回指標多項式は，計数のポリヤ(Pólya)理論にとって絶対不可欠なものである．古典的な例としてさまざまな色のビーズで何本のネックレスが作れるかという問題がある：

巡回回転のもとで不変の10個のビーズが付いたネックレスがある：

Wolfram Language code: poly = CycleIndexPolynomial[CyclicGroup[10], Array[Subscript[a, ##]&, 10]]

この紐には，r，g，bで示される3色のビーズが付いている：

Wolfram Language code: rgbpoly = poly /. Subscript[a, i_] -> r^i + g^i + b^i//Expand

例えば，r色のビーズが3個，g色のビーズが5個，b色のビーズが2個付いたネックレスが252本あるとする：

Wolfram Language code: Coefficient[rgbpoly, r^3 g^5 b^2]

これは実際にネックレスを作って確かめることができる：

Wolfram Language code: GroupOrbits[CyclicGroup[10], Permutations[{r, r, r, g, g, g, g, g, b, b}], Permute]//Length

ネックレスが直径に沿った鏡映でも不変だとすると，対称群は二面角である：

Wolfram Language code: poly = CycleIndexPolynomial[DihedralGroup[10], Array[Subscript[a, ##]&, 10]]

ここで，総数は異なる：

Wolfram Language code: rgbpoly = poly /. Subscript[a, i_] -> r^i + g^i + b^i//Expand
Wolfram Language code: Coefficient[rgbpoly, r^3 g^5 b^2]

特性と関係  (4)

恒等置換は次数0であり，したがって点は移動されない：

Wolfram Language code: CycleIndexPolynomial[Cycles[{}], {Subscript[x, 1], Subscript[x, 2]}]

これが4つの点の集合に作用すると，巡回指標多項式は4つのシングルトンの存在を反映する：

Wolfram Language code: CycleIndexPolynomial[Cycles[{}], {Subscript[x, 1], Subscript[x, 2]}, 4]

動かされない各点が第1変数による乗算に貢献する：

Wolfram Language code: CycleIndexPolynomial[Cycles[{{5, 6, 7}}], {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3]}]
Wolfram Language code: CycleIndexPolynomial[Cycles[{{1, 2, 3}}], {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3]}, 7]
Wolfram Language code: CycleIndexPolynomial[PermutationGroup[{Cycles[{{5, 6, 7}}]}], {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3]}]//Factor

欠損変数は事実上1で置き換えられる：

Wolfram Language code: p = CycleIndexPolynomial[SymmetricGroup[5], {Subscript[x, 1], Subscript[x, 2]}]
Wolfram Language code: p === CycleIndexPolynomial[SymmetricGroup[5], {Subscript[x, 1], Subscript[x, 2], 1, 1, 1}]
Wolfram Language code: CycleIndexPolynomial[SymmetricGroup[5], {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3], Subscript[x, 4], Subscript[x, 5]}]
Wolfram Language code: p === (% /. {Subscript[x, 3] -> 1, Subscript[x, 4] -> 1, Subscript[x, 5] -> 1})

群の直積の巡回指標多項式は，群の巡回指標多項式の積である：

Wolfram Language code: p4 = CycleIndexPolynomial[CyclicGroup[4], {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3], Subscript[x, 4]}]
Wolfram Language code: p5 = CycleIndexPolynomial[CyclicGroup[5], {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3], Subscript[x, 4], Subscript[x, 5]}]
Wolfram Language code: CycleIndexPolynomial[AbelianGroup[{4, 5}], {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3], Subscript[x, 4], Subscript[x, 5]}]
Wolfram Language code: % === Expand[p4 p5]
Wolfram Research (2012), CycleIndexPolynomial, Wolfram言語関数， https://reference.wolfram.com/language/ref/CycleIndexPolynomial.html.

テキスト

Wolfram Research (2012), CycleIndexPolynomial, Wolfram言語関数， https://reference.wolfram.com/language/ref/CycleIndexPolynomial.html.

CMS

Wolfram Language. 2012. "CycleIndexPolynomial." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/CycleIndexPolynomial.html.

APA

Wolfram Language. (2012). CycleIndexPolynomial. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CycleIndexPolynomial.html

BibTeX

@misc{reference.wolfram_2026_cycleindexpolynomial, author="Wolfram Research", title="{CycleIndexPolynomial}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/CycleIndexPolynomial.html}", note=[Accessed: 09-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_cycleindexpolynomial, organization={Wolfram Research}, title={CycleIndexPolynomial}, year={2012}, url={https://reference.wolfram.com/language/ref/CycleIndexPolynomial.html}, note=[Accessed: 09-August-2026]}