WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ExternalBundle[{"name1"obj1,"name2"obj2,…}]

名前付きのURL，関数等として外部的に配備されるリソースのバンドルを表す．

ExternalBundle[{name11{name1…,…},…}]

リソースのネストされたバンドルを表す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

ExternalBundle

ExternalBundle[{"name1"obj1,"name2"obj2,…}]

名前付きのURL，関数等として外部的に配備されるリソースのバンドルを表す．

ExternalBundle[{name11{name1…,…},…}]

リソースのネストされたバンドルを表す．

詳細

  • ExternalBundleは，CloudDeploy中，あるいはWebの配備先についてはEmbedCode中で，事実上，クラウド中のディレクトリあるいはディレクトリの階層のコンテンツを定義する．
  • ExternalBundleは，言語についてはEmbedCode内で，名前付きの外部関数のバンドルを定義する．

例題

すべて開く すべて閉じる

例  (1)

2つのAPIのバンドルを配備する：

Wolfram Language code: bundle = CloudDeploy[ExternalBundle[{"factor" -> APIFunction["n" -> "Integer", FactorInteger[#n]&], "primeq" -> APIFunction["n" -> "Integer", PrimeQ[#n]&]}]]

バンドルは式として読み戻すことができる：

Wolfram Language code: contents = Get[bundle]

配備したAPIの一つを使う：

Wolfram Language code: URLExecute[Lookup[First[contents], "factor"], {"n" -> 187}]

スコープ  (2)

サブディレクトリを作って，ネストした規則のリストを持つバンドルを作る：

Wolfram Language code: bundle = CloudDeploy[ ExternalBundle[ { "api" -> {"factor" -> APIFunction["n" -> "Integer", FactorInteger[#n]&], "primeq" -> APIFunction["n" -> "Integer", PrimeQ[#n]&]}, "form" -> {"factor" -> FormPage["n" -> "Integer", FactorInteger[#n]&], "primeq" -> FormPage["n" -> "Integer", PrimeQ[#n]&]} }]]

バンドルのコンテンツはネストしている：

Wolfram Language code: Get[bundle]

バンドルをWebに埋め込む：

Wolfram Language code: bundle = CloudDeploy[ExternalBundle[{"square" -> APIFunction[{"s" -> "Integer"}, #x^2&], "root" -> APIFunction[{"r" -> "Integer"}, Sqrt[#x]&]}]] EmbedCode[bundle]

特性と関係  (2)

同様の効果は，ディレクトリ内で個々のオブジェクトを配置および管理することによって達成できる．プロジェクト用ディレクトリを作成する：

Wolfram Language code: dir = CreateDirectory[CloudObject["api-bundle"]]

ディレクトリ内のAPIを一つずつ配備する：

Wolfram Language code: CloudDeploy[APIFunction["n" -> "Integer", FactorInteger[#n]&], CloudObject["factor", dir]] CloudDeploy[APIFunction["n" -> "Integer", PrimeQ[#n]&], CloudObject["primeq", dir]]

プロジェクトディレクトリのコンテンツは配備されたAPIである：

Wolfram Language code: CloudObjects[dir]

このアプローチとの主な相違点は，ExternalBundleの内部にあるオブジェクトが一段階で配備される点にある．

URLDispatcherを用いて同様の効果を得ることもできる：

Wolfram Language code: dispatch = CloudDeploy[URLDispatcher[{ "/factor" :> APIFunction["n" -> "Integer", FactorInteger[#n]&], "/primeq" :> APIFunction["n" -> "Integer", PrimeQ[#n]&] }]]

ディスパッチャは，当該オブジェクトのURLの後に続くURLパターンに基づいて要求に応答する単一のオブジェクトである．因数分解を行うAPIFunctionを有効にするためには，そのURLの後に"/factor"を付加してディスパッチャを呼び出す：

Wolfram Language code: URLExecute[CloudObject["factor", dispatch], {"n" -> 187}]
Wolfram Research (2014), ExternalBundle, Wolfram言語関数， https://reference.wolfram.com/language/ref/ExternalBundle.html.

テキスト

Wolfram Research (2014), ExternalBundle, Wolfram言語関数， https://reference.wolfram.com/language/ref/ExternalBundle.html.

CMS

Wolfram Language. 2014. "ExternalBundle." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/ExternalBundle.html.

APA

Wolfram Language. (2014). ExternalBundle. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ExternalBundle.html

BibTeX

@misc{reference.wolfram_2026_externalbundle, author="Wolfram Research", title="{ExternalBundle}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/ExternalBundle.html}", note=[Accessed: 13-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_externalbundle, organization={Wolfram Research}, title={ExternalBundle}, year={2014}, url={https://reference.wolfram.com/language/ref/ExternalBundle.html}, note=[Accessed: 13-September-2026]}