WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

MissingDataMethod

TimeSeries，EventSeriesおよび他の関数のオプションで，欠測データをどのように処理するかを制御する．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
特性と関係  
考えられる問題  
関連項目
履歴
引用書式

MissingDataMethod

MissingDataMethod

TimeSeries，EventSeriesおよび他の関数のオプションで，欠測データをどのように処理するかを制御する．

詳細

  • 欠測データメソッドは，通常，欠けている値を補うメソッドを提供する．
  • よく使われる設定
  • None処理しない
    Automatic自動的にメソッドを選ぶ
    "name"指定されたメソッドを使う
    {"name",opt1->val1,…}指定されたメソッドを特定のオプションで使う
  • "name"の可能な設定には"Interpolation"と"Constant"がある．
  • 個々の関数に使われる欠測データメソッドは，それぞれの関数ページに記されている．

例題

すべて開く すべて閉じる

例  (2)

線形補間を使って欠測データ値を補う：

Wolfram Language code: data = {-1, -2, -1, 0, Missing[], 2, 1, 2, 1, 0, 1, 2, 1, 2, 3};
Wolfram Language code: ListLinePlot[data]

TimeSeriesを使い，補完によって完全なデータを作る：

Wolfram Language code: TimeSeries[data, {1}, MissingDataMethod -> {"Interpolation", InterpolationOrder -> 1}];
Wolfram Language code: ListLinePlot[%]

使用可能なデータの平均値で欠測データの値を補う：

Wolfram Language code: ts = TimeSeries[{-1, 0, -1, 0, Missing[], Missing[], Missing[], 2, 1, 3, 1}]
Wolfram Language code: ListLinePlot[ts]
Wolfram Language code: TimeSeries[ts, MissingDataMethod -> {"Constant", Echo@Mean[ts]}]
Wolfram Language code: ListLinePlot[%]

スコープ  (3)

欠測値を補うためにカスタムの補間を使う：

Wolfram Language code: missd = {2, 1, 3, Missing[], 2, 1, 2, Missing[], 6, 2, 5};
Wolfram Language code: ts = TimeSeries[missd, Automatic, MissingDataMethod -> {"Interpolation", Method -> "Spline", InterpolationOrder -> 3}]
Wolfram Language code: ListLinePlot[ts]

左側の値を保持することで欠測値を補う：

Wolfram Language code: data = {0, -2, -1, 0, Missing[], 2, 1, 2, Missing[], 0, 1, Missing[], 3, 2, 3};
Wolfram Language code: tsL = TimeSeries[data, {1}, MissingDataMethod -> "PreviousElement"]

右側の値を保持することで欠測値を補う：

Wolfram Language code: tsR = TimeSeries[data, {1}, MissingDataMethod -> "NextElement"]

時系列を比較する：

Wolfram Language code: {ListPlot[{data, tsL}, Joined -> {False, True}], ListPlot[{data, tsR}, Joined -> {False, True}]}

欠測値を任意の定数で補う：

Wolfram Language code: data = {-1, -2, -1, 0, Missing[], 2, 1, 2, 1, 0, Missing[], 2, 1, 2, 3};
Wolfram Language code: ts = TimeSeries[data, MissingDataMethod -> {"Constant", 3}]
Wolfram Language code: {ListLinePlot[data, DataRange -> {0, 14}], ListLinePlot[ts, Epilog -> {Red, PointSize[Medium], Point[{4, 3}], Point[{10, 3}]}]}

特性と関係  (4)

Automaticと設定するとResamplingMethodの設定が使われる：

Wolfram Language code: missd = {2, 1, 3, Missing[], 2, 1, 2, Missing[], 6, 2, 5};
Wolfram Language code: p1 = ListPlot[missd, DataRange -> {0, Length[missd] - 1}, PlotStyle -> {StandardGray, PointSize[Large]}]
Wolfram Language code: ts1 = TimeSeries[missd, {0}, MissingDataMethod -> Automatic]
Wolfram Language code: Show[Plot[ts1[t], {t, 0, 10}, PlotRange -> {{0, 11}, All}], p1]

欠測データを処理するメソッドがResamplingMethodと同じである必要はない：

Wolfram Language code: ts2 = TimeSeries[missd, {0}, MissingDataMethod -> {"Interpolation", InterpolationOrder -> 0}, ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}]
Wolfram Language code: Show[Plot[ts2[t], {t, 0, 10}, PlotRange -> All], p1]

EventSeriesのデフォルトの欠測データの処理メソッドは，次数0の補間である：

Wolfram Language code: data = {-1, -2, -1, 4, Missing[], 2, 1, 2, 1};
Wolfram Language code: es = EventSeries[data, MissingDataMethod -> Automatic]
Wolfram Language code: es//Normal
Wolfram Language code: ListPlot[{data, es}, DataRange -> {0, 8}, PlotStyle -> PointSize[Large], Filling -> {1 -> Axis}, PlotLegends -> {"data", "es"}]

TimeSeriesのデフォルトの欠測データの処理メソッドは，次数2の補間である：

Wolfram Language code: data = {-1, -2, -1, 4, Missing[], 2, 1, 2, 1};
Wolfram Language code: ts = TimeSeries[data, MissingDataMethod -> Automatic]
Wolfram Language code: ts//Normal
Wolfram Language code: ListPlot[{data, ts}, DataRange -> {0, 8}, PlotStyle -> PointSize[Large], Joined -> {False, True}, Filling -> {1 -> Axis}, PlotLegends -> {"data", "ts"}]

TemporalDataのデフォルトの欠測データの処理メソッドは，次数0の補間である：

Wolfram Language code: data = {-1, -2, -1, 4, Missing[], 2, 1, 2, 1};
Wolfram Language code: td = TemporalData[data, MissingDataMethod -> Automatic]
Wolfram Language code: td//Normal
Wolfram Language code: ListPlot[{data, td}, DataRange -> {0, 8}, PlotStyle -> PointSize[Large], Filling -> {1 -> Axis}, Joined -> {False, True}, InterpolationOrder -> 0, PlotLegends -> {"data", "td"}]

考えられる問題  (1)

MissingDataMethodの選択によって，さまざまな結果が生み出される：

Wolfram Language code: data = {-1, -2, -1, 0, Missing[], 2, 1, 2, 1, 0, 1, 2, 1, 2, 3};

欠測値は指定しない：

Wolfram Language code: ts1 = TimeSeries[data, MissingDataMethod -> None]

累積する：

Wolfram Language code: res1 = Accumulate[ts1];

欠測値を定数で埋める：

Wolfram Language code: ts2 = TimeSeries[data, MissingDataMethod -> {"Constant", 5}];
Wolfram Language code: res2 = Accumulate[ts2];

補間を使って欠測値を埋める：

Wolfram Language code: ts3 = TimeSeries[data, MissingDataMethod -> {"Interpolation", InterpolationOrder -> 1}];
Wolfram Language code: res3 = Accumulate[ts3];

結果を比較する：

Wolfram Language code: ListLinePlot /@ {res1, res2, res3}
Wolfram Research (2012), MissingDataMethod, Wolfram言語関数， https://reference.wolfram.com/language/ref/MissingDataMethod.html.

テキスト

Wolfram Research (2012), MissingDataMethod, Wolfram言語関数， https://reference.wolfram.com/language/ref/MissingDataMethod.html.

CMS

Wolfram Language. 2012. "MissingDataMethod." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/MissingDataMethod.html.

APA

Wolfram Language. (2012). MissingDataMethod. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/MissingDataMethod.html

BibTeX

@misc{reference.wolfram_2026_missingdatamethod, author="Wolfram Research", title="{MissingDataMethod}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/MissingDataMethod.html}", note=[Accessed: 05-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_missingdatamethod, organization={Wolfram Research}, title={MissingDataMethod}, year={2012}, url={https://reference.wolfram.com/language/ref/MissingDataMethod.html}, note=[Accessed: 05-September-2026]}