WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

TimeSeriesWindow[tes,{tmin,tmax}]

tminから tmaxまでの中に入る，時系列または事象系列のデータ tes の要素を与える．

TimeSeriesWindow[tes,winspec]

窓指定 winspec を満足する tes の要素を与える．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
基本的な用法  
データの型  
オプション  
IncludeWindowTimes  
ResamplingMethod  
CalendarType  
HolidayCalendar  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

TimeSeriesWindow

TimeSeriesWindow[tes,{tmin,tmax}]

tminから tmaxまでの中に入る，時系列または事象系列のデータ tes の要素を与える．

TimeSeriesWindow[tes,winspec]

窓指定 winspec を満足する tes の要素を与える．

詳細とオプション

  • TimeSeriesWindowは，一般に，指定された時間窓に入る時系列または事象系列の部分集合を選ぶために使われる．
  • TimeSeriesWindowは，タイムスタンプ を持つデータ点のうち，を満たすものを選択する．
  • 次は，使用可能な時系列または事象系列のデータ tes の可能な形式である．
  • TimeSeries[…]連続時間で順序付けられたサンプルデータ
    EventSeries[…]値を伴う時間的事象の集合
    TemporalData[…]時間と値のペアから構成される1つ以上の経路
    {{t1,x1},{t2,x2},…}時間と値のペアのリスト
    {x1,x2,…}0から始まる暗黙の整数時刻を伴う値のリスト
  • 次は，使用可能な窓指定 winspec である．
  • {tmin,tmax}時刻または日付の範囲
    Interval[…]1つ以上の数値時間の断片
    DateInterval[…]1つ以上の暦の日付の断片
    DateObject[_, gran]単一粒度のDateObject
    daytype曜日指定
  • 窓の時点 tminおよび tmaxは，Automatic，数，あるいは日付で与えることができる．tminあるいは tmaxがAutomaticとして与えられている場合は，それぞれに tes の最初と最後の時点が使われる．
  • 使用可能な daytype の値には，"Weekday"，"Weekend"，MondayからSundayまで，"BeginningOfMonth"，"EndOfMonth"，"BusinessDay"，"Holiday"がある．
  • TimeSeriesWindowは次のオプションを取る．
  • ResamplingMethod Automatic経路のリサンプリングに使用するメソッド
    IncludeWindowTimes Falsetminおよび tmaxがタイムスタンプに属さない場合に，これらの値を作成するかどうか
    CalendarType Automatic日付を解釈する暦体系
    HolidayCalendar Automatic営業日のための休日のスケジュール
  • デフォルトで，窓の時点 tminおよび tmaxは，それらが既存の tes のタイムスタンプである場合にのみ含まれる．
  • tminおよび tmaxが tes のタイムスタンプの範囲外にある場合，それらは範囲に収まるように切り取られる．

例題

すべて開く すべて閉じる

例  (2)

時系列の部分集合を選択する：

Wolfram Language code: ts = TimeSeries[{1, 2, 3, 4, 5}, {DateObject[{2026, 3, 13}, "Day"]}]
Wolfram Language code: TimeSeriesWindow[ts, {DateObject[{2026, 3, 14}, "Day"], DateObject[{2026, 3, 16}, "Day"]}]
Wolfram Language code: Normal[%]

事象系列の部分集合を選択する：

Wolfram Language code: es = EventSeries[{{.1, Subscript[x, 1]}, {.6, Subscript[x, 2]}, {1.3, Subscript[x, 3]}, {2.2, Subscript[x, 4]}, {2.5, Subscript[x, 5]}}];
Wolfram Language code: TimeSeriesWindow[es, {.9, 2.3}]
Wolfram Language code: Normal[%]

スコープ  (7)

基本的な用法  (2)

日付の時系列から金曜日を選択する：

Wolfram Language code: ts = TimeSeries[TimeEventSeries`TimestampData[Association["UniformlySpacedQ" -> False, "Timestamps" -> TabularColumn[Association[ "Data" -> {21, {{NumericArray[{15492, 15495, 15496, 15497, 15498, 15499, 15502, 15503, 15504, 15505, ... , 284.53455, 282.832828, 280.82584, 279.804813, 282.53754, 285.710728, 291.056065, 289.044041, 282.887882, 286.026035, 280.630649, 282.622623, 284.93494, 282.437443, 290.325321}, {}, None}, "ElementType" -> "Real64"]], Association[]];
Wolfram Language code: fridays = TimeSeriesWindow[ts, Friday]
Wolfram Language code: DateListPlot[{ts, fridays}, Joined -> {True, False}, Filling -> 2 -> 0, FillingStyle -> Directive[Gray, Thick]]

金曜日の日付を示す：

Wolfram Language code: fridays["Timestamps"]//Normal

以下は，同じリストを入手する別の方法である：

Wolfram Language code: DateSelect[ts["Timestamps"]//Normal, #DayName === Friday&]
Wolfram Language code: Select[ts["Timestamps"], DayMatchQ[Friday]]//Normal
Wolfram Language code: Select[ts, DayMatchQ[#Timestamp, Friday]&]
Wolfram Language code: %["Timestamps"]//Normal

時系列のさまざまな部分集合を可視化する：

Wolfram Language code: data = TimeSeries@RandomFunction[ARIMAProcess[{.1}, 1, {.2}, 1], {1000}]
Wolfram Language code: ListLinePlot[data]

データを3つの部分に分割する：

Wolfram Language code: win1 = TimeSeriesWindow[data, {Automatic, 300}]; win2 = TimeSeriesWindow[data, {300, 700}]; win3 = TimeSeriesWindow[data, {700, Automatic}];
Wolfram Language code: ListLinePlot[{win1, win2, win3}, PlotLegends -> {"win1", "win2", "win3"}]

データの型  (5)

ベクトルから3要素を抽出する：

Wolfram Language code: v = {a, b, c, d, e};
Wolfram Language code: TimeSeriesWindow[v, {2, 4}]

時点と値のペアのリスト中の特定の時間間隔について値を選ぶ：

Wolfram Language code: v = {{1, a}, {3, b}, {7, c}, {14, d}, {15, e}};
Wolfram Language code: TimeSeriesWindow[v, {2, 8}]

TimeSeriesから50個の値を抽出する：

Wolfram Language code: ts = TimeSeries[TimeEventSeries`TimestampData[Association["UniformlySpacedQ" -> True, "Count" -> 100, "Endpoints" -> TabularColumn[Association["Data" -> {{0, 99}, {}, None}, "ElementType" -> "Integer64"]], "MinimumTimeIncrement" -> 1, "Caller ... -5.83329995009813, -5.365194518466113, -5.614668108914484, -6.477246191853266, -7.461704439607946, -6.79657593242878, -5.864937981765857, -6.27785271209235, -5.841962111797332}, {}, None}, "ElementType" -> "Real64"]], Association[]];
Wolfram Language code: win = TimeSeriesWindow[ts, {10, 59}]

窓をもとのデータに重ねる：

Wolfram Language code: ListLinePlot[{ts, win}]

EventSeriesから30個の値を抽出する：

Wolfram Language code: es = EventSeries[TimeEventSeries`TimestampData[Association["UniformlySpacedQ" -> True, "Count" -> 50, "Endpoints" -> TabularColumn[Association["Data" -> {{0, 49}, {}, None}, "ElementType" -> "Integer64"]], "MinimumTimeIncrement" -> 1, "Caller ... -1, -1, 1, 1, -1, 1, 1, -1, -1, 1, 1, 1, -1, -1, 1, -1, 1, -1, -1, -1, -1, -1, 1, -1, -1, -1, -1, 1, -1, 1, 1, 1, 1, 1, -1, 1, -1, -1, -1, 1, 1, 1, -1, 1, 1, -1, -1, -1, -1}, {}, None}, "ElementType" -> "Integer64"]], Association[]];
Wolfram Language code: win = TimeSeriesWindow[es, {10, 39}]

窓をもとのデータに重ねる：

Wolfram Language code: ListPlot[{es, win}, Filling -> Axis]

TemporalDataの経路をより間隔の狭いものに限定する：

Wolfram Language code: td = RandomFunction[WienerProcess[], {0, 20, 0.01}, 5]
Wolfram Language code: win = TimeSeriesWindow[td, {3, 15}]
Wolfram Language code: ListLinePlot[#, PlotRange -> {{0, 20}, {-10, 10}}]& /@ {td, win}

オプション  (4)

IncludeWindowTimes  (1)

時系列のデータとして解釈される，時点と値のペアのリストを取る：

Wolfram Language code: ts = {{1, 1}, {2, 2}, {3, 3}, {4, 4}};

時間窓の（端点を含まない）端点間のからペアを選択する：

Wolfram Language code: TimeSeriesWindow[ts, {1.5, 3.5}]

端点は，時系列のタイムスタンプの場合は含まれる：

Wolfram Language code: TimeSeriesWindow[ts, {2, 3}]

窓の端点を含むように指定する：

Wolfram Language code: TimeSeriesWindow[ts, {1.5, 3.5}, IncludeWindowTimes -> True]

窓の右の端点だけを含める：

Wolfram Language code: TimeSeriesWindow[ts, {1.5, 3.5}, IncludeWindowTimes -> {False, True}]

ResamplingMethod  (1)

タイムスタンプ内ではない窓時間にどの値を割り当てるかを指定する：

Wolfram Language code: s = {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3], Subscript[x, 4]}; t = {2, 4, 6, 8};
Wolfram Language code: data = TimeSeries[s, {t}]; data//Normal

デフォルトで，入力データのリサンプリングメソッドが使われる：

Wolfram Language code: win1 = TimeSeriesWindow[data, {4, 6.4}, IncludeWindowTimes -> True];
Wolfram Language code: win1//Normal//Simplify

次数1の補間を使う：

Wolfram Language code: win2 = TimeSeriesWindow[data, {4, 6.4}, IncludeWindowTimes -> True, ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}];
Wolfram Language code: win2//Normal//Simplify

固定された定数を使う：

Wolfram Language code: win3 = TimeSeriesWindow[data, {4, 6.4}, ResamplingMethod -> {"Constant", c}, IncludeWindowTimes -> True];
Wolfram Language code: win3//Normal

CalendarType  (1)

ユダヤ暦を使う：

Wolfram Language code: data = {{{5777, 1, 10}, 1}, {{5777, 1, 11}, 2}, {{5777, 1, 12}, 3}, {{5777, 1, 13}, 4}, {{5777, 1, 14}, 5}, {{5777, 1, 15}, 6}};
Wolfram Language code: TimeSeriesWindow[data, "Weekend", CalendarType -> "Jewish"]

HolidayCalendar  (1)

営業日を抽出する：

Wolfram Language code: ts = TimeSeries[Range[20], {{2017, 4, 10}}];
Wolfram Language code: res = TimeSeriesWindow[ts, "BusinessDay", HolidayCalendar -> "Germany"]
Wolfram Language code: DateListPlot[{ts, res}, Joined -> False, Filling -> 2 -> 0]

アプリケーション  (3)

この時系列は，ある人の5ヶ月間の毎日の歩数が含まれている：

Wolfram Language code: stepdata = TemporalData[TimeSeries, {{{10785, 11753, 7092, 5290, 5022, 7438, 13386, 11195, 12499, 12495, 12004, 11833, 4097, 14270, 10280, 11947, 12699, 15634, 12332, 8399, 4680, 10034, 9173, 5309, 9552, 5605, 13294, 7600, 2417, 0, 1315, 9066, 11624 ... 1, 9618, 21243, 22273, 15869, 17687, 9263, 21162, 14724, 6386}}, {TemporalData`DateSpecification[{2013, 4, 1, 0, 0, 0.}, {2013, 9, 1, 0, 0, 0.}, {1, "Day"}]}, 1, {"Discrete", 1}, {"Discrete", 1}, 1, {ValueDimensions -> 1}}, True, 10.];

各月の毎日の歩数を表示する：

Wolfram Language code: monthlyTS = Table[TimeSeriesWindow[stepdata, DateObject[{2013, k}]], {k, 4, 8}];
Wolfram Language code: months = {"April", "May", "June", "July", "August"};DateListPlot[monthlyTS, PlotLegends -> months]

各月の総歩数を表示する：

Wolfram Language code: monthlyTotals = Total /@ monthlyTS;
Wolfram Language code: PieChart[monthlyTotals, ChartLabels -> Placed[{monthlyTotals, months}, {"RadialCenter", "RadialCallout"}]]

2014年夏季のシャンペーンの気温を可視化する：

Wolfram Language code: td = TemporalData[TimeSeries, {{QuantityArray[StructuredArray`StructuredData[{365}, {{-2.94, -7.28, -14.94, -3.39, -2.56, -21, -23.06, -14.33, -6.5, 1.33, 3.22, 1.67, 5, -1.72, -2.33, -7.78, -0.5, -9, -4.28, 1.83, -0.94, -17, -12.17, -18 ... cation[{2014, 1, 1, 0, 0, 0.}, {2014, 12, 31, 0, 0, 0.}, {1, "Day"}]}, 1, {"Continuous", 1}, {"Discrete", 1}, 1, {ValueDimensions -> 1, DateFunction -> Automatic, ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}}}, True, 10.1];

夏季の各月の気温を抽出する：

Wolfram Language code: summer = TimeSeriesWindow[td, {DateObject[{2014, 6, 1}, "Day", "Gregorian", -6.], DateObject[{2014, 9, 1}, "Day", "Gregorian", -6.]}]

基本記述統計を求める：

Wolfram Language code: {Min[#], Mean[#], Max[#]}&@summer
Wolfram Language code: DateListPlot[{td, summer}, FrameLabel -> Automatic]

時系列の一部を抽出する：

Wolfram Language code: ts = TimeSeries[FinancialData["GOOGL", {"1 Jan 2012", "1 Jan 2014"}]]
Wolfram Language code: DateListPlot[ts]

2012年5月4日から8月4日までの要素を取り出す：

Wolfram Language code: win = TimeSeriesWindow[ts, {{2012, 5, 4}, {2012, 8, 4}}]
Wolfram Language code: DateListPlot[win]

2012年6月から要素を抽出する：

Wolfram Language code: TimeSeriesWindow[ts, DateObject[{2012, 6}, "Month"]]

各月末の事象を抽出する：

Wolfram Language code: end = TimeSeriesWindow[ts, "EndOfMonth"]
Wolfram Language code: DateListPlot[end, PlotMarkers -> Automatic]

特性と関係  (1)

Takeは時系列の要素を範囲指標に基づいて抽出する：

Wolfram Language code: ts = TimeSeries[Range[10], {DateObject[{2026, 1, 21}]}]
Wolfram Language code: Take[ts, {3, 6}]

TimeSeriesWindowは時間範囲を使う：

Wolfram Language code: TimeSeriesWindow[ts, {DateObject[{2026, 1, 23}], DateObject[{2026, 1, 26}]}]

これらの日付は，前に使われた指標範囲{3,6}に相当する：

Wolfram Language code: ts["Times"][[{3, 6}]]//Normal
Wolfram Research (2014), TimeSeriesWindow, Wolfram言語関数， https://reference.wolfram.com/language/ref/TimeSeriesWindow.html （2026年に更新）.

テキスト

Wolfram Research (2014), TimeSeriesWindow, Wolfram言語関数， https://reference.wolfram.com/language/ref/TimeSeriesWindow.html （2026年に更新）.

CMS

Wolfram Language. 2014. "TimeSeriesWindow." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2026. https://reference.wolfram.com/language/ref/TimeSeriesWindow.html.

APA

Wolfram Language. (2014). TimeSeriesWindow. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/TimeSeriesWindow.html

BibTeX

@misc{reference.wolfram_2026_timeserieswindow, author="Wolfram Research", title="{TimeSeriesWindow}", year="2026", howpublished="\url{https://reference.wolfram.com/language/ref/TimeSeriesWindow.html}", note=[Accessed: 04-October-2026]}

BibLaTeX

@online{reference.wolfram_2026_timeserieswindow, organization={Wolfram Research}, title={TimeSeriesWindow}, year={2026}, url={https://reference.wolfram.com/language/ref/TimeSeriesWindow.html}, note=[Accessed: 04-October-2026]}