WOLFRAM

Wolfram 语言与系统参考资料中心

ShearingMatrix[θ,v,n]

给出这样一个矩阵，它沿向量 v 的方向剪切 θ 弧度，法向量是 n.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
属性和关系  
可能存在的问题  
巧妙范例  
参见
技术笔记
相关指南
历史
按以下格式引用：

ShearingMatrix

ShearingMatrix[θ,v,n]

给出这样一个矩阵，它沿向量 v 的方向剪切 θ 弧度，法向量是 n.

更多信息

  • ShearingMatrix 根据剪切要求来生成矩阵而不改变坐标原点.
  • ShearingMatrix 根据面积或体积转化要求生成相应的矩阵，且矩阵的行列式为1.
  • 在二维图形中，ShearingMatrix 将三角形转变为矩形. ShearingMatrix[θ,{1,0},{0,1}] 向右倾斜 θ 角.
  • 在三维图形中，ShearingMatrix 的剪切方式类似沿向量 v 方向旋转 θ 角剪切一副卡片，而卡片的法向量是 n.

范例

打开所有单元 关闭所有单元

基本范例  (2)

沿 轴剪切 θ 弧度：

Wolfram Language code: ShearingMatrix[θ, {1, 0}, {0, 1}]//MatrixForm

沿着 轴，对矩形做 30° 剪切：

Wolfram Language code: Graphics[GeometricTransformation[Rectangle[], ShearingMatrix[30 Degree, {1, 0}, {0, 1}]], Frame -> True]

范围  (5)

沿 轴剪切：

Wolfram Language code: ShearingMatrix[θ, {1, 0}, {0, 1}]//MatrixForm

沿 轴剪切：

Wolfram Language code: ShearingMatrix[θ, {0, 1}, {1, 0}]//MatrixForm

在 轴构成的平面内沿 轴剪切：

Wolfram Language code: ShearingMatrix[θ, {1, 0, 0}, {0, 0, 1}]//MatrixForm

在 轴构成的平面内沿 轴剪切：

Wolfram Language code: ShearingMatrix[θ, {1, 0, 0}, {0, 1, 0}]//MatrixForm

一个沿 {1,1} 方向剪切 theta 弧度，以直线 {1,-1}.p==0 为方向：

Wolfram Language code: ShearingMatrix[θ, {1, 1}, {1, -1}]//MatrixForm

应用于二维图形的转换：

Wolfram Language code: gr = {Rectangle[], AbsolutePointSize[10], Opacity[1], {Magenta, Point[{0, 0}]}, {Green, Point[{1, 1}]}};
Wolfram Language code: Graphics[{{Opacity[.35], Blue, gr}, GeometricTransformation[{Opacity[.85], Red, gr}, ShearingMatrix[Pi / 6, {1, 0}, {0, 1}]]}]

应用于三维图形的转换：

Wolfram Language code: gr = {Cuboid[], AbsolutePointSize[10], Opacity[1], {Magenta, Point[{0, 0, 0}]}, {Green, Point[{1, 1, 1}]}};
Wolfram Language code: Graphics3D[{{Opacity[.35], Blue, gr}, GeometricTransformation[{Opacity[.85], Red, gr}, ShearingMatrix[Pi / 4, {1, 0, 0}, {-1, 1, 0}]]}, Boxed -> False]

应用  (2)

在表面上应用转换：

Wolfram Language code: Plot3D[-Sin[x y], {x, 0, Pi}, {y, 0, Pi}, BoxRatios -> Automatic, PlotRange -> All] /. gc_GraphicsComplex :> GeometricTransformation[gc, ShearingMatrix[-Pi / 4, {1, 1, 0}, {0, 0, 1}]]

生成所有简单的(方向与坐标轴平行) n 维剪切矩阵：

Wolfram Language code: Shearings[θ_, n_] := With[{pairs = Subsets[Table[ UnitVector[n, j], {j, n}], {2}]}, Map[ShearingMatrix[θ, #[[1]], #[[2]]]&, Join[pairs, Reverse /@ pairs]]];

所有二维剪切矩阵：

Wolfram Language code: Map[ MatrixForm, Shearings[θ, 2]]
Wolfram Language code: Map[Framed@Graphics[GeometricTransformation[Rectangle[], #], PlotRange -> {{0, 1.6}, {0, 1.6}}]&, Shearings[Pi / 6, 2]]

所有三维剪切矩阵：

Wolfram Language code: Map[ MatrixForm, Shearings[θ, 3]]
Wolfram Language code: Map[Graphics3D[GeometricTransformation[Cuboid[], #]]&, Shearings[Pi / 6, 3]]

所有四维剪切矩阵：

Wolfram Language code: Map[ MatrixForm, Shearings[θ, 4]]

属性和关系  (4)

剪切矩阵的行列式是1，所以它保留面积和体积不变：

Wolfram Language code: Det[ ShearingMatrix[θ, {1, 0, 0}, {0, 0, 1}]]

ShearingMatrix[θ,v,n] 的求逆可以通过 ShearingMatrix[-θ,v,n] 来求：

Wolfram Language code: ShearingMatrix[θ, {1, 0, 0}, {0, 0, 1}].ShearingMatrix[-θ, {1, 0, 0}, {0, 0, 1}]

ShearingMatrix[θ,v,n] 的求逆也可以通过 ShearingMatrix[θ,-v,n] 来求：

Wolfram Language code: ShearingMatrix[θ, {1, 0, 0}, {0, 0, 1}].ShearingMatrix[θ, -{1, 0, 0}, {0, 0, 1}]

一个剪切矩阵的 n 次幂还是一个有相同 v 和 n 的剪切矩阵：

Wolfram Language code: MatrixPower[ShearingMatrix[a, {1, 0}, {0, 1}], n] == ShearingMatrix[ArcTan[n Tan[a]], {1, 0}, {0, 1}]

可能存在的问题  (3)

剪切的次序非常重要：

Wolfram Language code: t1 = ShearingMatrix[θ, {1, 0, 0}, {0, 0, 1}]; t2 = ShearingMatrix[ϕ, {1, 0, 0}, {-1, 1, 0}];

两种不同的次序生成不同的矩阵：

Wolfram Language code: t1.t2 - t2.t1//Simplify

角度 的转换没有定义，例如 ：

Wolfram Language code: Limit[ShearingMatrix[a, {1, 0, 0}, {0, 0, 1}], a -> Pi / 2]

对于非正交的向量，方向是由投射方向决定的：

Wolfram Language code: ShearingMatrix[a, {1, 0}, {1, 1}] == ShearingMatrix[a, Projection[{1, 0}, Cross[{1, 1}]], {1, 1}]

巧妙范例  (1)

一个球体的转换：

Wolfram Language code: Graphics3D[Table[GeometricTransformation[Sphere[{1, 1, 1}], ShearingMatrix[Pi / 3, {Cos[u], 0, Sin[u]}, {0, 1, 0}]], {u, 2Pi / 5Range[5]}], Boxed -> False]
Wolfram Research (2007)，ShearingMatrix，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ShearingMatrix.html.

文本

Wolfram Research (2007)，ShearingMatrix，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ShearingMatrix.html.

CMS

Wolfram 语言. 2007. "ShearingMatrix." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/ShearingMatrix.html.

APA

Wolfram 语言. (2007). ShearingMatrix. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/ShearingMatrix.html 年

BibTeX

@misc{reference.wolfram_2026_shearingmatrix, author="Wolfram Research", title="{ShearingMatrix}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/ShearingMatrix.html}", note=[Accessed: 03-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_shearingmatrix, organization={Wolfram Research}, title={ShearingMatrix}, year={2007}, url={https://reference.wolfram.com/language/ref/ShearingMatrix.html}, note=[Accessed: 03-November-2026]}