WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

GroupMultiplicationTable[group]

group の乗積表を配列として与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

GroupMultiplicationTable

GroupMultiplicationTable[group]

group の乗積表を配列として与える．

詳細

  • 位数の n の group について，GroupMultiplicationTableは元 matijが群内の元 i と元 j の乗算の結果を与えるような整数の n×n 行列 mat を返す．位置 i, j, および matijは関数GroupElementPositionで計算される．

例題

すべて開く すべて閉じる

例  (1)

これは位数8の群である：

Wolfram Language code: GroupOrder[group = PermutationGroup[{Cycles[{{1, 3}, {2, 4}}], Cycles[{{1, 2}}]}]]

以下はGroupElementPositionで番号付けされた元のすべてのペアの乗算である：

Wolfram Language code: TableForm[GroupMultiplicationTable[group], TableHeadings -> Automatic]

この群の8つの置換すべてを生成する：

Wolfram Language code: list = GroupElements[group]

リスト中の置換5と置換2の積は置換7である：

Wolfram Language code: PermutationProduct[list[[5]], list[[2]]] === list[[7]]

スコープ  (1)

任意の有限群について乗積表が構築できる：

Wolfram Language code: GroupMultiplicationTable[SymmetricGroup[4]]

アプリケーション  (1)

置換群代数の基本の元は群の置換の線形結合である，乗積表を使うことで，置換の積を計算し直すことを避けることが可能である．群代数の元を係数のリストとして表示することでそれらの乗算が可能になる：

Wolfram Language code: group = PermutationGroup[{Cycles[{{1, 2}}], Cycles[{{1, 3}, {2, 4}}]}]
Wolfram Language code: (table = GroupMultiplicationTable[group])//MatrixForm
Wolfram Language code: product[list1_, list2_] := Coefficient[list1.Map[X, table, {2}].list2, Array[X, 8]]
Wolfram Language code: g1 = {0, 0, 3, 1, -2, 1 / 2, 0, 6}; g2 = {1, 0, -2, -2, 1, 4, 1, -2};
Wolfram Language code: product[g1, g2]

これはベキ零元である：

Wolfram Language code: g = {0, 0, 0, 0, -1, -1, 1, 1}; product[g, g]

これはベキ等元である：

Wolfram Language code: g = {1, 1, 1, 1, 1, 1, 1, 1} / 8;
Wolfram Language code: product[g, g] === g

特性と関係  (7)

群の乗積表のすべての行とすべての列にすべての置換が一回ずつ，異なる順序で含まれている．ゆえに，表はラテン方陣である（結合性が保証されないため，すべてのラテン方陣が群に対応する訳ではない）：

Wolfram Language code: GroupMultiplicationTable[DihedralGroup[4]] // MatrixForm

自明な群の乗積表：

Wolfram Language code: GroupMultiplicationTable[PermutationGroup[{}]]

ケーリーの定理にはすべての有限群は何らかの置換の対称群の部分群と同型であるとある．ゆえに，乗積表はすべて（置換に再度番号付けをした後の）対称群の表の一部である：

これは の部分群の乗積表である：

Wolfram Language code: table = GroupMultiplicationTable[PermutationGroup[{Cycles[{{1, 3}, {2, 4}}], Cycles[{{1, 2}}]}]]

ゆえに，これは の表の一部として抽出することができる：

Wolfram Language code: S4table = GroupMultiplicationTable[SymmetricGroup[4]];
Wolfram Language code: sublist = {1, 2, 7, 8, 17, 18, 23, 24};
Wolfram Language code: table === (S4table[[sublist, sublist]] /. Thread[sublist -> Range[8]])

群の乗積表が転置のもとに対称であるときかつそのときに限りその群はアーベル群である．次数3の対称群を例とする：

Wolfram Language code: MatrixForm[tableS3 = GroupMultiplicationTable[SymmetricGroup[3]]]

群 はアーベル群ではない：

Wolfram Language code: tableS3 == Transpose[tableS3]

群のすべての元が対合のとき，その群はアーベル群である．つまり，乗積表の対角に1のみが並ぶ場合，その群は対称群である：

Wolfram Language code: group = PermutationGroup[{Cycles[{{1, 2}, {3, 4}}], Cycles[{{1, 3}, {2, 4}}]}];
Wolfram Language code: elems = GroupElements[group]
Wolfram Language code: MatrixForm[GroupMultiplicationTable[group]]

乗積表はPermutationProductとGroupElementPositionを直接使っても得ることができる：

Wolfram Language code: group = PermutationGroup[{Cycles[{{1, 2}}], Cycles[{{1, 3}, {2, 4}}]}]; elems = GroupElements[group];
Wolfram Language code: Map[GroupElementPosition[group, #]&, Outer[PermutationProduct, elems, elems]]
Wolfram Language code: % === GroupMultiplicationTable[group]

2つの群が元の並べ替えを法とする同じ群乗積表を持つとき，両者は抽象群として同型である：

Wolfram Language code: group1 = PermutationGroup[{Cycles[{{1, 2}}], Cycles[{{3, 4}}]}]
Wolfram Language code: GroupMultiplicationTable[group1]//TableForm
Wolfram Language code: group2 = PermutationGroup[{Cycles[{{1, 2}, {3, 4}}], Cycles[{{1, 3}, {2, 4}}]}]
Wolfram Language code: GroupMultiplicationTable[group2]//TableForm

しかし，これら2つの群は置換群としては同型ではない．なぜなら，両者の置換が異なる巡回構造を持つからである：

Wolfram Language code: GroupElements[group1]
Wolfram Language code: GroupElements[group2]

考えられる問題  (1)

乗積表は最初の元が垂直軸で，第2元が水平軸で表現される「配列の指数付け」に従う．両者が逆になる「デカルト指標付け」に従うのではない：

Wolfram Language code: group = SymmetricGroup[3];
Wolfram Language code: elems = GroupElements[group]
Wolfram Language code: MatrixForm[table = GroupMultiplicationTable[group]]
Wolfram Language code: Map[elems[[#]]&, table, {2}] === Table[PermutationProduct[elems[[i]], elems[[j]]], {i, 6}, {j, 6}]

おもしろい例題  (1)

対称群 の乗積表の行列プロット：

Wolfram Language code: ArrayPlot[GroupMultiplicationTable[SymmetricGroup[5]], ImageSize -> 400]
Wolfram Research (2010), GroupMultiplicationTable, Wolfram言語関数， https://reference.wolfram.com/language/ref/GroupMultiplicationTable.html.

テキスト

Wolfram Research (2010), GroupMultiplicationTable, Wolfram言語関数， https://reference.wolfram.com/language/ref/GroupMultiplicationTable.html.

CMS

Wolfram Language. 2010. "GroupMultiplicationTable." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/GroupMultiplicationTable.html.

APA

Wolfram Language. (2010). GroupMultiplicationTable. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/GroupMultiplicationTable.html

BibTeX

@misc{reference.wolfram_2026_groupmultiplicationtable, author="Wolfram Research", title="{GroupMultiplicationTable}", year="2010", howpublished="\url{https://reference.wolfram.com/language/ref/GroupMultiplicationTable.html}", note=[Accessed: 26-July-2026]}

BibLaTeX

@online{reference.wolfram_2026_groupmultiplicationtable, organization={Wolfram Research}, title={GroupMultiplicationTable}, year={2010}, url={https://reference.wolfram.com/language/ref/GroupMultiplicationTable.html}, note=[Accessed: 26-July-2026]}