WOLFRAM

Wolfram 语言与系统参考资料中心

DescriptorStateSpace

是 StateSpaceModel 和 StateSpaceTransform 一个选项，指定是用描述子还是标准表示法.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
属性和关系  
参见
相关指南
历史
按以下格式引用：

DescriptorStateSpace

DescriptorStateSpace

是 StateSpaceModel 和 StateSpaceTransform 一个选项，指定是用描述子还是标准表示法.

更多信息

  • 在 StateSpaceModel[{a,b,c,d,e}] 中，矩阵 e 是描述子矩阵.
  • 表示连续时间标准和描述子状态空间模型的方程是：
  • 标准状态空间
    描述子状态空间
  • 离散时间系统具有相似格式.
  • 选项可以使用下列数值：
  • Automatic自动确定表示法
    False使用标准状态空间表示法
    True使用描述子状态空间表示法
  • 如果设置为 DescriptorStateSpace->Automatic，仅当无法获得标准表示形式时 StateSpaceModel 才使用描述子表示，StateSpaceTransform 不对表示进行更改.

范例

打开所有单元 关闭所有单元

基本范例  (4)

获取描述子 StateSpaceModel：

Wolfram Language code: StateSpaceModel[2 x'[t] == x[t] + u[t], x[t], u[t], x[t], t, DescriptorStateSpace -> True]

默认情况下，得到标准格式：

Wolfram Language code: StateSpaceModel[2x'[t] == x[t] + u[t], x[t], u[t], x[t], t]

对于某些奇异系统，默认情况下获取描述子形式：

Wolfram Language code: StateSpaceModel[{Subscript[x, 1]'[t] + Subscript[x, 2]'[t] == Subscript[x, 1][t] + u[t], Subscript[x, 1][t] + Subscript[x, 2][t] + u[t] == 0}, {Subscript[x, 1][t], Subscript[x, 2][t]}, u[t], Subscript[x, 1][t], t]

这是因为不可能获取标准形式：

Wolfram Language code: StateSpaceModel[{Subscript[x, 1]'[t] + Subscript[x, 2]'[t] == Subscript[x, 1][t] + u[t], Subscript[x, 1][t] + Subscript[x, 2][t] + u[t] == 0}, {Subscript[x, 1][t], Subscript[x, 2][t]}, u[t], Subscript[x, 1][t], t, DescriptorStateSpace -> False]

可能的情况下，获取标准形式：

Wolfram Language code: StateSpaceModel[{Subscript[x, 1]'[t] == Subscript[x, 1][t] + u[t], Subscript[x, 1][t] == Subscript[x, 2][t]}, {Subscript[x, 1][t], Subscript[x, 2][t]}, u[t], Subscript[x, 1][t], t]//FullSimplify

描述子形式：

Wolfram Language code: ssmD = StateSpaceModel[{Subscript[x, 1]'[t] == Subscript[x, 1][t] + u[t], Subscript[x, 1][t] == Subscript[x, 2][t]}, {Subscript[x, 1][t], Subscript[x, 2][t]}, u[t], Subscript[x, 1][t], t, DescriptorStateSpace -> True]

从 StateSpaceTransform 获得描述子形式的结果：

Wolfram Language code: StateSpaceTransform[StateSpaceModel[{{{a}}, {{b}}, {{c}}, {{d}}}, {x}, SamplingPeriod -> None, SystemsModelLabels -> None], {{p}}, DescriptorStateSpace -> True]

默认情况下，形式不变：

Wolfram Language code: StateSpaceTransform[StateSpaceModel[{{{a}}, {{b}}, {{c}}, {{d}}}, {x}, SamplingPeriod -> None, SystemsModelLabels -> None], {{p}}]

范围  (6)

从描述子状态空间模型创建标准状态空间模型：

Wolfram Language code: StateSpaceModel[StateSpaceModel[{{{1, -1, 0}, {-1, 1, 1}, {0, 2, 1}}, {{1, 2}, {-1, 1}, {0, 2}}, {{1, -1, 0}}, {{0, 0}}, {{1, 0, 2}, {0, 2, -1}, {1, 0, 1}}}, SamplingPeriod -> None, SystemsModelLabels -> None], DescriptorStateSpace -> False]

从标准状态空间模型创建描述子状态空间模型：

Wolfram Language code: StateSpaceModel[StateSpaceModel[{{{-1, 2}, {1, -4}}, {{1}, {1}}, {{1, 0}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None], DescriptorStateSpace -> True]

把恰当传递函数模型转化为描述子状态空间模型：

Wolfram Language code: StateSpaceModel[TransferFunctionModel[{{{1}}, 1 - 2*s + s^2}, s], DescriptorStateSpace -> True]

从常微分方程创建描述子状态空间模型：

Wolfram Language code: StateSpaceModel[{Subscript[a, 3] x'''[t] + Subscript[a, 2] x''[t] + Subscript[a, 1] x'[t] + Subscript[a, 0] x[t] == f[t]}, {{x[t], 0}, {x'[t], 0}, {x''[t], 0}}, {{f[t], 0}}, {x[t]}, t, DescriptorStateSpace -> True]

以描述子形式获得标准 StateSpaceModel 的状态转换：

Wolfram Language code: StateSpaceTransform[StateSpaceModel[{{{a}}, {{b}}, {{c}}, {{d}}}, {x}, SamplingPeriod -> None, SystemsModelLabels -> None], {{p}}, DescriptorStateSpace -> True]

它给出与显式描述子规范相同的结果：

Wolfram Language code: StateSpaceTransform[StateSpaceModel[{{{a}}, {{b}}, {{c}}, {{d}}, {{1}}}, SamplingPeriod -> None, SystemsModelLabels -> None], {{p}}]

也可以通过逆转换获得相似的结果：

Wolfram Language code: StateSpaceTransform[StateSpaceModel[{{{a}}, {{b}}, {{c}}, {{d}}}, {x}, SamplingPeriod -> None, SystemsModelLabels -> None], {Automatic, {{q}}}, DescriptorStateSpace -> True]
Wolfram Language code: StateSpaceTransform[StateSpaceModel[{{{a}}, {{b}}, {{c}}, {{d}}, {{1}}}, SamplingPeriod -> None, SystemsModelLabels -> None], {Automatic, {{q}}}]

具有可逆描述子矩阵的描述子矩阵 StateSpaceModel：

Wolfram Language code: ssm = StateSpaceModel[{{{a}}, {{b}}, {{c}}, {{d}}, {{e}}}, {x}, SamplingPeriod -> None, SystemsModelLabels -> None];

它的状态变换可以以标准格式获得：

Wolfram Language code: StateSpaceTransform[ssm, {{p}}, DescriptorStateSpace -> False]

属性和关系  (2)

默认情况下，不恰当传递函数模型将创建描述子状态空间模型：

Wolfram Language code: tfm = TransferFunctionModel[{{{s^3}}, 1 - 2*s + s^2}, s]; StateSpaceModel[tfm, DescriptorStateSpace -> Automatic]

没有标准状态空间实现：

Wolfram Language code: StateSpaceModel[tfm, DescriptorStateSpace -> False]

含有不可逆描述矩阵的描述子 StateSpaceModel：

Wolfram Language code: ssm = StateSpaceModel[{{{Subscript[a, 1], 0}, {0, Subscript[a, 2]}}, {{Subscript[b, 1]}, {Subscript[b, 2]}}, {{1, 0}, {0, 1}}, {{0}, {0}}, {{Subscript[e, 1], 0}, {0, 0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]

StateSpaceTransform 生成描述子模型：

Wolfram Language code: StateSpaceTransform[ssm, Array[Subscript[q, ##]&, {2, 2}]]

状态转换不能以标准形式获得：

Wolfram Language code: StateSpaceTransform[ssm, Array[Subscript[q, ##]&, {2, 2}], DescriptorStateSpace -> False]
Wolfram Research (2012)，DescriptorStateSpace，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DescriptorStateSpace.html （更新于 2014 年）.

文本

Wolfram Research (2012)，DescriptorStateSpace，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DescriptorStateSpace.html （更新于 2014 年）.

CMS

Wolfram 语言. 2012. "DescriptorStateSpace." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2014. https://reference.wolfram.com/language/ref/DescriptorStateSpace.html.

APA

Wolfram 语言. (2012). DescriptorStateSpace. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/DescriptorStateSpace.html 年

BibTeX

@misc{reference.wolfram_2026_descriptorstatespace, author="Wolfram Research", title="{DescriptorStateSpace}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/DescriptorStateSpace.html}", note=[Accessed: 10-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_descriptorstatespace, organization={Wolfram Research}, title={DescriptorStateSpace}, year={2014}, url={https://reference.wolfram.com/language/ref/DescriptorStateSpace.html}, note=[Accessed: 10-September-2026]}