WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ObservabilityGramian[ssm]

状態空間モデル ssm の可観測性グラミアンを与える．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
考えられる問題  
関連項目
関連するガイド
履歴
引用書式

ObservabilityGramian

ObservabilityGramian[ssm]

状態空間モデル ssm の可観測性グラミアンを与える．

詳細とオプション

  • 状態空間モデル ssm はStateSpaceModel[{a,b,c,d}]として与えられる．ただし，a，b，c，d は連続時間系あるいは離散時間系のどちらかにおける状態，入力，出力，伝送の各行列を表す．
  • 連続時間系
    離散時間系
  • 可観測性グラミアン
  • 連続時間系
    離散時間系
  • 漸近的に安定した系では，グラミアン はリャプノフ(Lyapunov)方程式の解として計算できる．
  • 連続時間系
    離散時間系
  • ディスクリプタ行列があるStateSpaceModelについて，ObservabilityGramianは行列のペア{wos,wof}を返す．ただし，wos た遅い部分系に関連しており，wof は速い部分系に関連している．
  • 可観測性グラミアンはあるλについてDet[λ e-a]≠0であるディスクリプタ系についてのみ存在する．

例題

すべて開く すべて閉じる

例  (1)

ある系の可観測性グラミアン：

Wolfram Language code: ObservabilityGramian[StateSpaceModel[{{{-1, 0, 0}, {0, -5, 0}, {0, 0, -6}}, {{1}, {2}, {-1}}, {{1, 0, 0}, {0, 1, 0}, {0, 0, 1}}, {{0}, {0}, {0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]

スコープ  (4)

連続時間系の可観測性グラミアン：

Wolfram Language code: ObservabilityGramian[StateSpaceModel[{{{-0.5, -0.5, 0}, {0.5, -0.5, 0}, {0, 0, -1}}, {{0}, {0}, {1}}, {{1, 2, 1}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]

離散時間系の可観測性グラミアン：

Wolfram Language code: ObservabilityGramian[StateSpaceModel[{{{0.9512, 0}, {0, 0.9048}}, {{4.88, 4.88}, {-0.019, 0.0095}}, {{0.01, 0}, {0, 1}}, {{0, 0}, {0, 0}}}, SamplingPeriod -> 5, SystemsModelLabels -> None]]

記号系の可観測性グラミアン：

Wolfram Language code: ObservabilityGramian[StateSpaceModel[{{{-a, 0}, {0, -a}}, {{1}, {1}}, {{1, 1}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]; FunctionExpand[%, a∈Reals]

ディスクリプタ系の可観測性グラミアン：

Wolfram Language code: ObservabilityGramian[StateSpaceModel[{{{-3, 0, 0}, {0, 1, 0}, {0, 0, 1}}, {{1}, {0}, {2}}, {{1, 4, 0}}, {{0}}, {{1, 0, 0}, {0, 0, 1}, {0, 0, 0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]

アプリケーション  (1)

系が可観測であるかどうか確認する：

Wolfram Language code: MatrixRank[ObservabilityGramian[StateSpaceModel[{{{-1, 0}, {0, -2}}, {{1}, {0}}, {{1, 1}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]] == 2

特性と関係  (7)

可観測性グラミアンは，双対系の可制御性グラミアンである：

Wolfram Language code: ssm = StateSpaceModel[{{{-5, -0.9, 0}, {0.9, -5, 0}, {0, 0, -3}}, {{1}, {0}, {-1}}, {{1, 0, -1}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]; ObservabilityGramian[ssm] == ControllabilityGramian[DualSystemsModel[ssm]]

可観測性グラミアンは状態行列の次元を持つ：

Wolfram Language code: Dimensions@ObservabilityGramian[StateSpaceModel[{{{0, 1}, {-Subscript[a, 2], -Subscript[a, 1]}}, {{0}, {1}}, {{1, 0}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]

可観測性グラミアンがフルランクの場合，その系は可観測である：

Wolfram Language code: ssm = StateSpaceModel[{{{-1, 0}, {0, -4}}, {{1}, {3}}, {{1, 0}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]; {ObservableModelQ[ssm], MatrixRank[ObservabilityGramian[ssm]] == 2}

可観測で漸近的に安定した系の可観測性グラミアンは対称かつ正定値である：

Wolfram Language code: ObservabilityGramian[StateSpaceModel[{{{-3, 0}, {0, -2}}, {{1}, {-1}}, {{1, 1}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]; SymmetricMatrixQ[%] && PositiveDefiniteMatrixQ[%]

連続時間（離散時間）系の可観測性グラミアンは連続（離散）リャプノフ方程式を満足する：

Wolfram Language code: {aa, bb, cc} = {{{-3, 1}, {-5, 0}}, {{1}, {5}}, {{1, 0}}}; ssm = StateSpaceModel[{aa, bb, cc}];
Wolfram Language code: Chop[ObservabilityGramian[ssm] - LyapunovSolve[aa, -cc.cc]]
Wolfram Language code: {aa, bb, cc} = {{{0, 1, 0}, {0, 0, 1}, {0.1054, -1.0183, 1.9052}}, {{0}, {0}, {1}}, {{0.002664, 0.01983, 0.0080859}}}; ssm = StateSpaceModel[{aa, bb, cc}, SamplingPeriod -> 1];
Wolfram Language code: Chop[ObservabilityGramian[ssm] - DiscreteLyapunovSolve[aa, -cc.cc]]

ディスクリプタ系は2つの可観測性グラミアンを与える：

Wolfram Language code: Subscript[ssm, 1] = StateSpaceModel[{{{1, 0, 0}, {0, -3, 0}, {0, 0, -2}}, {{0}, {1}, {0}}, {{1, 3, 0}}, {{0}}, {{0, 0, 0}, {0, 3, 0}, {1, 0, 0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]; gramians = ObservabilityGramian[Subscript[ssm, 1]];

これらの系は，総和が正定値であるときかつそのときに限り，完全に可観測である：

Wolfram Language code: PositiveDefiniteMatrixQ[Plus@@gramians]
Wolfram Language code: ObservableModelQ[Subscript[ssm, 1]]
Wolfram Language code: Subscript[ssm, 2] = StateSpaceModel[{{{1, 0, 0}, {0, -3, 0}, {0, 0, -2}}, {{1}, {1}, {0}}, {{1, 3, -2}}, {{0}}, {{0, 0, 0}, {0, 3, 0}, {1, 0, 0}}}, SamplingPeriod -> None, SystemsModelLabels -> None];
Wolfram Language code: PositiveDefiniteMatrixQ[Plus@@ObservabilityGramian[Subscript[ssm, 2]]]
Wolfram Language code: ObservableModelQ[Subscript[ssm, 2]]

速い部分系と遅い部分系のグラミアンは，クロネッカー分解から計算される：

Wolfram Language code: ssm = StateSpaceModel[{{{-1, 0, 0}, {0, -1, 1}, {0, 0, 1}}, {{1}, {1}, {1}}, {{1, 2, 5}}, {{0}}, {{1, 0, 0}, {0, 0, 1}, {0, 0, 0}}}, SamplingPeriod -> None, SystemsModelLabels -> None];
Wolfram Language code: {{p, q}, kssm} = KroneckerModelDecomposition[ssm]

分離された状態を分ける：

Wolfram Language code: {slowssm, fastssm} = {SystemsModelExtract[kssm, All, All, 1], SystemsModelExtract[kssm, All, All, {2, 3}]}

遅い部分系は，遅い状態のグラミアンと零行列を返す：

Wolfram Language code: {slowgramian, zeromat} = ObservabilityGramian[slowssm]

速い部分系は，速い状態のグラミアンと零行列を返す：

Wolfram Language code: {zeromat, fastgramian} = ObservabilityGramian[fastssm]

クロネッカー変換の逆変換はもとの系のグラミアンを与える：

Wolfram Language code: Inverse[p].PadRight[slowgramian, {3, 3}].Inverse[p]
Wolfram Language code: Inverse[p].PadLeft[fastgramian, {3, 3}].Inverse[p]

これはObservabilityGramianを直接使った場合と同じ結果を与える：

Wolfram Language code: ObservabilityGramian[ssm]

考えられる問題  (1)

漸近的に安定ではない系については可観測性グラミアンは定義されない：

Wolfram Language code: ObservabilityGramian[StateSpaceModel[{{{0, 1, 0}, {0, -1, 1}, {0, -4, -5}}, {{0}, {0}, {1}}, {{100, 20, 0}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]
Wolfram Research (2010), ObservabilityGramian, Wolfram言語関数， https://reference.wolfram.com/language/ref/ObservabilityGramian.html （2012年に更新）.

テキスト

Wolfram Research (2010), ObservabilityGramian, Wolfram言語関数， https://reference.wolfram.com/language/ref/ObservabilityGramian.html （2012年に更新）.

CMS

Wolfram Language. 2010. "ObservabilityGramian." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2012. https://reference.wolfram.com/language/ref/ObservabilityGramian.html.

APA

Wolfram Language. (2010). ObservabilityGramian. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ObservabilityGramian.html

BibTeX

@misc{reference.wolfram_2026_observabilitygramian, author="Wolfram Research", title="{ObservabilityGramian}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/ObservabilityGramian.html}", note=[Accessed: 30-October-2026]}

BibLaTeX

@online{reference.wolfram_2026_observabilitygramian, organization={Wolfram Research}, title={ObservabilityGramian}, year={2012}, url={https://reference.wolfram.com/language/ref/ObservabilityGramian.html}, note=[Accessed: 30-October-2026]}