WOLFRAM

Wolfram 语言与系统参考资料中心

DiskSegment[{x,y},r,{θ1,θ2}]

表示圆盘中从角度 θ1 到 θ2 的圆盘弓形，该圆盘以 {x,y} 为中心，半径为 r.

DiskSegment[{x,y},{rx,ry},{θ1,θ2}]

表示以轴对齐的椭圆中从角度 θ1 到 θ2 的椭圆弓形，该椭圆的半轴长度为 rx 和 ry.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
图形  
规范  
样式  
坐标  
区域  
应用  
属性和关系  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

DiskSegment

DiskSegment[{x,y},r,{θ1,θ2}]

表示圆盘中从角度 θ1 到 θ2 的圆盘弓形，该圆盘以 {x,y} 为中心，半径为 r.

DiskSegment[{x,y},{rx,ry},{θ1,θ2}]

表示以轴对齐的椭圆中从角度 θ1 到 θ2 的椭圆弓形，该椭圆的半轴长度为 rx 和 ry.

更多信息和选项

  • DiskSegment 可用作几何区域和图形基元.
  • DiskSegment 表示具有相同参数的 Disk 的实心弓形部分.
  • 角度按照从正 x 方向逆时针的弧度单位测量.
  • DiskSegment 可用在 Graphics 里.
  • 在图形中，点 {x,y} 可以是 Dynamic 表达式.
  • 图形绘制受诸如 FaceForm、EdgeForm 及颜色这样的指令影响.

范例

打开所有单元 关闭所有单元

基本范例  (5)

单位圆盘的一半：

Wolfram Language code: Graphics[DiskSegment[{0, 0}, 1, {0, Pi}]]

圆盘弓形：

Wolfram Language code: Graphics[{Orange, DiskSegment[{0, 0}, 1, {0, 3Pi / 4}]}]

椭圆圆盘的弓形：

Wolfram Language code: Graphics[{Orange, DiskSegment[{0, 0}, {3, 2}, {-Pi / 4, 3Pi / 4}]}]

不同样式的圆盘弓形：

Wolfram Language code: {Graphics[{Pink, DiskSegment[{0, 0}, 1, {0, 3Pi / 4}]}], Graphics[{EdgeForm[Thick], Pink, DiskSegment[{0, 0}, 1, {0, 3Pi / 4}]}], Graphics[{EdgeForm[Dashed], Pink, DiskSegment[{0, 0}, 1, {0, 3Pi / 4}]}], Graphics[{EdgeForm[Directive[Thick, Dashed, Blue]], Pink, DiskSegment[{0, 0}, 1, {0, 3Pi / 4}]}]}

获取圆盘弓形（一半的圆盘）的 Area：

Wolfram Language code: Area[DiskSegment[{0, 0}, 1, {0, Pi}]]

椭圆弓形的面积：

Wolfram Language code: Area[DiskSegment[{0, 0}, {Subscript[r, 1], Subscript[r, 2]}, {0, Pi / 3}]]

范围  (17)

图形  (7)

规范  (4)

指定半径：

Wolfram Language code: Graphics[{Red, DiskSegment[{0, 0}, 5, {0, Pi / 2}], Green, DiskSegment[{0, 0}, 3, {0, Pi / 2}], Blue, DiskSegment[{0, 0}, 1, {0, Pi / 2}]}]

指定中心：

Wolfram Language code: Graphics[{Red, DiskSegment[{0, 0}, 2, {0, Pi / 2}], Green, DiskSegment[{1, 1}, 2, {0, Pi / 2}], Blue, DiskSegment[{2, 2}, 2, {0, Pi / 2}]}]

指定角度：

Wolfram Language code: Graphics[DiskSegment[{0, 0}, 1, {0, Pi / 2}]]
Wolfram Language code: Graphics[DiskSegment[{0, 0}, 1, {-Pi / 3, 6Pi / 5}]]

椭圆圆盘弓形：

Wolfram Language code: Graphics[DiskSegment[{0, 0}, {2, 1}, {0, 3Pi / 2}]]

样式  (2)

颜色指令指定圆盘弓形的面颜色：

Wolfram Language code: Table[Graphics[{c, DiskSegment[{0, 0}, 1, {0, 3Pi / 2}]}], {c, {Red, Green, Blue, Yellow}}]

FaceForm 和 EdgeForm 可用于指定内部和边界的样式：

Wolfram Language code: Graphics[{FaceForm[Pink], EdgeForm[Directive[Dashed, Thick, Blue]], DiskSegment[{0, 0}, 1, {0, 3Pi / 2}]}]

圆盘弓形的边界：

Wolfram Language code: Graphics[{Yellow, EdgeForm[Directive[Thick, Blue]], DiskSegment[{0, 0}, 1, {0, 3Pi / 2}]}]

坐标  (1)

点可以是 Dynamic：

Wolfram Language code: DynamicModule[{x}, {Slider[Dynamic[x], {0, 3}], Graphics[{DiskSegment[{0, 0}, 1, {0, 3Pi / 2}], DiskSegment[Dynamic[{x, x}], 1, {0, 3Pi / 2}]}, PlotRange -> {{-1, 4}, {-1, 4}}]}]

区域  (10)

嵌入维度：

Wolfram Language code: RegionEmbeddingDimension[DiskSegment[{x, y}, r, {Subscript[θ, 1], Subscript[θ, 2]}]]

几何维度：

Wolfram Language code: RegionDimension[DiskSegment[{x, y}, r, {Subscript[θ, 1], Subscript[θ, 2]}]]

点成员检验：

Wolfram Language code: {RegionMember[DiskSegment[{0, 0}, 1, {0, 3Pi / 2}], {0, 0}], RegionMember[DiskSegment[{0, 0}, 1, {0, 3Pi / 2}], {0, 2}]}

获取点成员的条件：

Wolfram Language code: RegionMember[DiskSegment[{Subscript[x, 0], Subscript[y, 0]}, {Subscript[r, 1], Subscript[r, 2]}, {Subscript[θ, 1], Subscript[θ, 2]}], {x, y}]

面积：

Wolfram Language code: ℛ = DiskSegment[{0, 0}, 1, {0, 3Pi / 2}];
Wolfram Language code: {Area[ℛ], RegionMeasure[ℛ]}

中心：

Wolfram Language code: c = RegionCentroid[ℛ]
Wolfram Language code: Graphics[{{Pink, ℛ}, {Black, Point[c]}}]

到一个点的距离：

Wolfram Language code: ℛ = DiskSegment[{0, 0}, 1, {0, Pi}];
Wolfram Language code: {RegionDistance[ℛ, {1, 2}], RegionDistance[ℛ, {0, 0}]}

到一个点的符号距离：

Wolfram Language code: ℛ = DiskSegment[{0, 0}, 1, {0, 3Pi / 2}];
Wolfram Language code: {SignedRegionDistance[ℛ, {1, 2}], SignedRegionDistance[ℛ, {0, 0}]}

区域中的最近点：

Wolfram Language code: ℛ = DiskSegment[{0, 0}, 1, {0, 3Pi / 2}];
Wolfram Language code: RegionNearest[ℛ, {5, 6}]

最近点：

Wolfram Language code: pts = Table[{1, 2} + 5{Cos[k 2 π / 16], Sin[k 2π / 16]}, {k, 0., 15}]; nst = RegionNearest[ℛ, #]& /@ pts;
Wolfram Language code: Legended[Graphics[{{Gray, ℛ}, {Thin, Gray, Line[Transpose[{pts, nst}]]}, {Red, Point[pts]}, {Blue, Point[nst]}}], PointLegend[{Red, Blue}, {"start", "nearest"}]]

椭圆弓形是有界的：

Wolfram Language code: ℛ = DiskSegment[{0, 0}, {2, 1}, {0, 3Pi / 2}];
Wolfram Language code: BoundedRegionQ[ℛ]

获取它的范围：

Wolfram Language code: rr = RegionBounds[ℛ]
Wolfram Language code: Graphics[{StandardBlue, ℛ, {EdgeForm[{Dashed, Red}], Opacity[0.1, Yellow], Cuboid@@Transpose[rr]}}]

圆盘弓形上求积分：

Wolfram Language code: ℛ = DiskSegment[{0, 0}, {1, 2}, {0, Pi / 2}];
Wolfram Language code: Integrate[x y, {x, y}∈ℛ]

在椭圆弓形上求最优化：

Wolfram Language code: ℛ = DiskSegment[{0, 0}, {2, 1}, {0, 3Pi / 2}];
Wolfram Language code: {MinValue[{x y - x, {x, y}∈ℛ}, {x, y}], ArgMin[{x y - x, {x, y}∈ℛ}, {x, y}]}

求椭圆弓形中的方程：

Wolfram Language code: ℛ = DiskSegment[{0, 0}, {2, 3}, {0, 3Pi / 2}];
Wolfram Language code: Solve[x^2 + y^2 == 7 && x y == 1 && {x, y}∈ℛ, {x, y}]
Wolfram Language code: Show[{Graphics[{{StandardGreen, ℛ}, {Blue, Circle[{0, 0}, Sqrt[7]]}}], Plot[1 / x, {x, -3, 5}, PlotRange -> {{-3, 5}, {-3, 6}}], Graphics[{PointSize[Large], Red, Point[{x, y}] /. %}]}, Axes -> True]

应用  (5)

在圆盘弓形上绘制函数图线：

Wolfram Language code: Plot3D[Sin[x + Cos[y]], {x, y}∈DiskSegment[{0, 0}, 1, {0, Pi}]]

使用 RegionProduct 创建三维圆盘弓形立体图形：

Wolfram Language code: ℛ = RegionProduct[DiskSegment[{0, 0}, 1, {0, 3Pi / 4}], Line[{{0}, {1}}]];
Wolfram Language code: BoundaryDiscretizeRegion[ℛ]

为了显示圆盘和正多边形之间的区域差值，可以使用圆盘弓形的集合. 首先，获取弧的集合：

Wolfram Language code: n = 5; angles = ArcTan@@@CirclePoints[n]; arcs = Transpose@{angles, RotateLeft[angles]}//N

但是，一些弧不是递增的角度范围，因此在这些情况下，把 添加到第二个角度使其递增：

Wolfram Language code: arcs = If[#[[2]] < #[[1]], # + {0, 2Pi}, #]& /@ arcs

最后，可视化：

Wolfram Language code: Graphics[DiskSegment[{0, 0}, 1, #]& /@ arcs]

透镜可以建模为两个相邻的圆盘弓形. 创建高度为 ，半径为 的朝右的透镜弓形，以原点为中心：

Wolfram Language code: x = -Sqrt[r ^ 2 - h ^ 2];a = ArcTan[-x, h];
Wolfram Language code: Graphics[DiskSegment[{x, 0}, r, {-a, a}], ImageSize -> {Automatic, 75}] /. {h -> 1, r -> 2}

对于朝左的透镜，您必须转变 位置并且转变弧的方向：

Wolfram Language code: x = Sqrt[r ^ 2 - h ^ 2];a = ArcTan[x, h];
Wolfram Language code: Graphics[DiskSegment[{x, 0}, r, {Pi - a, Pi + a}], ImageSize -> {Automatic, 75}] /. {h -> 1, r -> 2}

现在创建一个函数构建给定高度和半径的圆盘弓形对，并且对一定半径范围值可视化：

Wolfram Language code: lens[h_, r1_, r2_] /; r1 ≥ h && r2 ≥ h := With[{x1 = Sqrt[r1 ^ 2 - h ^ 2], x2 = -Sqrt[r2 ^ 2 - h ^ 2]}, {DiskSegment[{x1, 0}, r1, {-1, 1} * ArcTan[x1, h] + {Pi, Pi}], DiskSegment[{x2, 0}, r2, {-1, 1} * ArcTan[-x2, h]]}]
Wolfram Language code: Manipulate[Graphics[lens[1, rl, rr], PlotRange -> 1], {{rl, 1.3, "Left Radius"}, 1, 3}, {{rr, 1.2, "Right Radius"}, 1, 3}, SaveDefinitions -> True]

通过查询位于已知体积的区域中的随机点的比率，您可以找到区域的近似测量值. 将圆盘花瓣作为示例使用：

Wolfram Language code: region = DiskSegment[{0, 0}, {1, 2}, {2, 3}];

该区域可以包含在区域 和 中，它的面积为16. 产生这个普通区域中的随机点列表：

Wolfram Language code: randompoints = RandomReal[{-2, 2}, {1000000, 2}];

求位于圆盘花瓣中的这些随机点的百分比：

Wolfram Language code: fraction = Count[RegionMember[region, randompoints], True] / 1000000

区域（圆盘花瓣）的面积应该接近比率乘以随机点分布的面积. 将该近似值与实际值比较：

Wolfram Language code: fraction * 16//N
Wolfram Language code: RegionMeasure[region]//N

属性和关系  (4)

DiskSegment 可以用 FilledCurve 表示：

Wolfram Language code: Subscript[ℛ, 1] = DiskSegment[{0, 0}, 1, {3Pi / 3, 5Pi / 3}];
Wolfram Language code: Subscript[ℛ, 2] = FilledCurve[BSplineCurve[{{-1, 0}, {-1, -1}, {0, -1}, {2 - Sqrt[3], -1}, {(1/2), -(Sqrt[3]/2)}, {-(1/4), -(Sqrt[3]/4)}, {-1, 0}}, SplineKnots -> {0, 0, 0, (1/3), (1/3), (2/3), (2/3), 1, 1, 1}, SplineWeights -> {1, 1, 2, 2, 16 - 8 Sqrt[3], 16 - 8 Sqrt[3], 16 - 8 Sqrt[3]}, SplineDegree -> 2]];
Wolfram Language code: Graphics /@ {Subscript[ℛ, 1], Subscript[ℛ, 2]}

圆盘弓形可以从 Disk 的 RegionIntersection 和另一个区域获得：

Wolfram Language code: disk = Disk[]; hs = HalfSpace[{-1, -2}, {1 / 4, 1 / 4}];
Wolfram Language code: ℛ = RegionIntersection[disk, hs]
Wolfram Language code: Graphics[{Orange, Opacity[0.3], disk, hs, {Red, ℛ}}]

ImplicitRegion 可以表示任意 DiskSegment：

Wolfram Language code: Subscript[ℛ, 1] = ImplicitRegion[x^2 + y^2 ≤ 1 && 1 - x - (1 + Sqrt[2])y ≤ 0, {x, y}];
Wolfram Language code: Subscript[ℛ, 2] = DiskSegment[{0, 0}, 1, {0, 3π / 4}];
Wolfram Language code: Reduce[{Subscript[x, 1], Subscript[x, 2]}∈Subscript[ℛ, 1]⧦{Subscript[x, 1], Subscript[x, 2]}∈Subscript[ℛ, 2], {Subscript[x, 1], Subscript[x, 2]}, Reals]

ParametricRegion 可以表示 DiskSegment：

Wolfram Language code: Subscript[ℛ, 1] = ParametricRegion[{x, y}, {{x, -(1/Sqrt[2]), 1}, {y, -1 + x + Sqrt[2] Sqrt[1 - 2 x + x^2], Sqrt[1 - x^2]}}];
Wolfram Language code: Subscript[ℛ, 2] = DiskSegment[{0, 0}, 1, {0, 3π / 4}];
Wolfram Language code: Reduce[{Subscript[x, 1], Subscript[x, 2]}∈Subscript[ℛ, 1]⧦{Subscript[x, 1], Subscript[x, 2]}∈Subscript[ℛ, 2], {Subscript[x, 1], Subscript[x, 2]}, Reals]
Wolfram Language code: {RegionPlot[Subscript[ℛ, 1]], Graphics[{LightBlue, Subscript[ℛ, 2]}, Frame -> True, AspectRatio -> 1]}

巧妙范例  (3)

随机圆盘弓形集合：

Wolfram Language code: Graphics[Table[{EdgeForm[Black], Hue[RandomReal[]], DiskSegment[RandomReal[4, {2}], RandomReal[1], RandomReal[2Pi] + {0, RandomReal[2Pi]}]}, {40}]]

圆盘弓形组成的系列：

Wolfram Language code: Graphics[Table[{Hue[t / 15, 1, .9, .3], DiskSegment[{Cos[2Pi t / 15], Sin[2Pi t / 15]}, 1, {2Pi t / 15, 2Pi t / 15 + Pi}]}, {t, 15}]]

数字花瓣：

Wolfram Language code: Graphics[Table[{EdgeForm[Opacity[.6]], Hue[(-11 + q + 19 r) / 72], DiskSegment[(8 - r){Cos[2Pi q / 20], Sin[2Pi q / 20]}, (8 - r) / 3, {2Pi q / 20, 2Pi q / 20 + Pi}]}, {r, 6}, {q, 20}]]
Wolfram Research (2015)，DiskSegment，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DiskSegment.html.

文本

Wolfram Research (2015)，DiskSegment，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DiskSegment.html.

CMS

Wolfram 语言. 2015. "DiskSegment." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/DiskSegment.html.

APA

Wolfram 语言. (2015). DiskSegment. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/DiskSegment.html 年

BibTeX

@misc{reference.wolfram_2026_disksegment, author="Wolfram Research", title="{DiskSegment}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/DiskSegment.html}", note=[Accessed: 09-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_disksegment, organization={Wolfram Research}, title={DiskSegment}, year={2015}, url={https://reference.wolfram.com/language/ref/DiskSegment.html}, note=[Accessed: 09-September-2026]}