WOLFRAM

Wolfram 语言与系统参考资料中心

CycleIndexPolynomial[perm,{x1,…,xn}]

构建变量 xi 的置换 perm 的循环指数单项式.

CycleIndexPolynomial[group,{x1,…,xn}]

构建变量 xi 的 group 的循环指数多项式.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
属性和关系  
参见
相关指南
历史
按以下格式引用：

CycleIndexPolynomial

CycleIndexPolynomial[perm,{x1,…,xn}]

构建变量 xi 的置换 perm 的循环指数单项式.

CycleIndexPolynomial[group,{x1,…,xn}]

构建变量 xi 的 group 的循环指数多项式.

更多信息

  • 置换群的循环指数多项式提供了有用的信息，可解决与该群对一组对象的作用相关的枚举问题. 它是 Pólya 理论中的一个基础课题.
  • CycleIndexPolynomial[perm,{x1,…,xk}] 返回置换 perm 的一个首一单项式 x1a1x2a2 … xkak，其循环结构包括 a1 1-循环，a2 2-循环，以此类推.
  • CycleIndexPolynomial[group,{x1,…,xk}] 返回一个多项式，其中单项式 x1a1x2a2 … xkak 的系数给出群元素的个数，其循环结构包含 a1 1-循环，a2 2-循环，等等，除以群的阶数. 这是它的元素的循环指标单项式的平均值.
  • 对于置换或群 p，CycleIndexPolynomial[p,vars,n] 表示 p 作用于 n 个点的域，其中 n 必须等于或大于 PermutationMax[p].
  • 对于置换或群 p，CycleIndexPolynomial[p,vars] 等价于 CycleIndexPolynomial[p,vars,PermutationMax[p]].
  • 与循环长度对应的变量，如果不出现在群元素中，则被忽略.
  • 如果群元素包含的循环长度超出了所提供的变量个数，则结果将使用值 1 作为这些缺失的变量.
  • 置换或置换群的循环长度总是以它们的支持长度以上为界，正如 PermutationLength 所给出的一样. 因此，对于作为 CycleIndexPolynomial 第二个参数所包括的变量个数而言，这是一个安全的估计.

范例

打开所有单元 关闭所有单元

基本范例  (2)

置换的循环指标单项式：

Wolfram Language code: CycleIndexPolynomial[Cycles[{{3, 2, 6}, {1, 7}, {4, 5}}], {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3]}]

五个点上替换群的循环指标单项式：

Wolfram Language code: CycleIndexPolynomial[AlternatingGroup[5], {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3], Subscript[x, 4], Subscript[x, 5]}]

范围  (4)

置换的循环指标单项式：

Wolfram Language code: CycleIndexPolynomial[Cycles[{{1, 7, 3}, {4, 10}, {6, 2, 8}, {9, 11}, {13, 15}}], {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3]}]
Wolfram Language code: CycleIndexPolynomial[{8, 9, 3, 13, 10, 11, 6, 12, 14, 4, 7, 1, 5, 2, 15}, {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3], Subscript[x, 4], Subscript[x, 5]}]

指定作用的定义域大小：

Wolfram Language code: CycleIndexPolynomial[Cycles[{{3, 4}, {5, 6}, {8, 10}}], {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3]}, 15]
Wolfram Language code: CycleIndexPolynomial[{1, 2, 3, 4, 7, 5, 6, 8, 9, 10}, {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3]}, 15]

置换群的循环指标多项式：

Wolfram Language code: CycleIndexPolynomial[DihedralGroup[8], Array[Subscript[x, ##]&, 8]]
Wolfram Language code: CycleIndexPolynomial[PermutationGroup[{Cycles[{{1, 2}}], Cycles[{{1, 3}, {2, 4}}]}], {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3], Subscript[x, 4]}]

指定作用的定义域大小：

Wolfram Language code: CycleIndexPolynomial[CyclicGroup[10], Array[Subscript[x, ##]&, 10], 15]
Wolfram Language code: CycleIndexPolynomial[PermutationGroup[{Cycles[{{1, 2}}], Cycles[{{1, 3}, {2, 4}}]}], {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3], Subscript[x, 4]}, 10]

应用  (1)

循环指标多项式在 Pólya 计数理论中至关重要. 一个经典例子是计算不同颜色的珠子可以串成多少项链.

假定项链由10个珠子串成，在循环轮换时顺序不变：

Wolfram Language code: poly = CycleIndexPolynomial[CyclicGroup[10], Array[Subscript[a, ##]&, 10]]

假定珠子由三种颜色组成，分别用 r、g 和 b 表示：

Wolfram Language code: rgbpoly = poly /. Subscript[a, i_] -> r^i + g^i + b^i//Expand

例如，有252个项链，用三个 r 珠，五个 g 珠和两个 b 珠组成：

Wolfram Language code: Coefficient[rgbpoly, r^3 g^5 b^2]

这可以通过实际制作项链检查：

Wolfram Language code: GroupOrbits[CyclicGroup[10], Permutations[{r, r, r, g, g, g, g, g, b, b}], Permute]//Length

如果认为项链沿直径在反射情况下也是不变的，则该对称群是二面体群：

Wolfram Language code: poly = CycleIndexPolynomial[DihedralGroup[10], Array[Subscript[a, ##]&, 10]]

现在的数目不同：

Wolfram Language code: rgbpoly = poly /. Subscript[a, i_] -> r^i + g^i + b^i//Expand
Wolfram Language code: Coefficient[rgbpoly, r^3 g^5 b^2]

属性和关系  (4)

恒等排列的次数为零，因此不能移动任何点：

Wolfram Language code: CycleIndexPolynomial[Cycles[{}], {Subscript[x, 1], Subscript[x, 2]}]

如果它作用于四个点的集合，则循环指标多项式反映了四个单体的存在：

Wolfram Language code: CycleIndexPolynomial[Cycles[{}], {Subscript[x, 1], Subscript[x, 2]}, 4]

每个不移动的点贡献第一个变量作为倍数：

Wolfram Language code: CycleIndexPolynomial[Cycles[{{5, 6, 7}}], {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3]}]
Wolfram Language code: CycleIndexPolynomial[Cycles[{{1, 2, 3}}], {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3]}, 7]
Wolfram Language code: CycleIndexPolynomial[PermutationGroup[{Cycles[{{5, 6, 7}}]}], {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3]}]//Factor

缺失的变量实际上由1替换：

Wolfram Language code: p = CycleIndexPolynomial[SymmetricGroup[5], {Subscript[x, 1], Subscript[x, 2]}]
Wolfram Language code: p === CycleIndexPolynomial[SymmetricGroup[5], {Subscript[x, 1], Subscript[x, 2], 1, 1, 1}]
Wolfram Language code: CycleIndexPolynomial[SymmetricGroup[5], {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3], Subscript[x, 4], Subscript[x, 5]}]
Wolfram Language code: p === (% /. {Subscript[x, 3] -> 1, Subscript[x, 4] -> 1, Subscript[x, 5] -> 1})

两个置换群的直积的循环指标多项式等于各置换群的指标多项式的积：

Wolfram Language code: p4 = CycleIndexPolynomial[CyclicGroup[4], {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3], Subscript[x, 4]}]
Wolfram Language code: p5 = CycleIndexPolynomial[CyclicGroup[5], {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3], Subscript[x, 4], Subscript[x, 5]}]
Wolfram Language code: CycleIndexPolynomial[AbelianGroup[{4, 5}], {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3], Subscript[x, 4], Subscript[x, 5]}]
Wolfram Language code: % === Expand[p4 p5]
Wolfram Research (2012)，CycleIndexPolynomial，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CycleIndexPolynomial.html.

文本

Wolfram Research (2012)，CycleIndexPolynomial，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CycleIndexPolynomial.html.

CMS

Wolfram 语言. 2012. "CycleIndexPolynomial." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/CycleIndexPolynomial.html.

APA

Wolfram 语言. (2012). CycleIndexPolynomial. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/CycleIndexPolynomial.html 年

BibTeX

@misc{reference.wolfram_2026_cycleindexpolynomial, author="Wolfram Research", title="{CycleIndexPolynomial}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/CycleIndexPolynomial.html}", note=[Accessed: 09-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_cycleindexpolynomial, organization={Wolfram Research}, title={CycleIndexPolynomial}, year={2012}, url={https://reference.wolfram.com/language/ref/CycleIndexPolynomial.html}, note=[Accessed: 09-September-2026]}