WOLFRAM

Wolfram 语言与系统参考资料中心

TreeGamePayoff[tgame,strat]

给出在具有策略概况 strat 的树状博弈 tgame 中每个玩家的预期收益.

TreeGamePayoff[tgame,strat,adv]

给出具有不完整策略概况 strat 和对手类型 adv 的树状博弈 tgame 中每个玩家的预期收益.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
社会学博弈  
休闲游戏  
参见
相关指南
历史
按以下格式引用：

TreeGamePayoff

TreeGamePayoff[tgame,strat]

给出在具有策略概况 strat 的树状博弈 tgame 中每个玩家的预期收益.

TreeGamePayoff[tgame,strat,adv]

给出具有不完整策略概况 strat 和对手类型 adv 的树状博弈 tgame 中每个玩家的预期收益.

更多信息

  • TreeGamePayoff 也被称为序贯博弈的预期收益或预期效用.
  • TreeGamePayoff 通常用于评估给定每个参与者的策略的预期收益.
  • 树状博弈策略 <|…,playeri<|{ni,1}pri,1,…,{ni,mi}pri,mi|>,…|> 指定 playeri 的动作节点 ni,j 中 playeri 的动作概率 pri,j.
  • 当有 mj 个选择时，玩家 i 在动作节点 nj 的预期收益 pi 为 pi[{nj}]=pi[{nj,k}].prj,k，而玩家 i 在终端节点 nt 的预期收益 pi 由其指定收益给出：pi[{nt}]=pi,j.
  • 不完全树策略是一种树形游戏策略，其中只有一部分动作节点具有指定的概率.
  • 对于不完全策略，可以对未指定的动作 adv 给出以下规范：
  • "Perfect"随机试验的收益，假定对未指定的行为做出最优选择
    "PerfectExpectation"平均收益，假定对未指定的行为做出最优随机选择
    "Random"随机试验的收益，假定对未指定的行为做出均匀随机选择
    "RandomExpectation"平均收益，假定对未指定的行为做出均匀随机选择

范例

打开所有单元 关闭所有单元

基本范例  (3)

生成三人树游戏：

Wolfram Language code: game = TreeGame[{"A", {"B", {"C", {1, 2, 3} -> "C1", {5, 5, 1} -> "C2"} -> "B1", {1, 3, 2} -> "B2"} -> "A1", {2, 5, 5} -> "A2"}]

找到给定策略的预期收益：

Wolfram Language code: TreeGamePayoff[game, <|"A" -> <|{} -> {1 / 2, 1 / 2}|>, "B" -> <|{1} -> {0, 1}|>, "C" -> <|{1, 1} -> {1, 0}|>|>]

当玩家采取最佳行动，使用“完美”策略的空关联时，革命游戏的收益为：

Wolfram Language code: TreeGamePayoff[GameTheoryData["Revolution"], <||>, "Perfect"]

当“自然”玩家选择“软弱型”且其他玩家随机行动时，啤酒-乳蛋饼游戏的收益为：

Wolfram Language code: TreeGamePayoff[GameTheoryData["BeerQuiche"], <|{} -> {1, 0}|>, "RandomExpectation"]

范围  (3)

生成双人树游戏：

Wolfram Language code: game = TreeGame[{"A", {"B", {1, 1}, {2, 2}}, {"B", {3, 3}, {4, 4}}}]

求给定策略的预期收益：

Wolfram Language code: TreeGamePayoff[game, <|"A" -> <|{} -> {1, 0}|>, "B" -> <|{1} -> {0, 1}, {2} -> {0, 1}|>|>]

考虑一个具有概率的双人游戏：

Wolfram Language code: game = TreeGame[{"A", {"B", {0, 1}, {1, 2}} -> 0.3, {"B", {3, 4}, {5, 4}} -> 0.7}]

求给定策略的预期收益：

Wolfram Language code: TreeGamePayoff[game, <|"A" -> <||>, "B" -> <|{1} -> {0, 1}, {2} -> {0, 1}|>|>]

计算蜈蚣游戏中随机玩家的预期收益：

Wolfram Language code: TreeGamePayoff[GameTheoryData["Centipede"], <||>, "RandomExpectation"]

应用  (5)

社会学博弈  (3)

蜈蚣游戏（Centipede game）有两名玩家轮流做决定. 在每个回合，玩家可以选择“向下”结束游戏，也可以选择“向右”继续游戏（除了最后一个节点，在最后一个节点“向右”也会结束游戏）. 游戏时间越长，总收益越高. 提前结束游戏的玩家将获得更大的收益份额. 考虑一个每个玩家有三个动作的蜈蚣游戏：

Wolfram Language code: game = GameTheoryData["Centipede"]

虽然博弈论最佳解决方案是悲观的第一选择，但请注意，随机玩家的预期收益相似. 比较随机玩家和完美玩家的预期输出：

Wolfram Language code: TreeGamePayoff[game, <||>, "RandomExpectation"]
Wolfram Language code: TreeGamePayoff[game, <||>, "PerfectExpectation"]

配对硬币（Matching Pennies）树游戏是两个人各自选择正面或反面的游戏. 如果选择不同，则第 1 个人向第 2 个人支付 1 美元；如果选择相同，则第 2 个人向第 1 个人支付 1 美元. 生成配对硬币树游戏：

Wolfram Language code: game = GameTheoryData["TreeMatchingPennies"]

可视化游戏：

Wolfram Language code: TreeGamePlot[game]

显然，这个游戏给玩家 2 提供了优势，使得玩家 2 在与完美玩家的对战中不可能获得更好的收益. 想象一下成为玩家 1. 尝试几种策略来击败完美玩家（获得收益 1）：

Wolfram Language code: TreeGamePayoff[game, <|{} -> {1, 0}|>, "Perfect"]
Wolfram Language code: TreeGamePayoff[game, <|{} -> {0, 1}|>, "Perfect"]
Wolfram Language code: TreeGamePayoff[game, <|{} -> {1 / 2, 1 / 2}|>, "Perfect"]

入场博弈是指进入者决定是否进入市场，而现有市场参与者则决定在新进入者进入后进行竞争还是接纳新进入者. 生成入场博弈：

Wolfram Language code: game = GameTheoryData["Entry"]

显示决策树：

Wolfram Language code: game["Tree"]

假设您是市场在位者，您的策略是始终对抗（第一选择）. 求对抗随机玩家的预期收益：

Wolfram Language code: TreeGamePayoff[game, <|{1} -> {1, 0}|>, "RandomExpectation"]

完美玩家假设完美子博弈均衡. 由于该策略不是最优的，因此完美玩家的收益可能比随机玩家更差. 求出完美玩家的预期收益：

Wolfram Language code: TreeGamePayoff[game, <|{1} -> {1, 0}|>, "PerfectExpectation"]

休闲游戏  (2)

石头剪刀布是一个零和游戏，要么一个玩家赢，另一个玩家输，要么平局. 生成此游戏的树版本，其中第二个玩家可以根据第一个玩家的动作选择一个动作：

Wolfram Language code: game = TreeGame[{"A", {"B", {0, 0} -> "Rock", {-1, 1} -> "Paper", {1, -1} -> "Scissors"} -> "Rock", {"B", {1, -1} -> "Rock", {0, 0} -> "Paper", {-1, 1} -> "Scissors"} -> "Paper", {"B", {-1, 1} -> "Rock", {1, -1} -> "Paper", {0, 0} -> "Scissors"} -> "Scissors"}]

可视化游戏：

Wolfram Language code: TreeGamePlot[game]

显然，在石头剪刀布的树状游戏中，第二个玩家总是可以选择最佳动作，因此第一个玩家先出手会处于劣势. 在此版本的石头剪刀布游戏中写下完美的策略：

Wolfram Language code: TreeGamePayoff[game, <|{1} -> {0, 1, 0}, {2} -> {0, 0, 1}, {3} -> {1, 0, 0}|>, "Perfect"]

以井字棋游戏为例. 设计一个函数来生成玩家 A 和 B 之间的部分井字棋游戏：

Wolfram Language code: ticTacToeTree[game_, player_] := If[StringContainsQ[ToString[Total /@ Join[game, Transpose[game], {Diagonal[game]}, {game[[1, 3]], game[[2, 2]], game[[3, 1]]}]], "3"], If[player == "A", {-1, 1}, {1, -1}], If[!MemberQ[Flatten[game], 0], {0, 0}, Prepend[Flatten[Table[Module[{g = game}, If[game[[i, j]] == 0, g[[i, j]] = If[player == "A", 1, -1]; ticTacToeTree[g, If[player == "A", "B", "A"]] -> ToString[{i, j}], Nothing] ], {i, 3}, {j, 3}], 1], player] ] ]

考虑一场部分完成的井字棋游戏：

Wolfram Language code: map = (⁠| | | | | - | - | -- | | 1 | 0 | -1 | | 0 | 1 | 0 | | 1 | 0 | -1 |⁠);

基于此形成一个 TreeGame：

Wolfram Language code: game = TreeGame[{"A", ticTacToeTree[map, "B"]}]

如果两位玩家都发挥完美，则玩家 B 获胜：

Wolfram Language code: TreeGamePayoff[game, <||>, "PerfectExpectation"]

如果两个玩家都随机发挥，则玩家 2 更有可能以微弱优势获胜：

Wolfram Language code: TreeGamePayoff[game, <||>, "RandomExpectation"]
Wolfram Research (2025)，TreeGamePayoff，Wolfram 语言函数，https://reference.wolfram.com/language/ref/TreeGamePayoff.html.

文本

Wolfram Research (2025)，TreeGamePayoff，Wolfram 语言函数，https://reference.wolfram.com/language/ref/TreeGamePayoff.html.

CMS

Wolfram 语言. 2025. "TreeGamePayoff." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/TreeGamePayoff.html.

APA

Wolfram 语言. (2025). TreeGamePayoff. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/TreeGamePayoff.html 年

BibTeX

@misc{reference.wolfram_2026_treegamepayoff, author="Wolfram Research", title="{TreeGamePayoff}", year="2025", howpublished="\url{https://reference.wolfram.com/language/ref/TreeGamePayoff.html}", note=[Accessed: 05-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_treegamepayoff, organization={Wolfram Research}, title={TreeGamePayoff}, year={2025}, url={https://reference.wolfram.com/language/ref/TreeGamePayoff.html}, note=[Accessed: 05-November-2026]}