WOLFRAM

Wolfram 语言与系统参考资料中心

PadeApproximant[expr,{x,x0,{m,n}}]

给出表达式 expr 在点 x=x0 处的 Padé 逼近，其分子的次数为 m，分母的次数为 n.

PadeApproximant[expr,{x,x0,n}]

给出 expr 在点 x=x0 处的 n 阶对角 Padé 近似值.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
推广和延伸  
应用  
属性和关系  
可能存在的问题  
参见
技术笔记
相关指南
历史
按以下格式引用：

PadeApproximant

PadeApproximant[expr,{x,x0,{m,n}}]

给出表达式 expr 在点 x=x0 处的 Padé 逼近，其分子的次数为 m，分母的次数为 n.

PadeApproximant[expr,{x,x0,n}]

给出 expr 在点 x=x0 处的 n 阶对角 Padé 近似值.

更多信息

  • 只有当可以算出点 x=x0 处的幂级数时，Wolfram 语言才可以求该点处的 Padé 逼近.
  • PadeApproximant 生成普通多项式的比，而不是一个特殊的 SeriesData 对象.

范例

打开所有单元 关闭所有单元

基本范例  (2)

分子分母次数 [2/3]、Exp[x] 的 Padé 逼近：

Wolfram Language code: PadeApproximant[Exp[x], {x, 0, {2, 3}}]

PadeApproximant 可以处理有极点的函数：

Wolfram Language code: PadeApproximant[(Exp[x]/x), {x, 0, {2, 3}}]

范围  (4)

一个任意函数的 Padé 逼近：

Wolfram Language code: PadeApproximant[(f[x]/x), {x, 0, 2}]

带有复数点的 Padé 逼近：

Wolfram Language code: PadeApproximant[Cos[x], {x, I, 2}]

带有无穷点的 Padé 逼近：

Wolfram Language code: PadeApproximant[Log[1 + 1 / x], {x, Infinity, 2}]

对一个给定级数求解一个 Padé 逼近：

Wolfram Language code: Sum[BernoulliB[2n]x ^ n, {n, 0, 10}]
Wolfram Language code: PadeApproximant[%, {x, 0, 5}]

推广和延伸  (3)

在点 处的Padé 近似值：

Wolfram Language code: PadeApproximant[Exp[x], {x, a, {2, 3}}]

在分数幂的 Padé 近似值：

Wolfram Language code: PadeApproximant[ Sin[Sqrt[x]], {x, 0, 3}]

包含对数的 Padé 近似函数：

Wolfram Language code: Hypergeometric2F1[2, 2, 4, 1 - x]
Wolfram Language code: PadeApproximant[Hypergeometric2F1[2, 2, 4, 1 - x], {x, 0, 5}]

应用  (2)

绘制连续的关于 的Padé 近似值：

Wolfram Language code: Plot[Evaluate[Table[PadeApproximant[Sin[x], {x, 0, n}], {n, 5}]], {x, 0, 2π}]

构建具有权重的不同离散正交多项式：

Wolfram Language code: ω[k_] = ((-1/2))^k (1/Sqrt[k]);
Wolfram Language code: moment[n_] = Sum[ω[k] / k ^ n, {k, 1, Infinity}]
Wolfram Language code: p[m_, x_] := 1 / x ^ m Denominator[PadeApproximant[Sum[x ^ k N[moment[k], 30], {k, 0, 10}], {x, 0, {m - 1, m}}]]

绘制前几个多项式：

Wolfram Language code: Plot[Evaluate[Table[p[n, x], {n, 5}]], {x, 1, 4}]

验证多项式的正交性与量度的关系：

Wolfram Language code: Table[Sum[ω[x]p[n, x] p[m, x], {x, 1, Infinity}], {n, 5}, {m, 5}]

属性和关系  (2)

级的普通级数的 Padé 近似值：

Wolfram Language code: Series[PadeApproximant[Exp[x], {x, 0, {2, 3}}], {x, 0, 6}]
Wolfram Language code: Series[Exp[x], {x, 0, 6}]

对于 ，PadeApproximant 给出一个普通级数：

Wolfram Language code: PadeApproximant[Exp[x], {x, 0, {5, 0}}]

可能存在的问题  (2)

Padé 逼近通常有伪极点，并且没有在原函数内表现：

Wolfram Language code: PadeApproximant[Exp[x], {x, 0, 3}]
Wolfram Language code: NSolve[Denominator[%] == 0, x]

一个给定次的 Padé 逼近可能不存在：

Wolfram Language code: PadeApproximant[Cos[x], {x, 0, 1}]

次数的轻微震荡足以影响一个近似值：

Wolfram Language code: PadeApproximant[Cos[x], {x, 0, 2}]
Wolfram Research (2007)，PadeApproximant，Wolfram 语言函数，https://reference.wolfram.com/language/ref/PadeApproximant.html.

文本

Wolfram Research (2007)，PadeApproximant，Wolfram 语言函数，https://reference.wolfram.com/language/ref/PadeApproximant.html.

CMS

Wolfram 语言. 2007. "PadeApproximant." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/PadeApproximant.html.

APA

Wolfram 语言. (2007). PadeApproximant. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/PadeApproximant.html 年

BibTeX

@misc{reference.wolfram_2026_padeapproximant, author="Wolfram Research", title="{PadeApproximant}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/PadeApproximant.html}", note=[Accessed: 09-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_padeapproximant, organization={Wolfram Research}, title={PadeApproximant}, year={2007}, url={https://reference.wolfram.com/language/ref/PadeApproximant.html}, note=[Accessed: 09-November-2026]}