WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

DiskSegment[{x,y},r,{θ1,θ2}]

{x,y}を中心とした半径 r の円板の，角度 θ1から θ2までの部分を表す．

DiskSegment[{x,y},{rx,ry},{θ1,θ2}]

半軸の長さが rxと ryで軸に平行な楕円の，角度 θ1から θ2までの部分を表す．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
グラフィックス  
指定  
スタイル付け  
座標  
領域  
アプリケーション  
特性と関係  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

DiskSegment

DiskSegment[{x,y},r,{θ1,θ2}]

{x,y}を中心とした半径 r の円板の，角度 θ1から θ2までの部分を表す．

DiskSegment[{x,y},{rx,ry},{θ1,θ2}]

半軸の長さが rxと ryで軸に平行な楕円の，角度 θ1から θ2までの部分を表す．

詳細とオプション

  • DiskSegmentは，幾何学領域およびグラフィックスプリミティブとして使うことができる．
  • DiskSegmentは，同じ引数を持つDiskの塗り潰された部分を表す．
  • 角度は，正の x 方向からラジアン単位で反時計回りに測られる．
  • DiskSegmentはGraphicsで使うことができる．
  • グラフィックスでは，点{x,y}はDynamic式でよい．
  • グラフィックスの描画は，FaceForm，EdgeForm等の指示子および色の影響を受ける．

例題

すべて開く すべて閉じる

例  (5)

単位円板の半分：

Wolfram Language code: Graphics[DiskSegment[{0, 0}, 1, {0, Pi}]]

円板の一部：

Wolfram Language code: Graphics[{Orange, DiskSegment[{0, 0}, 1, {0, 3Pi / 4}]}]

楕円板の一部：

Wolfram Language code: Graphics[{Orange, DiskSegment[{0, 0}, {3, 2}, {-Pi / 4, 3Pi / 4}]}]

さまざまにスタイル付けされた円板の一部：

Wolfram Language code: {Graphics[{Pink, DiskSegment[{0, 0}, 1, {0, 3Pi / 4}]}], Graphics[{EdgeForm[Thick], Pink, DiskSegment[{0, 0}, 1, {0, 3Pi / 4}]}], Graphics[{EdgeForm[Dashed], Pink, DiskSegment[{0, 0}, 1, {0, 3Pi / 4}]}], Graphics[{EdgeForm[Directive[Thick, Dashed, Blue]], Pink, DiskSegment[{0, 0}, 1, {0, 3Pi / 4}]}]}

円板の一部（半円板）のAreaを得る：

Wolfram Language code: Area[DiskSegment[{0, 0}, 1, {0, Pi}]]

楕円板の一部の面積：

Wolfram Language code: Area[DiskSegment[{0, 0}, {Subscript[r, 1], Subscript[r, 2]}, {0, Pi / 3}]]

スコープ  (17)

グラフィックス  (7)

指定  (4)

半径を指定する：

Wolfram Language code: Graphics[{Red, DiskSegment[{0, 0}, 5, {0, Pi / 2}], Green, DiskSegment[{0, 0}, 3, {0, Pi / 2}], Blue, DiskSegment[{0, 0}, 1, {0, Pi / 2}]}]

中心を指定する：

Wolfram Language code: Graphics[{Red, DiskSegment[{0, 0}, 2, {0, Pi / 2}], Green, DiskSegment[{1, 1}, 2, {0, Pi / 2}], Blue, DiskSegment[{2, 2}, 2, {0, Pi / 2}]}]

角度を指定する：

Wolfram Language code: Graphics[DiskSegment[{0, 0}, 1, {0, Pi / 2}]]
Wolfram Language code: Graphics[DiskSegment[{0, 0}, 1, {-Pi / 3, 6Pi / 5}]]

楕円板の一部：

Wolfram Language code: Graphics[DiskSegment[{0, 0}, {2, 1}, {0, 3Pi / 2}]]

スタイル付け  (2)

色指示子で円板の一部の表面の色を指定する：

Wolfram Language code: Table[Graphics[{c, DiskSegment[{0, 0}, 1, {0, 3Pi / 2}]}], {c, {Red, Green, Blue, Yellow}}]

FaceFormとEdgeFormを使って内側と境界のスタイルを指定することができる：

Wolfram Language code: Graphics[{FaceForm[Pink], EdgeForm[Directive[Dashed, Thick, Blue]], DiskSegment[{0, 0}, 1, {0, 3Pi / 2}]}]

円板の一部の境界：

Wolfram Language code: Graphics[{Yellow, EdgeForm[Directive[Thick, Blue]], DiskSegment[{0, 0}, 1, {0, 3Pi / 2}]}]

座標  (1)

点はDynamicでよい：

Wolfram Language code: DynamicModule[{x}, {Slider[Dynamic[x], {0, 3}], Graphics[{DiskSegment[{0, 0}, 1, {0, 3Pi / 2}], DiskSegment[Dynamic[{x, x}], 1, {0, 3Pi / 2}]}, PlotRange -> {{-1, 4}, {-1, 4}}]}]

領域  (10)

埋込み次元：

Wolfram Language code: RegionEmbeddingDimension[DiskSegment[{x, y}, r, {Subscript[θ, 1], Subscript[θ, 2]}]]

幾何次元：

Wolfram Language code: RegionDimension[DiskSegment[{x, y}, r, {Subscript[θ, 1], Subscript[θ, 2]}]]

点の帰属判定：

Wolfram Language code: {RegionMember[DiskSegment[{0, 0}, 1, {0, 3Pi / 2}], {0, 0}], RegionMember[DiskSegment[{0, 0}, 1, {0, 3Pi / 2}], {0, 2}]}

点の帰属条件を得る：

Wolfram Language code: RegionMember[DiskSegment[{Subscript[x, 0], Subscript[y, 0]}, {Subscript[r, 1], Subscript[r, 2]}, {Subscript[θ, 1], Subscript[θ, 2]}], {x, y}]

面積：

Wolfram Language code: ℛ = DiskSegment[{0, 0}, 1, {0, 3Pi / 2}];
Wolfram Language code: {Area[ℛ], RegionMeasure[ℛ]}

重心：

Wolfram Language code: c = RegionCentroid[ℛ]
Wolfram Language code: Graphics[{{Pink, ℛ}, {Black, Point[c]}}]

点からの距離：

Wolfram Language code: ℛ = DiskSegment[{0, 0}, 1, {0, Pi}];
Wolfram Language code: {RegionDistance[ℛ, {1, 2}], RegionDistance[ℛ, {0, 0}]}

点からの符号付き距離：

Wolfram Language code: ℛ = DiskSegment[{0, 0}, 1, {0, 3Pi / 2}];
Wolfram Language code: {SignedRegionDistance[ℛ, {1, 2}], SignedRegionDistance[ℛ, {0, 0}]}

領域内の最近点：

Wolfram Language code: ℛ = DiskSegment[{0, 0}, 1, {0, 3Pi / 2}];
Wolfram Language code: RegionNearest[ℛ, {5, 6}]

最近点：

Wolfram Language code: pts = Table[{1, 2} + 5{Cos[k 2 π / 16], Sin[k 2π / 16]}, {k, 0., 15}]; nst = RegionNearest[ℛ, #]& /@ pts;
Wolfram Language code: Legended[Graphics[{{Gray, ℛ}, {Thin, Gray, Line[Transpose[{pts, nst}]]}, {Red, Point[pts]}, {Blue, Point[nst]}}], PointLegend[{Red, Blue}, {"start", "nearest"}]]

楕円の一部は有界である：

Wolfram Language code: ℛ = DiskSegment[{0, 0}, {2, 1}, {0, 3Pi / 2}];
Wolfram Language code: BoundedRegionQ[ℛ]

その領域を得る：

Wolfram Language code: rr = RegionBounds[ℛ]
Wolfram Language code: Graphics[{StandardBlue, ℛ, {EdgeForm[{Dashed, Red}], Opacity[0.1, Yellow], Cuboid@@Transpose[rr]}}]

楕円の一部の上で積分する：

Wolfram Language code: ℛ = DiskSegment[{0, 0}, {1, 2}, {0, Pi / 2}];
Wolfram Language code: Integrate[x y, {x, y}∈ℛ]

楕円の一部の上で最適化する：

Wolfram Language code: ℛ = DiskSegment[{0, 0}, {2, 1}, {0, 3Pi / 2}];
Wolfram Language code: {MinValue[{x y - x, {x, y}∈ℛ}, {x, y}], ArgMin[{x y - x, {x, y}∈ℛ}, {x, y}]}

楕円の一部の上で方程式を解く：

Wolfram Language code: ℛ = DiskSegment[{0, 0}, {2, 3}, {0, 3Pi / 2}];
Wolfram Language code: Solve[x^2 + y^2 == 7 && x y == 1 && {x, y}∈ℛ, {x, y}]
Wolfram Language code: Show[{Graphics[{{StandardGreen, ℛ}, {Blue, Circle[{0, 0}, Sqrt[7]]}}], Plot[1 / x, {x, -3, 5}, PlotRange -> {{-3, 5}, {-3, 6}}], Graphics[{PointSize[Large], Red, Point[{x, y}] /. %}]}, Axes -> True]

アプリケーション  (5)

円板の一部の上で関数をプロットする：

Wolfram Language code: Plot3D[Sin[x + Cos[y]], {x, y}∈DiskSegment[{0, 0}, 1, {0, Pi}]]

RegionProductで3Dの円板の一部の押出し形成を作る：

Wolfram Language code: ℛ = RegionProduct[DiskSegment[{0, 0}, 1, {0, 3Pi / 4}], Line[{{0}, {1}}]];
Wolfram Language code: BoundaryDiscretizeRegion[ℛ]

円板と正多角形の領域の差を示すために，部分円板の集合を使うことができる．まず，弧の集合を得る：

Wolfram Language code: n = 5; angles = ArcTan@@@CirclePoints[n]; arcs = Transpose@{angles, RotateLeft[angles]}//N

しかし，弧の中には角が大きくならないものもある．そのような場合は 2番目の弧に を加えて増加するようにする：

Wolfram Language code: arcs = If[#[[2]] < #[[1]], # + {0, 2Pi}, #]& /@ arcs

最後にこれを可視化する：

Wolfram Language code: Graphics[DiskSegment[{0, 0}, 1, #]& /@ arcs]

レンズは隣接する2つの弧の部分としてモデル化することができる．原点を中心とする，高さ，半径 の右側に膨らむレンズを作る：

Wolfram Language code: x = -Sqrt[r ^ 2 - h ^ 2];a = ArcTan[-x, h];
Wolfram Language code: Graphics[DiskSegment[{x, 0}, r, {-a, a}], ImageSize -> {Automatic, 75}] /. {h -> 1, r -> 2}

左側に膨らむレンズは， の位置を入れ替えて，弧の向きを変える必要がある：

Wolfram Language code: x = Sqrt[r ^ 2 - h ^ 2];a = ArcTan[x, h];
Wolfram Language code: Graphics[DiskSegment[{x, 0}, r, {Pi - a, Pi + a}], ImageSize -> {Automatic, 75}] /. {h -> 1, r -> 2}

指定された高さと半径の円板のペアを作る関数を構築し，半径の範囲で可視化する：

Wolfram Language code: lens[h_, r1_, r2_] /; r1 ≥ h && r2 ≥ h := With[{x1 = Sqrt[r1 ^ 2 - h ^ 2], x2 = -Sqrt[r2 ^ 2 - h ^ 2]}, {DiskSegment[{x1, 0}, r1, {-1, 1} * ArcTan[x1, h] + {Pi, Pi}], DiskSegment[{x2, 0}, r2, {-1, 1} * ArcTan[-x2, h]]}]
Wolfram Language code: Manipulate[Graphics[lens[1, rl, rr], PlotRange -> 1], {{rl, 1.3, "Left Radius"}, 1, 3}, {{rr, 1.2, "Right Radius"}, 1, 3}, SaveDefinitions -> True]

求める測度の領域内にある既知の体積範囲のランダムな点との割合として領域の近似測度を求めることができる．部分円板を例として使う：

Wolfram Language code: region = DiskSegment[{0, 0}, {1, 2}, {2, 3}];

この領域は，面積が16の領域および内にあるの．この一般的な領域内にあるランダムな点のリストを生成する：

Wolfram Language code: randompoints = RandomReal[{-2, 2}, {1000000, 2}];

部分円板内にあるこのランダムな点の割合を百分率で求める：

Wolfram Language code: fraction = Count[RegionMember[region, randompoints], True] / 1000000

この領域（部分円板）の面積は上記の割合に点が分布している面積をかけたものに近いはずである．ここで得られた近似値を実際の値と比較する：

Wolfram Language code: fraction * 16//N
Wolfram Language code: RegionMeasure[region]//N

特性と関係  (4)

DiskSegmentはFilledCurveによって表すことができる：

Wolfram Language code: Subscript[ℛ, 1] = DiskSegment[{0, 0}, 1, {3Pi / 3, 5Pi / 3}];
Wolfram Language code: Subscript[ℛ, 2] = FilledCurve[BSplineCurve[{{-1, 0}, {-1, -1}, {0, -1}, {2 - Sqrt[3], -1}, {(1/2), -(Sqrt[3]/2)}, {-(1/4), -(Sqrt[3]/4)}, {-1, 0}}, SplineKnots -> {0, 0, 0, (1/3), (1/3), (2/3), (2/3), 1, 1, 1}, SplineWeights -> {1, 1, 2, 2, 16 - 8 Sqrt[3], 16 - 8 Sqrt[3], 16 - 8 Sqrt[3]}, SplineDegree -> 2]];
Wolfram Language code: Graphics /@ {Subscript[ℛ, 1], Subscript[ℛ, 2]}

円板の一部はDiskやその他の領域のRegionIntersectionの結果であることがある：

Wolfram Language code: disk = Disk[]; hs = HalfSpace[{-1, -2}, {1 / 4, 1 / 4}];
Wolfram Language code: ℛ = RegionIntersection[disk, hs]
Wolfram Language code: Graphics[{Orange, Opacity[0.3], disk, hs, {Red, ℛ}}]

ImplicitRegionは任意のDiskSegmentを表すことができる：

Wolfram Language code: Subscript[ℛ, 1] = ImplicitRegion[x^2 + y^2 ≤ 1 && 1 - x - (1 + Sqrt[2])y ≤ 0, {x, y}];
Wolfram Language code: Subscript[ℛ, 2] = DiskSegment[{0, 0}, 1, {0, 3π / 4}];
Wolfram Language code: Reduce[{Subscript[x, 1], Subscript[x, 2]}∈Subscript[ℛ, 1]⧦{Subscript[x, 1], Subscript[x, 2]}∈Subscript[ℛ, 2], {Subscript[x, 1], Subscript[x, 2]}, Reals]

ParametricRegionはDiskSegmentを表すことができる：

Wolfram Language code: Subscript[ℛ, 1] = ParametricRegion[{x, y}, {{x, -(1/Sqrt[2]), 1}, {y, -1 + x + Sqrt[2] Sqrt[1 - 2 x + x^2], Sqrt[1 - x^2]}}];
Wolfram Language code: Subscript[ℛ, 2] = DiskSegment[{0, 0}, 1, {0, 3π / 4}];
Wolfram Language code: Reduce[{Subscript[x, 1], Subscript[x, 2]}∈Subscript[ℛ, 1]⧦{Subscript[x, 1], Subscript[x, 2]}∈Subscript[ℛ, 2], {Subscript[x, 1], Subscript[x, 2]}, Reals]
Wolfram Language code: {RegionPlot[Subscript[ℛ, 1]], Graphics[{LightBlue, Subscript[ℛ, 2]}, Frame -> True, AspectRatio -> 1]}

おもしろい例題  (3)

ランダムな円板の一部の集合：

Wolfram Language code: Graphics[Table[{EdgeForm[Black], Hue[RandomReal[]], DiskSegment[RandomReal[4, {2}], RandomReal[1], RandomReal[2Pi] + {0, RandomReal[2Pi]}]}, {40}]]

円板の一部の族：

Wolfram Language code: Graphics[Table[{Hue[t / 15, 1, .9, .3], DiskSegment[{Cos[2Pi t / 15], Sin[2Pi t / 15]}, 1, {2Pi t / 15, 2Pi t / 15 + Pi}]}, {t, 15}]]

デジタル花弁：

Wolfram Language code: Graphics[Table[{EdgeForm[Opacity[.6]], Hue[(-11 + q + 19 r) / 72], DiskSegment[(8 - r){Cos[2Pi q / 20], Sin[2Pi q / 20]}, (8 - r) / 3, {2Pi q / 20, 2Pi q / 20 + Pi}]}, {r, 6}, {q, 20}]]
Wolfram Research (2015), DiskSegment, Wolfram言語関数， https://reference.wolfram.com/language/ref/DiskSegment.html.

テキスト

Wolfram Research (2015), DiskSegment, Wolfram言語関数， https://reference.wolfram.com/language/ref/DiskSegment.html.

CMS

Wolfram Language. 2015. "DiskSegment." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/DiskSegment.html.

APA

Wolfram Language. (2015). DiskSegment. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/DiskSegment.html

BibTeX

@misc{reference.wolfram_2026_disksegment, author="Wolfram Research", title="{DiskSegment}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/DiskSegment.html}", note=[Accessed: 16-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_disksegment, organization={Wolfram Research}, title={DiskSegment}, year={2015}, url={https://reference.wolfram.com/language/ref/DiskSegment.html}, note=[Accessed: 16-September-2026]}