WOLFRAM

Wolfram 语言与系统参考资料中心

ImplicitD[eqn,y,x]

给出偏导数 ，假定变量 y 表示由方程 eqn 定义的隐函数.

ImplicitD[f,eqn,y,x]

给出偏导数 ，假定变量 y 表示由方程 eqn 定义的隐函数.

ImplicitD[f,{eqn1,…,eqnk},{y1,…,yk},x]

给出偏导数 ，假定变量 y1,…,yk 表示由方程组 eqn1∧…∧eqnk 定义的隐函数.

ImplicitD[f,eqns,ys,{x,n}]

给出多重导数 .

ImplicitD[f,eqns,ys,x1,x2,…]

给出偏导数 .

ImplicitD[f,eqns,ys,{x1,n1},{x2,n2},…]

给出多重偏导数 .

ImplicitD[f,eqns,ys,{{x1,x2,…}}]

对于标量 f 给出向量导数 .

ImplicitD[f,eqns,ys,{array}]

给出一个数组导数.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
属性和关系  
可能存在的问题  
参见
相关指南
历史
按以下格式引用：

ImplicitD

ImplicitD[eqn,y,x]

给出偏导数 ，假定变量 y 表示由方程 eqn 定义的隐函数.

ImplicitD[f,eqn,y,x]

给出偏导数 ，假定变量 y 表示由方程 eqn 定义的隐函数.

ImplicitD[f,{eqn1,…,eqnk},{y1,…,yk},x]

给出偏导数 ，假定变量 y1,…,yk 表示由方程组 eqn1∧…∧eqnk 定义的隐函数.

ImplicitD[f,eqns,ys,{x,n}]

给出多重导数 .

ImplicitD[f,eqns,ys,x1,x2,…]

给出偏导数 .

ImplicitD[f,eqns,ys,{x1,n1},{x2,n2},…]

给出多重偏导数 .

ImplicitD[f,eqns,ys,{{x1,x2,…}}]

对于标量 f 给出向量导数 .

ImplicitD[f,eqns,ys,{array}]

给出一个数组导数.

更多信息

  • ImplicitD 通常用于计算隐式定义函数的导数.
  • 如果变量 x 和 y 满足方程 ，则在下面阐述的某些条件下，y 可以被局部视为 x 的函数，并且该函数的导数可以用 g 的偏导数表示.
  • 如果函数 是连续可微的， 和 ，则隐函数定理保证在 的邻域中存在唯一函数 ，使得 且 . 被称为由方程 定义的隐函数. 因此，.
  • ImplicitD[f,g==0,y,…] 假定 是连续可微的并且要求 .
  • 类似地，如果 个变量 和 满足由 个方程组成的方程组 ，则在下述特定条件下， 可以局部视为 的函数，这些函数的导数可以用 的偏导数表示.
  • 如果函数 连续可微， 且雅可比矩阵 可逆，则隐函数定理保证在 的邻域存在唯一函数 使得 且 . 函数 被称为由方程 定义的因函数. 因此，.
  • ImplicitD[f,{g1==0,…,gk==0},{y1,…,yk},…] 假定 是连续可微的，并且要求雅可比矩阵 可逆.
  • 对于列表，ImplicitD[{f1,f2,…},…] 递归地等价于 {ImplicitD[f1,…],ImplicitD[f2,…],…}.
  • ImplicitD[eqns,ys,…] 等价于 ImplicitD[ys,eqns,ys,…]，其中 eqns 是方程或方程的列表.
  • ImplicitD[f,eqns,ys,{array}] 有效地将 ImplicitD 遍历 array 的各个元素.
  • 所有表达式，只要不显式依赖于微分变量或表示隐函数的变量，都被认为偏导数为零.

范例

打开所有单元 关闭所有单元

基本范例  (5)

关于 的导数，其中 受方程 约束：

Wolfram Language code: ImplicitD[2y, x ^ 2 + y ^ 2 == 1, y, x]

的二阶导数，假定 ：

Wolfram Language code: ImplicitD[Log[x y], y ^ 2 - x Sin[y] == 0, y, {x, 2}]

涉及两个隐定义函数的导数：

Wolfram Language code: ImplicitD[E ^ (x + y + z), {x ^ 2 + y ^ 3 + z ^ 4 == 5, Log[x y] == z}, {y, z}, x]

关于 和 的导数：

Wolfram Language code: ImplicitD[Sin[y], y ^ t == x, y, x, t]

涉及符号函数 和 的导数：

Wolfram Language code: ImplicitD[f[x, y], g[x, y] == 0, y, x]

范围  (9)

隐式定义函数的导数：

Wolfram Language code: ImplicitD[y ^ 3 - 3x y == 2, y, x]

涉及由多项式方程定义的隐函数的表达式的导数：

Wolfram Language code: ImplicitD[Cos[x y], y ^ 3 - 2x == 0, y, x]

涉及由超越方程定义的隐函数的表达式的导数：

Wolfram Language code: ImplicitD[Exp[y ^ 2], Sin[x y] - Log[x + y] == 0, y, x]

涉及由一对方程定义的两个隐函数的表达式的导数：

Wolfram Language code: ImplicitD[Tan[x + y + z], {x == y z, Sin[y + z] == x ^ 2}, {y, z}, x]

涉及隐函数的表达式的三阶导数：

Wolfram Language code: ImplicitD[y ^ 2, 3 ^ y == x ^ 3, y, {x, 3}]

包含隐函数的表达式的混合偏导 ：

Wolfram Language code: ImplicitD[y ^ 3, Log[t + y] == x y, y, x, t]

混合偏导 ：

Wolfram Language code: ImplicitD[y ^ 3, Log[t + y] == x y, y, {x, 2}, {t, 3}]

涉及隐函数的表达式的梯度：

Wolfram Language code: ImplicitD[Gamma[y ^ 2], t y ^ 3 == Sin[x y], y, {{t, x}}]

涉及隐函数的表达式的雅可比行列式：

Wolfram Language code: ImplicitD[{y ^ 2, Sin[x y]}, Log[x + y] == t ^ 2 y ^ 3, y, {{t, x}}]//MatrixForm

定义隐函数 的方程需要有一个关于 的非零导数：

Wolfram Language code: ImplicitD[x ^ 2 == 1, y, x]

定义隐函数 的方程需要有一个关于 的逆雅可比式：

Wolfram Language code: ImplicitD[y + z, {x - y z == 0, x ^ 2 - 2 y z == 0}, {y, z}, x]

应用  (3)

计算曲线的切线斜率：

Wolfram Language code: curve = x ^ 3 + y ^ 3 - 4x y == 0

切线的斜率等于 对 的导数：

Wolfram Language code: slope = ImplicitD[curve, y, x]

在曲线上的六个点处显示切线：

Wolfram Language code: points = FindInstance[curve && -3 < x < 3 && -3 < y < 3, {x, y}, Reals, 6]
Wolfram Language code: Show[ContourPlot@@{curve, {x, -3, 3}, {y, -3, 3}}, Graphics[{{Red, PointSize[Medium], Point[{x, y}] /. points}, {Orange, Dashed, InfiniteLine[{x, y}, {1, slope}] /. points}}]]

求曲面的切平面：

Wolfram Language code: surface = x ^ 2 + 2y ^ 2 + 3z ^ 2 == 1

计算 关于 和 的梯度：

Wolfram Language code: {zx, zy} = ImplicitD[surface, z, {{x, y}}]

在曲面上的三个点处显示切平面：

Wolfram Language code: points = FindInstance[surface && z != 0, {x, y, z}, Reals, 3]
Wolfram Language code: Show[ContourPlot3D@@{surface, {x, -1.2, 1.2}, {y, -1.2, 1.2}, {z, -1.2, 1.2}, Mesh -> None}, Graphics3D[{{Red, PointSize[Medium], Point[{x, y, z}] /. points}, {Orange, Opacity[0.5], InfinitePlane[{x, y, z}, {{1, 0, zx}, {0, 1, zy}}] /. points}}]]

验证微分方程的隐式解：

Wolfram Language code: DSolve[y'[x] == -y[x] ^ 2(2 x + y[x]), y[x], x]

解的导数等于微分方程的右边：

Wolfram Language code: ImplicitD[%[[1]], y[x], x]//Simplify

属性和关系  (4)

方程 在 的任何点的邻域中定义一个隐函数：

Wolfram Language code: g = (x^2 + y^2) (x (2 + x) + y^2) - 8 x y^2;
Wolfram Language code: except = SolveValues[D[g, y] == 0 && g == 0, {x, y}]
Wolfram Language code: ContourPlot[g == 0, {x, -2.1, 1.2}, {y, -1.8, 1.8}, AspectRatio -> Automatic, PlotPoints -> 100, Epilog -> {Red, PointSize[Large], Point[except]}]

隐函数的导数等于 ：

Wolfram Language code: ImplicitD[g == 0, y, x] == -D[g, x] / D[g, y]//Simplify

导数在 处具有奇点：

Wolfram Language code: ImplicitD[g == 0, y, x] /. (Thread[{x, y} -> #]& /@ except)//Quiet

使用 D 计算隐函数的导数：

Wolfram Language code: eqn = y[x] ^ 2 + 3y[x] == x ^ 2 + 1;
Wolfram Language code: Solve[D[eqn, x], y'[x]]

与使用 ImplicitD 获得的结果进行比较：

Wolfram Language code: ImplicitD[y ^ 2 + 3y == x ^ 2 + 1, y, x]

使用 SolveValues 求 的显式解：

Wolfram Language code: g = y ^ 3 - x y ^ 2 + 2x ^ 2y - x + 1;
Wolfram Language code: y1 = SolveValues[g == 0, y][[1]]

将解的导数与使用 ImplicitD 获得的结果进行比较：

Wolfram Language code: (ImplicitD[g == 0, y, x] /. y -> y1) == D[y1, x]//Simplify

Root[g,k] 表示 g[y] 的解：

Wolfram Language code: r = Root[# ^ 5 - x # + 1&, 1]

比较 的导数和使用 ImplicitD 得到的结果：

Wolfram Language code: (ImplicitD[r[[1]][y] == 0, y, x] /. y -> r) == D[r, x]

可能存在的问题  (1)

ImplicitD[f,{y,g},…] 要求 ：

Wolfram Language code: g = Sqrt[y ^ 2] - y - 2x ^ 2 - x + 1;
Wolfram Language code: df = ImplicitD[y ^ 3, g == 0, y, x]

当 时，结果是有效的，在其他情况下是奇异的：

Wolfram Language code: Reduce[D[g, y] != 0, y, Reals]
Wolfram Language code: Refine[df, y < 0]
Wolfram Language code: Refine[df, y >= 0]
Wolfram Research (2022)，ImplicitD，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ImplicitD.html.

文本

Wolfram Research (2022)，ImplicitD，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ImplicitD.html.

CMS

Wolfram 语言. 2022. "ImplicitD." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/ImplicitD.html.

APA

Wolfram 语言. (2022). ImplicitD. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/ImplicitD.html 年

BibTeX

@misc{reference.wolfram_2026_implicitd, author="Wolfram Research", title="{ImplicitD}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/ImplicitD.html}", note=[Accessed: 13-July-2026]}

BibLaTeX

@online{reference.wolfram_2026_implicitd, organization={Wolfram Research}, title={ImplicitD}, year={2022}, url={https://reference.wolfram.com/language/ref/ImplicitD.html}, note=[Accessed: 13-July-2026]}