WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

FirstCase[{e1,e2,…},pattern]

pattern にマッチする最初の eiを返す．pattern にマッチする要素が見付からない場合はMissing["NotFound"]を返す．

FirstCase[{e1,…},patternrhs]

pattern にマッチする最初の eiに対応する rhs の値を返す．

FirstCase[expr,pattern,default]

pattern にマッチする要素が見付からない場合に default を返す．

FirstCase[expr,pattern,default,levelspec]

levelspec で指定されたレベルに現れるオブジェクトのみを求める．

FirstCase[pattern]

式に適用可能なFirstCaseの演算子形を表す．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
Heads  
特性と関係  
考えられる問題  
関連項目
関連するガイド
履歴
引用書式

FirstCase

FirstCase[{e1,e2,…},pattern]

pattern にマッチする最初の eiを返す．pattern にマッチする要素が見付からない場合はMissing["NotFound"]を返す．

FirstCase[{e1,…},patternrhs]

pattern にマッチする最初の eiに対応する rhs の値を返す．

FirstCase[expr,pattern,default]

pattern にマッチする要素が見付からない場合に default を返す．

FirstCase[expr,pattern,default,levelspec]

levelspec で指定されたレベルに現れるオブジェクトのみを求める．

FirstCase[pattern]

式に適用可能なFirstCaseの演算子形を表す．

詳細とオプション

  • FirstCaseの第1引数は，頭部Listを持たなくてもよく，連想でもよい．
  • FirstCase[expr,pattern:>rhs]は，パターンが見付かった場合にのみ rhs を評価する．
  • FirstCase[{e1,e2,…},pattern,default]では，ei がどれもマッチしない場合にのみ default が評価される．
  • FirstCase[pattern][expr]はFirstCase[expr,pattern]に等しい．
  • FirstCaseは，標準的なレベル指定を使う．
  • nレベル 1 からレベル n まで
    Infinityレベル 1 からInfinityまで
    {n}レベル n のみ
    {n1,n2}レベル n1 からレベル n2まで
  • FirstCaseにおける levelspec のデフォルト値は{1}である．
  • 正のレベル n は，n 個の指標で指定される expr のすべての部分からなる．
  • 負のレベル-n は，expr の深さ n のすべての部分からなる．
  • レベル-1は，数，記号，下位区分を持たないその他のオブジェクトからなる．
  • レベル0は式全体に相当する．
  • オプション設定をHeads->Trueとすると，FirstCaseは式の頭部およびその部分を見る．
  • FirstCaseは 深さ優先の順序で，根の前に葉を訪れ，expr の部分を横断する．

例題

すべて開く すべて閉じる

例  (3)

整数にマッチするリスト中の最初の要素を求める：

Wolfram Language code: FirstCase[{a, b, c, 5, 6, 7}, _Integer]

整数ではない最初の要素を求める：

Wolfram Language code: FirstCase[{1, 1, f[a], 2, 3, y, f[8], 9, f[10]}, Except[_Integer]]

f[x_]にマッチした最初のものの中からxを返す：

Wolfram Language code: FirstCase[{1, 1, f[a], 2, 3, y, f[8], 9, f[10]}, f[x_] :> x]

Associationから要素を拾う：

Wolfram Language code: FirstCase[<|1 -> "a", 2 -> "b", 3 -> c, 4 -> d|>, _Symbol]

スコープ  (7)

Casesの演算子形を使う：

Wolfram Language code: FirstCase[_Integer]@{f[a], 2, 3, a}

一次のペアを求める：

Wolfram Language code: FirstCase[{{1, 2}, {2}, {3, 4, 1}, {5, 4}, {3, 3}}, {_, _}]

その合計を求める：

Wolfram Language code: FirstCase[{{1, 2}, {2}, {3, 4, 1}, {5, 4}, {3, 3}}, {a_, b_} -> a + b]

最初の非零要素を拾う：

Wolfram Language code: FirstCase[{1, 0, 2, 0, 3, 5, 6, 7, 0, 0, 0}, Except[0]]

:>を使って，明示的な要素が求まってから評価する：

Wolfram Language code: FirstCase[{f[{}], f[{a}], g[{a, b}], f[{a, b, c}]}, g[x_] :> Length[x]]

カスタムのデフォルト値を指定する：

Wolfram Language code: FirstCase[{1, 2, 3}, _ ? StringQ, "NoStrings"]

レベル指定を使って行列の要素を調べる：

Wolfram Language code: FirstCase[{{1, 4, a, 0}, {b, 3, 2, 2}, {c, c, 5, 5}}, _Symbol, Missing[], {2}]

ネストした連想から要素を拾う：

Wolfram Language code: FirstCase[<|1 -> 5, 2 -> <|3 -> 1, a -> b|>|>, _Symbol, Missing[], Infinity]

オプション  (1)

Heads  (1)

式の要素から記号を求める：

Wolfram Language code: FirstCase[{5, a, π}, _Symbol]

式の頭部も検索に含める：

Wolfram Language code: FirstCase[{a, 5, π}, _Symbol, Heads -> True]

特性と関係  (4)

デフォルト値は必要な場合にしか評価されない：

Wolfram Language code: FirstCase[{None, "A", "B"}, _String, Abort[]]
Wolfram Language code: FirstCase[{None, None, None}, _String, Abort[]]

FirstCaseは最初にマッチしたものだけを返す：

Wolfram Language code: FirstCase[{None, "A", "B"}, "A" | "B"]

Casesはマッチしたものをすべて返す：

Wolfram Language code: Cases[{None, "A", "B"}, "A" | "B"]

FirstCaseは，CasesとReplaceの組合せで実装することができる：

Wolfram Language code: FirstCase[{1, 2, a, Sqrt[2], Pi, E}, _Symbol] FirstCase[{1, 2, a, Sqrt[2], Pi, E}, _StringQ]
Wolfram Language code: Replace[Cases[{1, 2, a, Sqrt[2], Pi, E}, _Symbol], {{} :> Missing["NotFound"], l_ :> First[l]}] Replace[Cases[{1, 2, a, Sqrt[2], Pi, E}, _StringQ], {{} :> Missing["NotFound"], l_ :> First[l]}]

FirstCaseは，関数の代りにパターンを使う点を除いて，SelectFirstに似ている：

Wolfram Language code: list = RandomInteger[{3, 7}, {10, 2}]

要素の合計が10より小さい最初のリストを選ぶ：

Wolfram Language code: smallQ = Total[#] < 10&;
Wolfram Language code: FirstCase[list, x_ /; smallQ[x]]

SelectFirstを使って同じ結果を得る：

Wolfram Language code: SelectFirst[list, smallQ]

考えられる問題  (1)

規則はマッチする要素をその右辺に変換する：

Wolfram Language code: FirstCase[{1, b -> Automatic, c -> 3}, _ -> Automatic]

HoldPatternを使って規則そのものをパターンとして扱う：

Wolfram Language code: FirstCase[{1, b -> Automatic, c -> 3}, HoldPattern[_ -> Automatic]]
Wolfram Research (2014), FirstCase, Wolfram言語関数， https://reference.wolfram.com/language/ref/FirstCase.html.

テキスト

Wolfram Research (2014), FirstCase, Wolfram言語関数， https://reference.wolfram.com/language/ref/FirstCase.html.

CMS

Wolfram Language. 2014. "FirstCase." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/FirstCase.html.

APA

Wolfram Language. (2014). FirstCase. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/FirstCase.html

BibTeX

@misc{reference.wolfram_2026_firstcase, author="Wolfram Research", title="{FirstCase}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/FirstCase.html}", note=[Accessed: 07-October-2026]}

BibLaTeX

@online{reference.wolfram_2026_firstcase, organization={Wolfram Research}, title={FirstCase}, year={2014}, url={https://reference.wolfram.com/language/ref/FirstCase.html}, note=[Accessed: 07-October-2026]}